Sliding Toolbar

ConsultingJoe · May 15, 2006

WOW This is amazing. Great job. Mad Props

Valuater · May 15, 2006

Wow, nice additions Valuater.. I really like it. I'll work on an animated Gif for your version of it today!
I think the next thing I'm going to add is if you drag the window close to one side or the other it will switch which side to snap to.
EDIT: and in your case, the position of the config button and the slider button will switch if it switches sides as well.

Great!!... and thanks Simucal!!

Nice and clean looking job on the original post

8)

Simucal · May 15, 2006

@Val,

Ok, here is how I thought we could do the side switching. The spacing on the left side of the toolbar isnt even with the right.. so it will have to be lengthed and all the controls moved over slightly. Let me know if you think there is a better way to do it:

EDIT: TEMP CODE REMOVED

Edited May 15, 2006 by Simucal

Valuater · May 15, 2006

Perfect... I couldn't have done any better on that

good job!

8)

ConsultingJoe · May 15, 2006

Perfect... I couldn't have done any better on that
good job!
8)

Wow, I didnt think it could get better, But, it did. Great man

AutoItKing · May 15, 2006

Great job!

Edited May 15, 2006 by AutoItKing

Valuater · May 15, 2006

here is another approach... just bored

#include <GUIConstants.au3>

Global $Button_[8], $Label_[8], $config_[8]
Dim $Max = 350
Dim $Child_[8], $Top = 100, $y_pos[8]

If Not FileExists(@ScriptDir & "\toolbar.ini") Then Create_ini()
$Label_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Label")
$Launch_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Launch")

For $x = 1 To 7
    $y_pos[$x] = $Top + 30
    $Child_[$x] = GUICreate("", 100, 25, 2, $Top + 30, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
    $Button_[$x] = GUICtrlCreateButton($Label_name[$x][1], -2, -1, 102, 27)
    GUISetState()
    DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $Child_[$x], "int", 350, "long", 0x00050002);slide out to left
    $Top = $Top + 30
Next

While 1
    $msg1 = GUIGetMsg()
    If $msg1 = $GUI_EVENT_CLOSE Then Exit
    $a_loc = 10
    $a_mpos = MouseGetPos()
    For $b = 1 To 7
        If $a_mpos[1] <= $y_pos[$b] + 25 And $a_mpos[1] >= $y_pos[$b] And $a_mpos[0] <= $a_loc Then
            DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $Child_[$b], "int", 350, "long", 0x00040001);slide in from left
            $a_loc = 100
            While $a_mpos[1] <= $y_pos[$b] + 25 And $a_mpos[1] >= $y_pos[$b] And $a_mpos[0] <= $a_loc
                $msg = GUIGetMsg()
                If $msg = $Button_[$b] Then
                    Function($B)
                    ExitLoop
                EndIf
                $a_mpos = MouseGetPos()
            WEnd
            DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $Child_[$b], "int", 350, "long", 0x00050002);slide out to left
        EndIf
    Next
WEnd

Func Create_ini()
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 1, @ProgramFilesDir & "\Internet Explorer\iexplore.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 2, @SystemDir & "\osk.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 3, @ProgramFilesDir & "\Windows Media Player\wmplayer.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 4, @SystemDir & "\notepad.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 5, @SystemDir & "\calc.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 6, @SystemDir & "\mstsc.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 7, @SystemDir & "\cleanmgr.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 1, "IE Explorer")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 2, "Keyboard")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 3, "Media Player")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 4, "Notepad")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 5, "Calculator")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 6, "Net Service")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 7, "Clean Mngr")
EndFunc  ;==>Create_ini

Func Function(ByRef $B)
    If FileExists($Launch_name[$b][1]) Then
        $LFile = FileGetShortName($Launch_name[$b][1])
        Run($LFile)
    Else
        MsgBox(262208, "Sorry!", "The file location could not be verified   ", 4)
    EndIf
EndFunc  ;==>Function

8)

Edited May 17, 2006 by Valuater

Simucal · May 16, 2006

That gives me some ideas Val.. I like that. I'm going to play with that tonight for a horizontal toolbar.

