#AutoIt3Wrapper_UseX64=N
#AutoIt3Wrapper_Run_AU3Check=Y
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#Tidy_Parameters=/sort_funcs /reel

#include <AutoItConstants.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include "GDPR.au3"

Global Const $EMAIL_CONFIG_GUID = '{E07288CC-1BE0-4A49-BF46-8BA29B64DBF1}'

Global Enum _
		$EMAIL_CONFIG__00__GUID, _
		$EMAIL_CONFIG__01__GUI_TITLE, _
		$EMAIL_CONFIG__02__COMMON_NAME, _
		$EMAIL_CONFIG__03__EMAIL_ADDRESS, _
		$EMAIL_CONFIG__04__POPIMAP_TYPE, _
		$EMAIL_CONFIG__05__GUI_POPIMAP_TITLE, _
		$EMAIL_CONFIG__06__GUI_SMTP_TITLE, _
		$EMAIL_CONFIG__07__GUI_SAVE, _
		$EMAIL_CONFIG__08__GUI_CLOSE, _
		$EMAIL_CONFIG__09__SECURITY_SETTING, _
		$EMAIL_CONFIG__10__POPIMAP_USER_NAME = 10, _
		$EMAIL_CONFIG__11__POPIMAP_PASSWORD, _
		$EMAIL_CONFIG__12__POPIMAP_SERVER_NAME, _
		$EMAIL_CONFIG__13__POPIMAP_PORT_NUMBER, _
		$EMAIL_CONFIG__14__POPIMAP_ENCRYPTION, _
		$EMAIL_CONFIG__15__POPIMAP_AUTHENTICATION, _
		$EMAIL_CONFIG__20__SMTP_USER_NAME = 20, _
		$EMAIL_CONFIG__21__SMTP_PASSWORD, _
		$EMAIL_CONFIG__22__SMTP_SERVER_NAME, _
		$EMAIL_CONFIG__23__SMTP_PORT_NUMBER, _
		$EMAIL_CONFIG__24__SMTP_ENCRYPTION, _
		$EMAIL_CONFIG__25__SMTP_AUTHENTICATION, _
		$EMAIL_CONFIG__XX__COUNTER

Global Enum _
		$EMAIL_CONFIG__COL0_Name, _
		$EMAIL_CONFIG__COL1_ControlID, _
		$EMAIL_CONFIG__COL2_SAVELOAD_NAME, _
		$EMAIL_CONFIG__COL3_SAVELOAD_VALUE, _
		$EMAIL_CONFIG__COLX_COUNTER

__EmailConfig__API(Null) ; Clear at startup

#Region - EmailConfig.au3 - Functions

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __EmailConfig_GUI_FillTheForm
; Description ...: Fill the GUI Form with language/configuration stored in __EmailConfig__API()
; Syntax ........: __EmailConfig_GUI_FillTheForm()
; Parameters ....: None
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......: __EmailConfig__API()
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __EmailConfig_GUI_FillTheForm()
	Local $aEMAIL_CONFIG = __EmailConfig__API()
	For $iRow_idx = 0 To $EMAIL_CONFIG__XX__COUNTER - 1
		If $aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL3_SAVELOAD_VALUE] <> '' Then
			GUICtrlSetData($aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL1_ControlID], $aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL3_SAVELOAD_VALUE])
		EndIf
	Next
EndFunc   ;==>__EmailConfig_GUI_FillTheForm

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_GUI_Preset_DE
; Description ...: Preset GUI Language/Configuration
; Syntax ........: _EmailConfig_GUI_Preset_DE()
; Parameters ....:
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......: ; Thanks to @water for translation
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_GUI_Preset_DE()
	__EmailConfig__API(Null)
	_EmailConfig_LanguageSetUp__MAIN_GUI('Email-Konfiguration', 'Email-Kontoname', 'Email-Adresse', 'Wählen Sie den Verbindungstyp', 'POP / IMAP Konfiguration', 'SMTP Konfiguration', 'Sichern', 'Schließen')
	_EmailConfig_LanguageSetUp__PROTOCOLS('Benutzer', 'Passwort', 'Serveradresse', 'Port', 'Sicherheitseinstellungen', 'Verbindungssicherheit', 'Authentifizierungs-Methode')
	_EmailConfig_LanguageSetUp__POPIMAP_Encryption('Keine Verschlüsselung|STARTTLS|TLS/SSL')
	_EmailConfig_LanguageSetUp__POPIMAP_Authentication('Normales Passwort|Verschlüsseltes Password|Kerberos / GSSAPI|NTLM|TLS Zertifikat|OAuth2')
	_EmailConfig_LanguageSetUp__SMTP_Encryption('Keine Verschlüsselung|STARTTLS|STARTTLS falls verfügbar|TLS/SSL')
	_EmailConfig_LanguageSetUp__SMTP_Authentication('Keine Authentifizierung|Normales Passwort|Passwort in Klartext|Verschlüsseltes Passwort|Kerberos / GSSAPI|NTLM')
