Code getting in the way.

[JavaScript_Freek]

Case $msg = $zs14\
            Run(@ComSpec & ' /c start http://invisionfreeskins.com/index.php?act=UserCP&CODE=02', '', @SW_HIDE)

When I go to the menu it links me to: http://invisionfreeskins.com/index.php?act=UserCP

but leaves the &CODE=02 behind. Why is that?

[GaryFrost]

Run (@ComSpec & ' /c start "http://invisionfreeskins.com/index.php?act=UserCP&CODE=02"', '', @SW_HIDE)

[BigDod]

Use Beta

#include <IE.au3>
$oIE = _IECreate ("http://invisionfreeskins.com/index.php?act...CP&CODE=02")

Edit - @GaFrost, your does not work for me.

Edited August 11, 2006 by BigDod

[SmOke_N]

Personally I like using their default browser, and use this 99% of the time:

$Url = "http://invisionfreeskins.com/index.php?act...CP&CODE=02"
DllCall("shell32.dll", "long", "ShellExecute", "hwnd", 0, "string", 'open', "string", $Url, "string", '', "string", @ScriptDir, "long", @SW_SHOWNORMAL)

[GaryFrost]

Use Beta

#include <IE.au3>
$oIE = _IECreate ("http://invisionfreeskins.com/index.php?act...CP&CODE=02")

Edit - @GaFrost, your does not work for me.

You might have the same problem I have, just using the command I posted or even Smokes don't work for me either. But the following does work for me.

Run (@ComSpec & ' /c start explorer "http://invisionfreeskins.com/index.php?act=UserCP&CODE=02"', '', @SW_HIDE)

[SmOke_N]

that explorer works well... Mine don't work? SP2 XP right?

[GaryFrost]

that explorer works well... Mine don't work? SP2 XP right?

Yep

[Klaatu]

The start method doesn't work because of the command syntax of start: if given a quoted string as it's first parameter, it takes that as the title of the window to open. Try this instead and see if it works any better:

Run (@ComSpec & ' /c start "anything here" "http://invisionfreeskins.com/index.php?act=UserCP&CODE=02"', '', @SW_HIDE)

[GaryFrost]

The start method doesn't work because of the command syntax of start: if given a quoted string as it's first parameter, it takes that as the title of the window to open. Try this instead and see if it works any better:

Run (@ComSpec & ' /c start "anything here" "http://invisionfreeskins.com/index.php?act=UserCP&CODE=02"', '', @SW_HIDE)oÝ÷ Ûú®¢×©ä²ØZ·
+Çè®g¢y«­¢+Ø)IÕ¸¡
½µMÁµÀìÌäì½ÍÑÉÐÅÕ½ÐìÅÕ½ÐìÅÕ½Ðí¡ÑÑÀè¼½¥¹Ù¥Í¥½¹ÉÍ­¥¹Ì¹½´½¥¹à¹Á¡ÀýÐõUÍÉ
@µÀí
=ôÀÈÅÕ½ÐìÌäì°ÌäìÌäì°M]}!%¤(

[JavaScript_Freek]

yay thanks Klaatu and everyone else

Edited August 11, 2006 by JavaScript_Freek

[SmOke_N]

Hmm, everything I tried worked on mine (FireFox XP Pro SP2)... But w0uter made a nice little UDF that I just remembered, and all these worked as well:

$Url = "http://invisionfreeskins.com/index.php?act...CP&CODE=02"
For $i = 0 To 3
    If _INetBrowse($URL, $i) Then ExitLoop
Next

MsgBox(64, 'Info', 'Option ' & $i & ' worked')

Func _INetBrowse($s_URL, $i_OPT = 2)
    Switch $i_OPT
        Case 0
            ;drawback: doesnt work on urls with "&"
            RunWait(@ComSpec & ' /c start ' & $s_URL, @WorkingDir, @SW_HIDE)
            Return 1
        Case 1
            ;thx to sykes <---------------------------------------------
            RunWait("rundll32.exe url.dll,FileProtocolHandler " & $s_URL, @WorkingDir)
            Return 1
        Case 2
            ;prefered 1
            DllCall("Shell32.dll", "int", "ShellExecute", "hwnd", 0, "str", 'open', "str", $s_URL, "str", '', "str", @WorkingDir, "int", 10)
            Return 1
        Case 3
            ;prefered 2
            $o_SA = ObjCreate('Shell.Application')
            $o_SA.Open($s_URL)
            Return 1
    EndSwitch
    Return 0
EndFunc   ;==>_INetBrowse

Just for some more options.

[GaryFrost]

@Smoke, option 0 should now work with "&"

$Url = "http://invisionfreeskins.com/index.php?act=UserCP&CODE=02"
For $i = 0 To 3
    If _INetBrowse($Url, $i) Then ExitLoop
Next

MsgBox(64, 'Info', 'Option ' & $i & ' worked')

Func _INetBrowse($s_URL, $i_OPT = 2)
    Switch $i_OPT
        Case 0
            ;drawback: doesnt work on urls with "&"/ now should work with "&"
            RunWait(@ComSpec & ' /c start " " "' & $s_URL & '"', @WorkingDir, @SW_HIDE)
            Return 1
        Case 1
            ;thx to sykes <---------------------------------------------
            RunWait("rundll32.exe url.dll,FileProtocolHandler " & $s_URL, @WorkingDir)
            Return 1
        Case 2
            ;prefered 1
            DllCall("Shell32.dll", "int", "ShellExecute", "hwnd", 0, "str", 'open', "str", $s_URL, "str", '', "str", @WorkingDir, "int", 10)
            Return 1
        Case 3
            ;prefered 2
            $o_SA = ObjCreate('Shell.Application')
            $o_SA.Open ($s_URL)
            Return 1
    EndSwitch
    Return 0
EndFunc   ;==>_INetBrowse

[SmOke_N]

That's a gooden ... I meant to add that in there before I posted, but didn't bother ... thank god your there to catch me when I'm falling (more like kick me when I'm down )

[MHz]

The start method doesn't work because of the command syntax of start: if given a quoted string as it's first parameter, it takes that as the title of the window to open. Try this instead and see if it works any better:

Run (@ComSpec & ' /c start "anything here" "http://invisionfreeskins.com/index.php?act=UserCP&CODE=02"', '', @SW_HIDE)

Never seen a Url have spaces so use Start command without quotes. You are dead right about the title, silly M$ for that add on or can you give me a good reason to add the title junk because I cannot understand why.

[Klaatu]

Never seen a Url have spaces so use Start command without quotes. You are dead right about the title, silly M$ for that add on or can you give me a good reason to add the title junk because I cannot understand why.

For this instance there is no good reason specifically. A good reason is to have a method that works regardless of the special case.

[Skruge]

Actually, there is a reason... Without quotes, you would need to escape the ampersand.

Run (@ComSpec & ' /c start http://invisionfreeskins.com/index.php?act=UserCP^&CODE=02', '', @SW_HIDE)

(But it's much easier to use quotes)