Vollyman made a good suggestion that we should have a button that would allow the sliding toolbar to just be "out" and not snap to the side. I'll implement that once I finish the snap to both sides and spacing issues. Any ideas on where the button would go?

I might make another one that mimicks the behavior of the Mac OSX toolbar.. when you click a button/icon it will bounce in place for half a second or so.. and all the buttons size change with the one under the mouse being the largest and smaller from there on out.

Valuater · May 16, 2006

Any ideas on where the button would go?

on the congif GUI, there could be a checkbox or two

8)

Hooch · May 16, 2006

Loves it....

My only problem with it is that in a dual monitor config it snaps to the left side of the main monitor but my secondary in on the left, so the "hidden" portion of the bar is visible on the second monitor..

Simucal · May 16, 2006

Loves it....
My only problem with it is that in a dual monitor config it snaps to the left side of the main monitor but my secondary in on the left, so the "hidden" portion of the bar is visible on the second monitor..

Yea, I just started using dual monitors and noticed this. I'll fix it in the next release with the snap-to on both sides, config menu.. etc.

Valuater · May 16, 2006

best one i have ever seen... REALLY

Posted Image

and its free

ObjectDock

I just didn't like how BIG it is... but it has alot of stuff and capabilities too!

Multi-Monitor Support... if you buy the plus version

8)

Edited May 16, 2006 by Valuater

Simucal · May 16, 2006

best one i have ever seen... REALLY
and its free
ObjectDock
8)

Thanks valuater. A similar effect is my goal. I'm goign to download it to play with it a bit.

jaenster · May 17, 2006

Perfect script to add in your "include" map

Simucal · May 17, 2006

Perfect script to add in your "include" map

Sorry.. I dont understand. What include map?

slightly_abnormal · May 17, 2006

great job guys..

Have you guys seen launchtab, that should give you more ideas

oh and objectdock is like a clone of Yzdock(FREE), which RKlauncher(FREE) is based off.

Edited May 17, 2006 by slightly_abnormal

Valuater · May 18, 2006

Thanks valuater. A similar effect is my goal. I'm goign to download it to play with it a bit.

?????... what happened... the dock is so nice.. dont think we can compete????