EndFunc   ;==>_EmailConfig_GUI_Preset_DE

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_GUI_Preset_EN
; Description ...: Preset GUI Language/Configuration
; Syntax ........: _EmailConfig_GUI_Preset_EN()
; Parameters ....:
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......: ; Thanks to https://translate.google.pl/ for translation
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_GUI_Preset_EN()
	__EmailConfig__API(Null)
	_EmailConfig_LanguageSetUp__MAIN_GUI('Email configuration', 'Email account name', 'Email address', 'Choose connection type', 'POP / IMAP configuration', 'SMTP configuration', 'Save', 'Close')
	_EmailConfig_LanguageSetUp__PROTOCOLS('User', 'Password', 'Server address', 'Port', 'Security settings', 'Connection security', 'Authentication method')
	_EmailConfig_LanguageSetUp__POPIMAP_Encryption('No encryption|STARTTLS|TLS/SSL')
	_EmailConfig_LanguageSetUp__POPIMAP_Authentication('Normal Password|Encrypted Password|Kerberos / GSSAPI|NTLM|TLS Certificate|OAuth2')
	_EmailConfig_LanguageSetUp__SMTP_Encryption('No encryption|STARTTLS|STARTTLS if available|TLS/SSL')
	_EmailConfig_LanguageSetUp__SMTP_Authentication('No authentication|Normal password|Password sent in plain text|Encrypted password|Kerberos / GSSAPI|NTLM')
EndFunc   ;==>_EmailConfig_GUI_Preset_EN

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_GUI_Preset_FR
; Description ...: Preset GUI Language/Configuration
; Syntax ........: _EmailConfig_GUI_Preset_FR()
; Parameters ....:
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......: Thanks to @jchd for translation
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_GUI_Preset_FR()
	__EmailConfig__API(Null)
	_EmailConfig_LanguageSetUp__MAIN_GUI('Configuration e-mail', "Nom d'utilisateur", 'Adresse e-mail', 'Choix du type de connexion', 'Configuration POP / IMAP', 'Configuration SMTP', 'Sauvegarder', 'Fermer')
	_EmailConfig_LanguageSetUp__PROTOCOLS('Utilisateur', 'Mot de passe', 'Adresse du serveur', 'Port', 'Paramètres de sécurité', 'Sécurité de connexion', "Méthode d'authentification")
	_EmailConfig_LanguageSetUp__POPIMAP_Encryption('Sans chiffrement|STARTTLS|TLS/SSL')
	_EmailConfig_LanguageSetUp__POPIMAP_Authentication('Mot de passe en clair|Mot de passe chiffré|Kerberos / GSSAPI|NTLM|Certificat TLS|OAuth2')
	_EmailConfig_LanguageSetUp__SMTP_Encryption('Sans chiffrement|STARTTLS|STARTTLS si disponible|TLS/SSL')
	_EmailConfig_LanguageSetUp__SMTP_Authentication("Pas d'authentification|Mot de passe|Mot de passe en clair|Mot de passe chiffré|Kerberos / GSSAPI|NTLM")
EndFunc   ;==>_EmailConfig_GUI_Preset_FR

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_GUI_Preset_NL
; Description ...: Preset GUI Language/Configuration
; Syntax ........: _EmailConfig_GUI_Preset_NL()
; Parameters ....:
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......: Thanks to @jos for translation
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_GUI_Preset_NL()
	__EmailConfig__API(Null)
	_EmailConfig_LanguageSetUp__MAIN_GUI('Email configuratie', 'Email gebruikersnaam', 'Email adres', 'Kies verbindingstype', 'POP / IMAP configuratie', 'SMTP configuratie', 'Opslaan', 'Sluiten')
	_EmailConfig_LanguageSetUp__PROTOCOLS('Gebruiker', 'Wachtwoord', 'Server adres', 'Poort', 'Beveiligingsinstelling', 'Verbindingsbeveiliging', 'Authenticatie methode')
	_EmailConfig_LanguageSetUp__POPIMAP_Encryption('geen |STARTTLS|TLS/SSL')
	_EmailConfig_LanguageSetUp__POPIMAP_Authentication('Normaal Paswoord|Versleuteld Paswoord|Kerberos / GSSAPI|NTLM|TLS Certificate|OAuth2')
	_EmailConfig_LanguageSetUp__SMTP_Encryption('geen versleuteling|STARTTLS|STARTTLS wanneer beschikbaar|TLS/SSL')
	_EmailConfig_LanguageSetUp__SMTP_Authentication('Geen authenticatie|Normaal paswoord|wachtwoord in text|Versleuteld wachtwoord|Kerberos / GSSAPI|NTLM')
