If I have a Const variable, can I delete it?

[DannyJ]

I declared a const array, that I won't change and I can not change in the entire program. (Safety)

Exept one point, one point I need to change this variable.

My question is that can I delete the const variable and redeclare it?

Or I need to remove Const to change the variable.

If I remove const how can I make my variable "safe", because this variable can not be changed only the declaration and one point in the whole program.

Thanks in advance!

[Nine]

You cannot redefine/delete a Const within the same scope.  But you can if you change the scope too.

#include <Array.au3>

Global Const $aConst[3] = [1,2,3]
_ArrayDisplay($aConst)

DoIt()

Func DoIt()
  Local $aConst[4] = [4,5,6,7]
  _ArrayDisplay($aConst)
EndFunc

This is one way to override the previous declaration of a variable.

[water]

Setting a variable/Array to Const is kind of a security measure to prevent unintended modification.
Remove Const and do the "security" checking yourself.

When you are ready to put your script into production scan the code for the name of the array and make sure that none of the found lines changes the array.
Have a careful look at parameters as the name of the array parameter might change.

[LarsJ]

#AutoIt3Wrapper_Au3Check_Parameters=-d -w- 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#AutoIt3Wrapper_UseX64=Y

Opt( "MustDeclareVars", 1 )

Example()

Func Example()
  Local $oDict = ObjCreate( "Scripting.Dictionary" )
  $oDict.Item( "Int" ) = 1
  $oDict.Item( "Flt" ) = 1.1
  $oDict.Item( "Str" ) = "One"
  Local Const $aArray[1] = [ $oDict ] ; Local Const
  $oDict = 0
  ConsoleWrite( "$aArray[0].Item( ""Int"" ) = " & $aArray[0].Item( "Int" ) & @CRLF )
  ConsoleWrite( "$aArray[0].Item( ""Flt"" ) = " & $aArray[0].Item( "Flt" ) & @CRLF )
  ConsoleWrite( "$aArray[0].Item( ""Str"" ) = " & $aArray[0].Item( "Str" ) & @CRLF & @CRLF )

  Local $oMyDict = $aArray[0]
  $oMyDict.Item( "Int" ) = 2
  $oMyDict.Item( "Flt" ) = 2.2
  $oMyDict.Item( "Str" ) = "Two"
  $oMyDict = 0
  ConsoleWrite( "$aArray[0].Item( ""Int"" ) = " & $aArray[0].Item( "Int" ) & @CRLF )
  ConsoleWrite( "$aArray[0].Item( ""Flt"" ) = " & $aArray[0].Item( "Flt" ) & @CRLF )
  ConsoleWrite( "$aArray[0].Item( ""Str"" ) = " & $aArray[0].Item( "Str" ) & @CRLF & @CRLF )
EndFunc

Console output:

$aArray[0].Item( "Int" ) = 1
$aArray[0].Item( "Flt" ) = 1.1
$aArray[0].Item( "Str" ) = One

$aArray[0].Item( "Int" ) = 2
$aArray[0].Item( "Flt" ) = 2.2
$aArray[0].Item( "Str" ) = Two

 

[argumentum]

5 hours ago, DannyJ said:

how can I make my variable "safe"

Well, you're the coder. Declaring a value, is a value. If you where, in say C, the Const goes in a different memory space than a variable but, you're in AutoIt. Here it makes no difference. Just don't overwrite/assign other values to it. That's all.