'''''''''''''''''''''''''''''''''

well anyways.... added trasnparency

#include <GUIConstants.au3>
Global $hide_state = 0, $btn_state = 0, $pass = 0
Global $Button_[8], $Label_[8], $config_[12]

If Not FileExists(@ScriptDir & "\toolbar.ini") Then Create_ini()
$config_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Config")
If Not IsArray($config_name) Then; this is for older versions retro use
    IniWrite(@ScriptDir & "\toolbar.ini", "Config", 1, "255")
    IniWrite(@ScriptDir & "\toolbar.ini", "Config", 2,  "0"); 0 = left / 1 = right
    $config_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Config")
EndIf
$Label_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Label")
$Launch_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Launch")

$hwnd= GUICreate("Sliding Launcher", 603, 85, -588, -1, -1,  BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW, $WS_EX_ACCEPTFILES)) 
$config_[1] = GUICtrlCreateLabel("Label Name", 15, 22, 60, 20)
$config_[2] = GUICtrlCreateInput("", 75, 22, 80, 20)
$config_[3] = GUICtrlCreateLabel("Program to Launch", 175, 22, 100, 20)
$config_[4] = GUICtrlCreateInput("", 270, 20, 255, 20)
GUICtrlSetState( -1, $GUI_DROPACCEPTED )
$config_[5] = GUICtrlCreateButton("Cancel", 530, 5, 50, 20)
$config_[6] = GUICtrlCreateButton("Browse", 530, 30, 50, 20)
$config_[7] = GUICtrlCreateButton("Accept", 530, 55, 50, 20)
$config_[8] = GUICtrlCreateSlider(270, 50, 255, 20)
GUICtrlSetLimit($config_[8], 255, 200)
GUICtrlSetData($config_[8], $config_name[1][1])
$config_[9] = GUICtrlCreateRadio("Left Justify", 18, 50)
If $config_name[2][1] = 0 Then GUICtrlSetState( $config_[9], $GUI_CHECKED)
$config_[10] = GUICtrlCreateRadio("Right Justify", 95, 50)
If $config_name[2][1] = 1 Then GUICtrlSetState( $config_[10], $GUI_CHECKED)
$config_[11] = GUICtrlCreateLabel("Transparency", 195, 53, 80, 20)

GUICtrlSetState( $config_[10], $GUI_DISABLE); not developed yet

For $x = 1 To 11
    GUICtrlSetState($config_[$x], $GUI_HIDE)
Next
$author = GUICtrlCreateLabel(" By...   Simucal  &&  Valuater", 120, 25, 400, 40)
GUICtrlSetFont(-1, 20, 700)
$Show = GUICtrlCreateButton(">", 585, 8, 17, 70, BitOR($BS_CENTER, $BS_FLAT))
GUISetState(@SW_HIDE, $hwnd)
WinSetTrans($hwnd, "",$config_name[1][1])

$hwnd2 = GUICreate("Sliding Launcher", 603, 85, 3, -1, -1, BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
$Button_[1] = GUICtrlCreateButton("", 20, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[1][1])
$Label_[1] = GUICtrlCreateLabel($Label_name[1][1], 20, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Button_[2] = GUICtrlCreateButton("", 100, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[2][1])
$Label_[2] = GUICtrlCreateLabel($Label_name[2][1], 100, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Button_[3] = GUICtrlCreateButton("", 180, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[3][1])
$Label_[3] = GUICtrlCreateLabel($Label_name[3][1], 180, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Button_[4] = GUICtrlCreateButton("", 260, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[4][1])
$Label_[4] = GUICtrlCreateLabel($Label_name[4][1], 260, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Button_[5] = GUICtrlCreateButton("", 340, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[5][1])
$Label_[5] = GUICtrlCreateLabel($Label_name[5][1], 340, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Button_[6] = GUICtrlCreateButton("", 420, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[6][1])
$Label_[6] = GUICtrlCreateLabel($Label_name[6][1], 420, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Button_[7] = GUICtrlCreateButton("", 500, 35, 73, 41, $BS_ICON)
GUICtrlSetImage(-1, $Launch_name[7][1])
$Label_[7] = GUICtrlCreateLabel($Label_name[7][1], 500, 8, 73, 17, $SS_CENTER + $SS_SUNKEN)
$Hide = GUICtrlCreateButton("<", 585, 8, 17, 70, BitOR($BS_CENTER, $BS_FLAT, $BS_MULTILINE))
$Edit = GUICtrlCreateButton("[]", 0, 8, 15, 70, BitOR($BS_CENTER, $BS_FLAT, $BS_MULTILINE))
GUICtrlSetTip(-1, "Config")
DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hwnd2, "int", 500, "long", 0x00040001);slide in from left
GUISetState()
Sleep(100)
WinSetTrans($hwnd2, "",$config_name[1][1])

Opt("TrayMenuMode", 1)
Opt("TrayOnEventMode", 1)
$config_tray = TrayCreateItem("Configure...")
TrayItemSetOnEvent(-1, "Set_config")
TrayCreateItem("")
$exit_tray = TrayCreateItem("Exit  Sliding Launcher")
TrayItemSetOnEvent(-1, "Set_Exit")
TraySetState()

While 1
    $msg1 = GUIGetMsg()
    If $msg1 = $GUI_EVENT_CLOSE Then Exit
    If $msg1 = $Hide Then
        If $pass = 1 Then
            WinSetTitle($hwnd2, "", "Sliding Launcher")
            $pass = 0
        Else
            Slide_out()
        EndIf
    EndIf
    If $msg1 = $Show Then Slide_in()
    If $msg1 = $Edit Then $pass = 1
    $a_pos = WinGetPos($hwnd2)
    $a_pos2 = WinGetPos($hwnd)
    If $a_pos[0] <> 0 And $hide_state = 0 Then
        WinMove($hwnd2, "", 3, $a_pos[1])
        WinMove($hwnd, "", -588, $a_pos[1])
    EndIf
    If $a_pos2[0] <> - 588 And $hide_state = 1 Then
        WinMove($hwnd, "", -588, $a_pos2[1])
        WinMove($hwnd2, "", 3, $a_pos2[1])
    EndIf
    If $pass = 1 Then WinSetTitle($hwnd2, "", "Config Mode - Please Press the Button to Configure...  Press  ""<""  to Cancel")
    If $hide_state = 0 Then
        $a_mpos = GUIGetCursorInfo($hwnd2)
        If IsArray($a_mpos) = 1 Then
            For $b = 1 To 7
                If $a_mpos[4] = $Button_[$b] Then
                    If $b = 1 Then $left = 15
                    If $b > 1 Then $left = (($b - 1) * 80) + 15
                    GUICtrlSetPos($Button_[$b], $left, 30, 83, 46)
                    GUICtrlSetColor($Label_[$b], 0xff0000)
                    GUICtrlSetCursor($Button_[$b], 0)
                    While $a_mpos[4] = $Button_[$b]
                        $msg = GUIGetMsg()
                        If $msg = $Button_[$b] Then
                            If $pass = 0 Then
                                Function($b)
                                ExitLoop
                            Else
                                Set_ini($b)
                                ExitLoop
                            EndIf
                        EndIf
                        $a_mpos = GUIGetCursorInfo($hwnd2)
                        If IsArray($a_mpos) <> 1 Then ExitLoop
                    WEnd
                    $left = $left + 5
                    GUICtrlSetPos($Button_[$b], $left, 35, 73, 41)
                    GUICtrlSetColor($Label_[$b], 0x000000)
                EndIf
            Next
        EndIf
    EndIf
WEnd

Func Slide_in()
    $hide_state = 0
    GUISetState(@SW_HIDE, $hwnd)
    DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hwnd2, "int", 500, "long", 0x00040001);slide in from left
    WinActivate($hwnd2)
    WinWaitActive($hwnd2)
EndFunc ;==>Slide_in

Func Slide_out()
    $hide_state = 1
    DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hwnd2, "int", 500, "long", 0x00050002);slide out to left
    GUISetState(@SW_SHOW, $hwnd)
    WinActivate($hwnd)
    WinWaitActive($hwnd)
EndFunc ;==>Slide_out

Func Create_ini()
    IniWrite(@ScriptDir & "\toolbar.ini", "Config", 1, "255")
    IniWrite(@ScriptDir & "\toolbar.ini", "Config", 2,  "0"); 0 = left / 1 = right
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 1, @ProgramFilesDir & "\Internet Explorer\iexplore.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 2, @SystemDir & "\osk.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 3, @ProgramFilesDir & "\Windows Media Player\wmplayer.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 4, @SystemDir & "\notepad.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 5, @SystemDir & "\calc.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 6, @SystemDir & "\mstsc.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", 7, @SystemDir & "\cleanmgr.exe")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 1, "IE Explorer")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 2, "Keyboard")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 3, "Media Player")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 4, "Notepad")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 5, "Calculator")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 6, "Net Service")
    IniWrite(@ScriptDir & "\toolbar.ini", "Label", 7, "Clean Mngr")
EndFunc ;==>Create_ini

Func Set_ini(ByRef $b)
    Slide_out()
    GUICtrlSetState($author, $GUI_HIDE)
    GUICtrlSetState($Show, $GUI_HIDE)
    For $x = 1 To 11
        GUICtrlSetState($config_[$x], $GUI_SHOW)
    Next
    Sleep(50)
    WinSetTrans($hwnd, "", 0)
    WinMove($hwnd, "", 3, $a_pos[1])
    GUICtrlSetData($config_[2], $Label_name[$b][1])
    GUICtrlSetData($config_[4], $Launch_name[$b][1])
    GUICtrlSetState($config_[4], $GUI_DROPACCEPTED )
    For $x = 1 To $config_name[1][1] Step 3
        WinSetTrans($hwnd, "", $x)
        Sleep(1)
    Next
    While 3
        $a_pos = WinGetPos($hwnd)
        WinMove($hwnd, "", 3, $a_pos[1])
        WinMove($hwnd2, "", 3, $a_pos[1])
        $msg3 = GUIGetMsg()
        If $msg3 = $config_[8] Then
            WinSetTrans($hwnd, "", GUICtrlRead($config_[8]))
            WinSetTrans($hwnd2, "", GUICtrlRead($config_[8]))
        EndIf
        If $msg3 = $GUI_EVENT_CLOSE Then Exit
        If $msg3 = $config_[5] Then ExitLoop
        If $msg3 = $config_[6] Then
            $Find = FileOpenDialog("Please Select a Program to Launch", @ProgramFilesDir, "exe (*.exe)", 1 + 2)
            If Not @error = 1 Then GUICtrlSetData($config_[4], $Find)
        EndIf
        If $msg3 = $config_[7] Then
            $temp_info = GUICtrlRead($config_[4])
            If FileExists($temp_info) Then
                If StringInStr($temp_info, ".lnk") Then
                    $details = FileGetShortcut($temp_info)
                    $temp_info = $details[0]
                EndIf
                If StringInStr($temp_info, ".exe") Then
                    IniWrite(@ScriptDir & "\toolbar.ini", "Config", 1, GUICtrlRead($config_[8]))
                    If BitAnd(GUICtrlRead($config_[9]),$GUI_CHECKED) = $GUI_CHECKED then
                        IniWrite(@ScriptDir & "\toolbar.ini", "Config", 2, "0"); 0 = left / 1 = right
                    Else
                        IniWrite(@ScriptDir & "\toolbar.ini", "Config", 2, "1"); 0 = left / 1 = right
                    EndIf
                    IniWrite(@ScriptDir & "\toolbar.ini", "Launch", $b, $temp_info)
                    IniWrite(@ScriptDir & "\toolbar.ini", "Label", $b, (GUICtrlRead($config_[2])))
                    $config_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Config")
                    $Label_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Label")
                    $Launch_name = IniReadSection(@ScriptDir & "\toolbar.ini", "Launch")
                    For $x = 1 To 7
                        GUICtrlSetData($Label_[$x], $Label_name[$x][1])
                        GUICtrlSetImage($Button_[$x], $Launch_name[$x][1])
                    Next
                    ExitLoop
                Else
                    MsgBox(262208, "Sorry!", "The ""exe"" file could not be verified   ", 4)
                EndIf
            Else
                MsgBox(262208, "Sorry!", "The file location could not be verified   ", 4)
            EndIf
        EndIf
    WEnd
    For $x = 1 To 11
        GUICtrlSetState($config_[$x], $GUI_HIDE)
    Next
    GUICtrlSetState($author, $GUI_SHOW)
    Sleep(300)
    For $x = $config_name[1][1] To 1 Step - 3
        WinSetTrans($hwnd, "", $x)
        Sleep(1)
    Next
    
    WinMove($hwnd, "", -588, $a_pos[1])
    GUICtrlSetState($Show, $GUI_SHOW)
    WinSetTrans($hwnd, "", $config_name[1][1])
    Slide_in()
EndFunc ;==>Set_ini

Func Function(ByRef $b)
    Slide_out()
    If FileExists($Launch_name[$b][1]) Then
        $LFile = FileGetShortName($Launch_name[$b][1])
        Run($LFile)
    Else
        MsgBox(262208, "Sorry!", "The file location could not be verified   ", 4)
    EndIf
EndFunc ;==>Function

Func Set_Exit()
    Exit
EndFunc ;==>Set_Exit

Func Set_Config()
    $a_pos = WinGetPos($hwnd)
    If $a_pos[0] = 3 Then Return
    Slide_in()
    $pass = 1
EndFunc ;==>Set_Exit

if the transparency to too light,,, the re-draw of the sliding window has some problems.. redrawing, of-course

8)

Edited May 18, 2006 by Valuater

AutoItKing · May 19, 2006

I changed it a little! Check it out here. Have fun!

PS: You MUST extract the files for it to work!

Edited September 18, 2006 by AutoItKing

Paulie · May 19, 2006

Wow, am i glad i belong to this forum,

im surrounded by overwhelming intellegence

Anyway,

Great Job Guys, I have 2 of your toolbars running, as well as YzDock Its great, I love A clean desktop.

Edited May 19, 2006 by Paulie

Valuater · May 21, 2006

I changed it a little! Check it out here. Have fun!
PS: You HAVE to extract the files for it to work!

nice king... a double layer

8)

Sliding Toolbar

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

Simucal

GreenCan

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members