EndFunc   ;==>_EmailConfig_GUI_Preset_NL

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_GUI_Preset_PL
; Description ...: Preset GUI Language/Configuration
; Syntax ........: _EmailConfig_GUI_Preset_PL()
; Parameters ....:
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......: Thanks to @mLipok for creation in likeness ThunderBird
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_GUI_Preset_PL()
	__EmailConfig__API(Null)
	_EmailConfig_LanguageSetUp__MAIN_GUI('Konfiguracja poczty email', 'Nazwa konta email', 'Adres email', "Wybierz typ połączenia", 'Konfiguracja POP/IMAP', 'Konfiguracja SMTP', 'Zapisz', 'Zamknij')
	_EmailConfig_LanguageSetUp__PROTOCOLS('Użytkownik', 'Hasło', 'Adres serwera', 'Port', 'Ustawienia zabezpieczeń', 'Bezpieczeństwo połączenia', 'Metoda uwierzytelniania')
	_EmailConfig_LanguageSetUp__POPIMAP_Encryption("Bez szyfrowania|STARTTLS|TLS/SSL")
	_EmailConfig_LanguageSetUp__POPIMAP_Authentication('Normalne hasło|Szyfrowane hasło|Kerberos / GSSAPI|NTLM|Certyfikat TLS|OAuth2')
	_EmailConfig_LanguageSetUp__SMTP_Encryption('Bez szyfrowania|STARTTLS|STARTTLS, jeśli dostępne|TLS/SSL')
	_EmailConfig_LanguageSetUp__SMTP_Authentication('Bez uwierzytelniania|Normalne hasło|Hasło przesyłane otwartym tekstem|Szyfrowane hasło|Kerberos / GSSAPI|NTLM')
EndFunc   ;==>_EmailConfig_GUI_Preset_PL

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LanguageSetUp__MAIN_GUI
; Description ...:
; Syntax ........: _EmailConfig_LanguageSetUp__MAIN_GUI($sParam_01__GUI_TITLE, $sParam_02__COMMON_NAME,
;                  $sParam_03__EMAIL_ADDRESS, $sParam_04__POPIMAP_TYPE, $sParam_05__GUI_POPIMAP_TITLE,
;                  $sParam_06__GUI_SMTP_TITLE, $sParam_07__GUI_SAVE, $sParam_08__GUI_CLOSE)
; Parameters ....: $sParam_01__GUI_TITLE- a string value.
;                  $sParam_02__COMMON_NAME- a string value.
;                  $sParam_03__EMAIL_ADDRESS- a string value.
;                  $sParam_04__POPIMAP_TYPE- a string value.
;                  $sParam_05__GUI_POPIMAP_TITLE- a string value.
;                  $sParam_06__GUI_SMTP_TITLE- a string value.
;                  $sParam_07__GUI_SAVE - a string value.
;                  $sParam_08__GUI_CLOSE- a string value.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LanguageSetUp__MAIN_GUI($sParam_01__GUI_TITLE, $sParam_02__COMMON_NAME, $sParam_03__EMAIL_ADDRESS, $sParam_04__POPIMAP_TYPE, $sParam_05__GUI_POPIMAP_TITLE, $sParam_06__GUI_SMTP_TITLE, $sParam_07__GUI_SAVE, $sParam_08__GUI_CLOSE)
	Local $aEMAIL_CONFIG = __EmailConfig__API()
	$aEMAIL_CONFIG[$EMAIL_CONFIG__01__GUI_TITLE][$EMAIL_CONFIG__COL0_Name] = $sParam_01__GUI_TITLE
	$aEMAIL_CONFIG[$EMAIL_CONFIG__02__COMMON_NAME][$EMAIL_CONFIG__COL0_Name] = $sParam_02__COMMON_NAME
	$aEMAIL_CONFIG[$EMAIL_CONFIG__03__EMAIL_ADDRESS][$EMAIL_CONFIG__COL0_Name] = $sParam_03__EMAIL_ADDRESS
	$aEMAIL_CONFIG[$EMAIL_CONFIG__04__POPIMAP_TYPE][$EMAIL_CONFIG__COL0_Name] = $sParam_04__POPIMAP_TYPE
	$aEMAIL_CONFIG[$EMAIL_CONFIG__05__GUI_POPIMAP_TITLE][$EMAIL_CONFIG__COL0_Name] = $sParam_05__GUI_POPIMAP_TITLE
	$aEMAIL_CONFIG[$EMAIL_CONFIG__06__GUI_SMTP_TITLE][$EMAIL_CONFIG__COL0_Name] = $sParam_06__GUI_SMTP_TITLE
	$aEMAIL_CONFIG[$EMAIL_CONFIG__07__GUI_SAVE][$EMAIL_CONFIG__COL0_Name] = $sParam_07__GUI_SAVE
	$aEMAIL_CONFIG[$EMAIL_CONFIG__08__GUI_CLOSE][$EMAIL_CONFIG__COL0_Name] = $sParam_08__GUI_CLOSE
	__EmailConfig__API($aEMAIL_CONFIG)
EndFunc   ;==>_EmailConfig_LanguageSetUp__MAIN_GUI

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LanguageSetUp__POPIMAP_Authentication
; Description ...:
; Syntax ........: _EmailConfig_LanguageSetUp__POPIMAP_Authentication([$sCoding = Default])
; Parameters ....: $sCoding             - [optional] a string value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LanguageSetUp__POPIMAP_Authentication($sCoding = Default)
	Local Static $sCoding_static = ''
	If $sCoding = Default Then Return $sCoding_static

	$sCoding_static = $sCoding
EndFunc   ;==>_EmailConfig_LanguageSetUp__POPIMAP_Authentication

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LanguageSetUp__POPIMAP_Encryption
; Description ...:
; Syntax ........: _EmailConfig_LanguageSetUp__POPIMAP_Encryption([$sEncryption = Default])
; Parameters ....: $sEncryption         - [optional] a string value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LanguageSetUp__POPIMAP_Encryption($sEncryption = Default)
	Local Static $sEncryption_static = ''
	If $sEncryption = Default Then Return $sEncryption_static

	$sEncryption_static = $sEncryption
EndFunc   ;==>_EmailConfig_LanguageSetUp__POPIMAP_Encryption

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LanguageSetUp__PROTOCOLS
; Description ...:
; Syntax ........: _EmailConfig_LanguageSetUp__PROTOCOLS($sParam_10_USER_NAME, $sParam_11_PASSWORD, $sParam_12_SERVER_NAME,
;                  $sParam_13_PORT_NUMBER, $sParam_14__SECURITY_SETTING, $sParam_15_ENCRYPTION, $sParam_16_AUTHENTICATION)
; Parameters ....: $sParam_10_USER_NAME - a string value.
;                  $sParam_11_PASSWORD  - a string value.
;                  $sParam_12_SERVER_NAME- a string value.
;                  $sParam_13_PORT_NUMBER- a string value.
;                  $sParam_14__SECURITY_SETTING- a string value.
;                  $sParam_15_ENCRYPTION- a string value.
;                  $sParam_16_AUTHENTICATION- a string value.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LanguageSetUp__PROTOCOLS($sParam_10_USER_NAME, $sParam_11_PASSWORD, $sParam_12_SERVER_NAME, $sParam_13_PORT_NUMBER, $sParam_14__SECURITY_SETTING, $sParam_15_ENCRYPTION, $sParam_16_AUTHENTICATION)
	Local $aEMAIL_CONFIG = __EmailConfig__API()
	$aEMAIL_CONFIG[$EMAIL_CONFIG__09__SECURITY_SETTING][$EMAIL_CONFIG__COL0_Name] = $sParam_14__SECURITY_SETTING
	$aEMAIL_CONFIG[$EMAIL_CONFIG__10__POPIMAP_USER_NAME][$EMAIL_CONFIG__COL0_Name] = $sParam_10_USER_NAME
	$aEMAIL_CONFIG[$EMAIL_CONFIG__11__POPIMAP_PASSWORD][$EMAIL_CONFIG__COL0_Name] = $sParam_11_PASSWORD
	$aEMAIL_CONFIG[$EMAIL_CONFIG__12__POPIMAP_SERVER_NAME][$EMAIL_CONFIG__COL0_Name] = $sParam_12_SERVER_NAME
	$aEMAIL_CONFIG[$EMAIL_CONFIG__13__POPIMAP_PORT_NUMBER][$EMAIL_CONFIG__COL0_Name] = $sParam_13_PORT_NUMBER
	$aEMAIL_CONFIG[$EMAIL_CONFIG__14__POPIMAP_ENCRYPTION][$EMAIL_CONFIG__COL0_Name] = $sParam_15_ENCRYPTION
	$aEMAIL_CONFIG[$EMAIL_CONFIG__15__POPIMAP_AUTHENTICATION][$EMAIL_CONFIG__COL0_Name] = $sParam_16_AUTHENTICATION
	$aEMAIL_CONFIG[$EMAIL_CONFIG__20__SMTP_USER_NAME][$EMAIL_CONFIG__COL0_Name] = $sParam_10_USER_NAME
	$aEMAIL_CONFIG[$EMAIL_CONFIG__21__SMTP_PASSWORD][$EMAIL_CONFIG__COL0_Name] = $sParam_11_PASSWORD
	$aEMAIL_CONFIG[$EMAIL_CONFIG__22__SMTP_SERVER_NAME][$EMAIL_CONFIG__COL0_Name] = $sParam_12_SERVER_NAME
	$aEMAIL_CONFIG[$EMAIL_CONFIG__23__SMTP_PORT_NUMBER][$EMAIL_CONFIG__COL0_Name] = $sParam_13_PORT_NUMBER
	$aEMAIL_CONFIG[$EMAIL_CONFIG__24__SMTP_ENCRYPTION][$EMAIL_CONFIG__COL0_Name] = $sParam_15_ENCRYPTION
	$aEMAIL_CONFIG[$EMAIL_CONFIG__25__SMTP_AUTHENTICATION][$EMAIL_CONFIG__COL0_Name] = $sParam_16_AUTHENTICATION
	__EmailConfig__API($aEMAIL_CONFIG)
EndFunc   ;==>_EmailConfig_LanguageSetUp__PROTOCOLS

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LanguageSetUp__SMTP_Authentication
; Description ...:
; Syntax ........: _EmailConfig_LanguageSetUp__SMTP_Authentication([$sCoding = Default])
; Parameters ....: $sCoding             - [optional] a string value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LanguageSetUp__SMTP_Authentication($sCoding = Default)
	Local Static $sCoding_static = ''
	If $sCoding = Default Then Return $sCoding_static

	$sCoding_static = $sCoding
EndFunc   ;==>_EmailConfig_LanguageSetUp__SMTP_Authentication

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LanguageSetUp__SMTP_Encryption
; Description ...:
; Syntax ........: _EmailConfig_LanguageSetUp__SMTP_Encryption([$sEncryption = Default])
; Parameters ....: $sEncryption         - [optional] a string value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LanguageSetUp__SMTP_Encryption($sEncryption = Default)
	Local Static $sEncryption_static = ''
	If $sEncryption = Default Then Return $sEncryption_static

	$sEncryption_static = $sEncryption
EndFunc   ;==>_EmailConfig_LanguageSetUp__SMTP_Encryption

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LoadFromINI
; Description ...: an example way of loading the email configuration
; Syntax ........: _EmailConfig_LoadFromINI()
; Parameters ....: None
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LoadFromINI()
	Local $sReadData = ''
;~ 	Local $aEMAIL_CONFIG = $__g_aEmailConfig = __EmailConfig__API(Null)
	Local $aEMAIL_CONFIG = __EmailConfig__API()
	__EmailConfig__API($aEMAIL_CONFIG)
	For $iRow_idx = 0 To $EMAIL_CONFIG__XX__COUNTER - 1
		$sReadData = IniRead(@ScriptDir & '\EmailConfig.ini', 'EMAIL_CONFIG', $aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL2_SAVELOAD_NAME], '!ERROR!')
		If $sReadData = '!ERROR!' Then ContinueLoop

		$sReadData = _GDPR_DeCrypt_AsString(Binary($sReadData))
		GUICtrlSetData($aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL1_ControlID], $sReadData)
		If @error Then MsgBox($MB_OK + $MB_TOPMOST + $MB_ICONERROR, '', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

		$aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL3_SAVELOAD_VALUE] = $sReadData
	Next

	__EmailConfig__API($aEMAIL_CONFIG)
	Return $aEMAIL_CONFIG
EndFunc   ;==>_EmailConfig_LoadFromINI

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_LoadWrapper
; Description ...: Wrapper which give you an ability to change the way how to load email configuration
; Syntax ........: _EmailConfig_LoadWrapper([$sFunction = Default])
; Parameters ....: $sFunction           - [optional] a string value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_LoadWrapper($sFunction = Default)
	Local Static $sFunction_static = Null
	If IsFunc($sFunction) Then
		$sFunction_static = $sFunction
		Return
	EndIf
	If Not IsFunc($sFunction_static) Then Return
	Return $sFunction_static()
EndFunc   ;==>_EmailConfig_LoadWrapper

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_SaveToINI
; Description ...: an example way of saving the email configuration
; Syntax ........: _EmailConfig_SaveToINI()
; Parameters ....: None
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_SaveToINI()
	Local $sCurrent = ''
	Local $sCurrent_Save = ''
	Local $aEMAIL_CONFIG = __EmailConfig__API()
	For $iRow_idx = 0 To $EMAIL_CONFIG__XX__COUNTER - 1
		If $aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] <> '' Then
			$sCurrent = GUICtrlRead($aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL1_ControlID])
			$sCurrent_Save = _GDPR_Crypt_String($sCurrent)
			IniWrite(@ScriptDir & '\EmailConfig.ini', 'EMAIL_CONFIG', $aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL2_SAVELOAD_NAME], $sCurrent_Save)
			$aEMAIL_CONFIG[$iRow_idx][$EMAIL_CONFIG__COL3_SAVELOAD_VALUE] = $sCurrent
		EndIf
	Next
	If $IDYES = MsgBox($MB_YESNO, 'Question:', 'Do you want to test email ?') Then
	EndIf
EndFunc   ;==>_EmailConfig_SaveToINI

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_SaveWrapper
; Description ...: Wrapper which give you an ability to change the way how to save email configuration
; Syntax ........: _EmailConfig_SaveWrapper([$sFunction = Default])
; Parameters ....: $sFunction           - [optional] a string value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_SaveWrapper($sFunction = Default)
	Local Static $sFunction_static = Null
	If IsFunc($sFunction) Then
		$sFunction_static = $sFunction
		Return
	EndIf
	If Not IsFunc($sFunction_static) Then Return
	$sFunction_static()
EndFunc   ;==>_EmailConfig_SaveWrapper

; #FUNCTION# ====================================================================================================================
; Name ..........: _EmailConfig_ShowGUI
; Description ...: Show the GUI and let it do the saving
; Syntax ........: _EmailConfig_ShowGUI([$hwnd_Parent = 0[, $fnInteraction = Null]])
; Parameters ....: $hwnd_Parent         - [optional] a handle value. Default is 0.
;                  $fnInteraction       - [optional] a floating point value. Default is Null.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _EmailConfig_ShowGUI($hwnd_Parent = 0, $fnInteraction = Null)
	#Region ### START Koda GUI section ### Form=
	Local $i_EMAILGUI_LABEL_X_POPIMAP = 45
	Local $i_EMAILGUI_LABEL_X_SMTP = 515
	Local $i_EMAILGUI_INPUT_X_POPIMAP = 220
	Local $i_EMAILGUI_INPUT_X_SMTP = 690
	Local $i_EMAILGUI_LABEL_W_POPIMAP = $i_EMAILGUI_INPUT_X_POPIMAP - $i_EMAILGUI_LABEL_X_POPIMAP
	Local $i_EMAILGUI_LABEL_W_SMTP = $i_EMAILGUI_INPUT_X_SMTP - $i_EMAILGUI_LABEL_X_SMTP
	Local $i_EMAILGUI_INPUT_WIDTH = 235
	Local $i_EMAILGUI_Y_POS = 5

	Local $aEMAIL_CONFIG = __EmailConfig__API()
;~ 	_ArrayDisplay($aEMAIL_CONFIG, @ScriptLineNumber)
	Local $hWnd_EMAILGUI_Main = GUICreate($aEMAIL_CONFIG[$EMAIL_CONFIG__01__GUI_TITLE][$EMAIL_CONFIG__COL0_Name], 972, 410, Default, Default, -1, -1, $hwnd_Parent)
	GUISetBkColor(0xFFFFFF)

	#Region - POP/IMAP
	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__02__COMMON_NAME][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__02__COMMON_NAME][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, 600, 21)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__03__EMAIL_ADDRESS][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__03__EMAIL_ADDRESS][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, 600, 21)
	$i_EMAILGUI_Y_POS += 25

	$i_EMAILGUI_Y_POS += 10
	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__04__POPIMAP_TYPE][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__04__POPIMAP_TYPE][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateCombo("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, 70, 21, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
	GUICtrlSetData($aEMAIL_CONFIG[$EMAIL_CONFIG__04__POPIMAP_TYPE][$EMAIL_CONFIG__COL1_ControlID], "POP3|IMAP", 'IMAP')
	GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateGroup($aEMAIL_CONFIG[$EMAIL_CONFIG__05__GUI_POPIMAP_TITLE][$EMAIL_CONFIG__COL0_Name], 24, $i_EMAILGUI_Y_POS, 457, 260, BitOR($GUI_SS_DEFAULT_GROUP, $BS_CENTER), $WS_EX_TRANSPARENT)
	GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__10__POPIMAP_USER_NAME][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__10__POPIMAP_USER_NAME][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 21)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__11__POPIMAP_PASSWORD][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__11__POPIMAP_PASSWORD][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 21, $ES_PASSWORD)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__12__POPIMAP_SERVER_NAME][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__12__POPIMAP_SERVER_NAME][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 20)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__13__POPIMAP_PORT_NUMBER][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 25, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__13__POPIMAP_PORT_NUMBER][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("143", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 21)
	$i_EMAILGUI_Y_POS += 25

	#Region - POP/IMAP - security
	$i_EMAILGUI_Y_POS += 20
	GUICtrlCreateGroup($aEMAIL_CONFIG[$EMAIL_CONFIG__09__SECURITY_SETTING][$EMAIL_CONFIG__COL0_Name], 35, $i_EMAILGUI_Y_POS, 433, 97)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__14__POPIMAP_ENCRYPTION][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__14__POPIMAP_ENCRYPTION][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateCombo("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
	GUICtrlSetData(-1, _EmailConfig_LanguageSetUp__POPIMAP_Encryption())
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__15__POPIMAP_AUTHENTICATION][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_POPIMAP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__15__POPIMAP_AUTHENTICATION][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateCombo("", $i_EMAILGUI_INPUT_X_POPIMAP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
	GUICtrlSetData(-1, _EmailConfig_LanguageSetUp__POPIMAP_Authentication())
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateGroup("", -99, -99, 1, 1)
	#EndRegion - POP/IMAP - security

	GUICtrlCreateGroup("", -99, -99, 1, 1)
	#EndRegion - POP/IMAP

	#Region - SMTP
	$i_EMAILGUI_Y_POS = 5
	$i_EMAILGUI_Y_POS += 25
	$i_EMAILGUI_Y_POS += 25
	$i_EMAILGUI_Y_POS += 10
	$i_EMAILGUI_Y_POS += 25
	GUICtrlCreateGroup($aEMAIL_CONFIG[$EMAIL_CONFIG__06__GUI_SMTP_TITLE][$EMAIL_CONFIG__COL0_Name], 496, $i_EMAILGUI_Y_POS, 457, 260, BitOR($GUI_SS_DEFAULT_GROUP, $BS_CENTER), $WS_EX_TRANSPARENT)
	GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__20__SMTP_USER_NAME][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_SMTP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__20__SMTP_USER_NAME][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 21)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__21__SMTP_PASSWORD][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_SMTP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__21__SMTP_PASSWORD][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 21, $ES_PASSWORD)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__22__SMTP_SERVER_NAME][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_SMTP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__22__SMTP_SERVER_NAME][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("", $i_EMAILGUI_INPUT_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 20)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__23__SMTP_PORT_NUMBER][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_SMTP, 25, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__23__SMTP_PORT_NUMBER][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateInput("587", $i_EMAILGUI_INPUT_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 21)
	$i_EMAILGUI_Y_POS += 25

	#Region - SMTP security
	$i_EMAILGUI_Y_POS += 20
	GUICtrlCreateGroup($aEMAIL_CONFIG[$EMAIL_CONFIG__09__SECURITY_SETTING][$EMAIL_CONFIG__COL0_Name], 508, $i_EMAILGUI_Y_POS, 433, 97)
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__24__SMTP_ENCRYPTION][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_SMTP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__24__SMTP_ENCRYPTION][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateCombo("", $i_EMAILGUI_INPUT_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
	GUICtrlSetData(-1, _EmailConfig_LanguageSetUp__SMTP_Encryption())
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateLabel($aEMAIL_CONFIG[$EMAIL_CONFIG__25__SMTP_AUTHENTICATION][$EMAIL_CONFIG__COL0_Name] & ":", $i_EMAILGUI_LABEL_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_LABEL_W_SMTP, 17, $SS_CENTERIMAGE)
	$aEMAIL_CONFIG[$EMAIL_CONFIG__25__SMTP_AUTHENTICATION][$EMAIL_CONFIG__COL1_ControlID] = GUICtrlCreateCombo("", $i_EMAILGUI_INPUT_X_SMTP, $i_EMAILGUI_Y_POS, $i_EMAILGUI_INPUT_WIDTH, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
	GUICtrlSetData(-1, _EmailConfig_LanguageSetUp__SMTP_Authentication())
	$i_EMAILGUI_Y_POS += 25

	GUICtrlCreateGroup("", -99, -99, 1, 1)
	#EndRegion - SMTP security

	GUICtrlCreateGroup("", -99, -99, 1, 1)
	#EndRegion - SMTP

	Local $id_EMAILGUI_Save_Button = GUICtrlCreateButton($aEMAIL_CONFIG[$EMAIL_CONFIG__07__GUI_SAVE][$EMAIL_CONFIG__COL0_Name], 320, 360, 145, 33, $WS_BORDER)
	GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
	GUICtrlSetBkColor(-1, 0x00FF00)
	Local $id_EMAILGUI_Close_Button = GUICtrlCreateButton($aEMAIL_CONFIG[$EMAIL_CONFIG__08__GUI_CLOSE][$EMAIL_CONFIG__COL0_Name], 520, 360, 145, 33, BitOR($BS_TOP, $WS_BORDER))
	GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
	GUICtrlSetBkColor(-1, 0xFF0000)
;~ 	_ArrayDisplay($aEMAIL_CONFIG, @ScriptLineNumber)
	__EmailConfig__API($aEMAIL_CONFIG)
	__EmailConfig_GUI_FillTheForm()
	GUISetState(@SW_SHOW)
	#EndRegion ### END Koda GUI section ###

	Local $nMsg = 0
	While 1
		$nMsg = GUIGetMsg()
		If IsFunc($fnInteraction) Then $fnInteraction($nMsg)
		Switch $nMsg
			Case $GUI_EVENT_CLOSE
				GUIDelete($hWnd_EMAILGUI_Main)
				Return
			Case $id_EMAILGUI_Save_Button
				_EmailConfig_SaveWrapper()
				GUIDelete($hWnd_EMAILGUI_Main)
				Return
			Case $id_EMAILGUI_Close_Button
				GUIDelete($hWnd_EMAILGUI_Main)
				Return
		EndSwitch
	WEnd

EndFunc   ;==>_EmailConfig_ShowGUI
#EndRegion - EmailConfig.au3 - Functions

#Region - EmailConfig.au3 - Internal Functions
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __EmailConfig__API
; Description ...: An "API" to manage configuration
; Syntax ........: __EmailConfig__API([$v_Param1 = Default])
; Parameters ....: $v_Param1            - [optional] a variant value. Default is Default.
; Return values .: None
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __EmailConfig__API($v_Param1 = Default)
	Local Static $aConfig_Static[0][0]
	If UBound($aConfig_Static) = 0 Or $v_Param1 = Null Then
		ReDim $aConfig_Static[0][0] ; clear
		ReDim $aConfig_Static[$EMAIL_CONFIG__XX__COUNTER][$EMAIL_CONFIG__COLX_COUNTER] ; resize/reseting
		$aConfig_Static[$EMAIL_CONFIG__00__GUID][0] = $EMAIL_CONFIG_GUID
		$aConfig_Static[$EMAIL_CONFIG__02__COMMON_NAME][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "COMMON_NAME"
		$aConfig_Static[$EMAIL_CONFIG__03__EMAIL_ADDRESS][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "EMAIL_ADDRESS"
		$aConfig_Static[$EMAIL_CONFIG__04__POPIMAP_TYPE][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_TYPE"
		$aConfig_Static[$EMAIL_CONFIG__10__POPIMAP_USER_NAME][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_USER_NAME"
		$aConfig_Static[$EMAIL_CONFIG__11__POPIMAP_PASSWORD][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_PASSWORD"
		$aConfig_Static[$EMAIL_CONFIG__12__POPIMAP_SERVER_NAME][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_SERVER_NAME"
		$aConfig_Static[$EMAIL_CONFIG__13__POPIMAP_PORT_NUMBER][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_PORT_NUMBER"
		$aConfig_Static[$EMAIL_CONFIG__14__POPIMAP_ENCRYPTION][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_ENCRYPTION"
		$aConfig_Static[$EMAIL_CONFIG__15__POPIMAP_AUTHENTICATION][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "POPIMAP_AUTHENTICATION"
		$aConfig_Static[$EMAIL_CONFIG__20__SMTP_USER_NAME][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "SMTP_USER_NAME"
		$aConfig_Static[$EMAIL_CONFIG__21__SMTP_PASSWORD][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "SMTP_PASSWORD"
		$aConfig_Static[$EMAIL_CONFIG__22__SMTP_SERVER_NAME][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "SMTP_SERVER_NAME"
		$aConfig_Static[$EMAIL_CONFIG__23__SMTP_PORT_NUMBER][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "SMTP_PORT_NUMBER"
		$aConfig_Static[$EMAIL_CONFIG__24__SMTP_ENCRYPTION][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "SMTP_ENCRYPTION"
		$aConfig_Static[$EMAIL_CONFIG__25__SMTP_AUTHENTICATION][$EMAIL_CONFIG__COL2_SAVELOAD_NAME] = "SMTP_AUTHENTICATION"
		Return $aConfig_Static
	ElseIf $v_Param1 = Default Then
		Return $aConfig_Static
	ElseIf UBound($v_Param1, $UBOUND_ROWS) = $EMAIL_CONFIG__XX__COUNTER And UBound($v_Param1, $UBOUND_COLUMNS) = $EMAIL_CONFIG__COLX_COUNTER Then
		If $v_Param1[$EMAIL_CONFIG__00__GUID][0] = $EMAIL_CONFIG_GUID Then
			$aConfig_Static = $v_Param1
			Return $aConfig_Static
		EndIf
	ElseIf IsInt($v_Param1) And $v_Param1 > 0 And $v_Param1 < $EMAIL_CONFIG__XX__COUNTER Then
		Return $aConfig_Static[$v_Param1][$EMAIL_CONFIG__COL3_SAVELOAD_VALUE]
	Else
	EndIf
EndFunc   ;==>__EmailConfig__API
#EndRegion - EmailConfig.au3 - Internal Functions