#include-once
#include <File.au3>
#include <_zip.au3>

; #INDEX# =======================================================================================================================
; Title .........: GOLLOG
; AutoIt Version : 3.3.14.0++
; Language ......: English
; Description ...: Smart logging system
; Author(s) .....: NSC
; ===============================================================================================================================

; ------------------------------------------------------------------------------
; This software is provided 'as-is', without any express or
; implied warranty.  In no event will the authors be held liable for any
; damages arising from the use of this software.

; #VARIABLES# ===================================================================================================================
; internal use
Global $gollogcount = 0 ;total number of chars in editbox
Global $lastlog = "sicrlf" ;carriage return default yes "sicrlf" or no onetime "nocrlf", see func GOLLOG
Global $cachelog = "" ;to count number of chars on single line
Global $Gollogedit = "" ;name of edit control
; to initialize with func _GOLLOG_INI
Global $guititle = "" ;name of gui for checkin' if activate on screen loggin'
Global $geleft = 0 ;left coord edit box
Global $getop = 0 ;top coord edit box
Global $gewidth = 0 ;width of edit box
Global $geheight = 0 ;height of edit box
; optionally to initialize with func _GOLLOG_INI, otherwise default values used
Global $GEfontcolor = "0x00FF00"
Global $GEbkcolor = "0x000000"
Global $GEfont = "consolas"
Global $GEfontsize = 8
Global $gefontweight = 800
Global $logpath = @ScriptDir & "\logs"
Global $logfile = $logpath & "\" & StringTrimRight(@ScriptName, 4) & "_LOG_"
; ===============================================================================================================================


; #CURRENT# =====================================================================================================================
; GOLLOG_INI
; GOLLOG
; GOLzipLOG
; ===============================================================================================================================

; #INTERNAL_USE_ONLY#============================================================================================================
; cleanedit
; ===============================================================================================================================

#comments-start
	Changelog:
	; V.2.31 2014-2015-2016-2018 only functions up to this version
	; V.3.00 2018/07/30 first attempt to convert to UDF
	; V.3.02 2018/08/03 bugfix in log folder creation
	ideas to do
	don't repeat timestamps, at least on GUI , or highlight only time changes
	in line option to display also as balloon text one or more lines
	in line option to write only on screen and not on disk
	in line option to change font size / color only on one line

#comments-end

; #FUNCTION# ====================================================================================================================
; Name...........: GOLLOG_INI
; Description ...: Initialize variables for GOLLOG edit, and creates the GOLLOG EDIT BOX
;				   if the Gui window is not existant ($guititle) also creates the windows gui;  in this case, the parameters of
;				   coords and dimensions are used for the new gui window, but are coords and dimensions are inverted
;				   due to different parameters order in GUICreate and GUICtrlCreateEdit
;				   if not called gollog only write to disk with default setting (because $guititle = "")
;				   if called with &guititle = "", the edit box related variables are ignored but you can still define values for the log file
; Syntax.........: GOLLOG_INI ($guititle, $geleft, $getop, $gewidth, $geheight[, $gefontcolor [, $gebkcolor  [, $gefont [, $gefontsize [, $gefontweight [, $logfile [, $months2NOTzip ]]]]]]] )
; Parameters ....: $guititle  - name of gui
;				   $geleft - left coord of the edit (for windows gui: width)
;				   $getop - top coord of the edit (for windows gui: height)
;				   $gewidth - width of the edit (for windows gui: left coord)
;				   $geheight - height of the edit (for windows gui: top coord)
;				   $gefontcolor - optional color of font in edit control
;				   $gebkcolor - optional color of background of edit control
;				   $gefont - optional font type
;				   $gefontsize - optional size of font
;				   $gefontweight - optional weight of font
;                  $logfile - optional complete path\name of the logfile (datetime will be still added to the name)
;					otherwise default path\name will be used
; Return values .: Success - Returns "OK"
;                  Failure - error message, sets @error = 1
;					set @extended
;                  |1 - left cooord missing
;                  |2 - top coord missing
;				   |3 - widht missing
;				   |4 - height missing
; Author ........: NSC
; Modified.......:
; Remarks .......:
; Related .......: GOLLOG
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func GOLLOG_INI($Fguititle, $Fgeleft, $Fgetop, $Fgewidth, $Fgeheight, $FGEfontcolor = "0x00FF00", $FGEbkcolor = "0x000000", $FGEfont = "consolas", $FGEfontsize = 8, $Fgefontweight = 800, $Flogfile = @ScriptDir & "\logs\" & StringTrimRight(@ScriptName, 4) & "_LOG_")
	$guititle = $Fguititle
	$geleft = $Fgeleft
	$getop = $Fgetop
	$gewidth = $Fgewidth
	$geheight = $Fgeheight
	; optionally to initialize with func _GOLLOG_INI, otherwise default values used
	$GEfontcolor = $FGEfontcolor
	$GEbkcolor = $FGEbkcolor
	$GEfont = $FGEfont
	$GEfontsize = $FGEfontsize
	$gefontweight = $Fgefontweight
	$logfile = $Flogfile

	If $guititle = "" Then
		Return "paramter GUI title missing"
	EndIf
	If $geleft = "" Then Return SetError(1, 1, "edit: left cooord missing")
	If $getop = "" Then Return SetError(1, 2, "edit: top coord missing")
	If $gewidth = "" Then Return SetError(1, 3, "edit: widht missing")
	If $geheight = "" Then Return SetError(1, 4, "edit: height missing")

	If Not WinExists($guititle) Then
		If $geleft = "" Then Return SetError(1, 1, "GUI: width missing")
		If $getop = "" Then Return SetError(1, 2, "GUI: heigh missing")
		If $gewidth = "" Then Return SetError(1, 3, "GUI: left cooord missing")
		If $geheight = "" Then Return SetError(1, 4, "GUI: top coord missing")
		$test = GUICreate($guititle, $geleft, $getop, $gewidth, $geheight)
		; modify parameters to fit edit in "auto" generated GUI
		$gewidth = $geleft - 10
		$geheight = $getop - 10
		$getop = 5
		$geleft = 5
		cleanedit()
		GUISetState(@SW_SHOW)
	Else
		If $geleft = "" Then Return SetError(1, 1, "left cooord missing")
		If $getop = "" Then Return SetError(1, 2, "top coord missing")
		If $gewidth = "" Then Return SetError(1, 3, "widht missing")
		If $geheight = "" Then Return SetError(1, 4, "height missing")
		cleanedit()
	EndIf
	Return "OK"
EndFunc   ;==>GOLLOG_INI

; #FUNCTION# ====================================================================================================================
; Name...........: GOLLOG
; Description ...: writes one line of log
;				   if there isn't edit control, the line is only written on the log file
;				   if there is also an associated edit control, it writes both on screen and on file
; Syntax.........: GOLLOG(ByRef $logtext)
; Parameters ....: $logtext  - a string of text to be written down on disk and on screen
;				   if $logtext containg at the end a substring like "|nocrlf50" that line does not CR ("noCRLF")
;                  except if the max specified number of chars on the line ("50") is excedeed
;				   next call of Gollog() without substring "|nocrlf50" restores auto Carriage Return behaviour
; Return values .: n/a
; Author ........: NSC
; Modified.......:
; Remarks .......:
; Related .......: GOLLOG_INI,cleanedit
; Link ..........:
; Example .......: no
; ===============================================================================================================================
Func GOLLOG($logtext)
	If Not FileExists($logpath) Then
		DirCreate($logpath) ; pre-UDF this was in the scripts
	EndIf
	$gollogcount += StringLen($logtext)
	Local $logfiletimerange = @YEAR & @MON
	Local $linelimit = StringRight($logtext, 2)
	If StringRight($logtext, 9) = "|nocrlf" & $linelimit Then
		$logtext = StringTrimRight($logtext, 9)
		Local $acapo = "no"
	Else
		Local $acapo = "si"
		$gollogcount += 4
		If $gollogcount > 13000 And $guititle <> "" Then
			;Sleep(3000)
			cleanedit()
			;	MsgBox(64, "debug", $conta)
			$gollogcount = 0
		EndIf
	EndIf

	If $acapo = "no" And (StringLen($cachelog) <= $linelimit) Then ;pearl perla no CRLF if > linelimt
		If $lastlog = "nocrlf" Then
			If WinExists($guititle) Then ; no GUI no on screen log
				GUICtrlSetData($Gollogedit, $logtext, 1)
			EndIf
		Else
			If WinExists($guititle) Then ; no GUI no on screen log
				GUICtrlSetData($Gollogedit, @MDAY & "/" & @MON & "_" & @HOUR & ":" & @MIN & " " & $logtext, 1)
			EndIf
		EndIf
		$cachelog = $cachelog & $logtext
		$lastlog = "nocrlf"
	Else
		If $lastlog = "nocrlf" Then
			If WinExists($guititle) Then ; no GUI no on screen log
				GUICtrlSetData($Gollogedit, $logtext & @CRLF, 1)
			EndIf
			$cachelog = $cachelog & $logtext
			_FileWriteLog($logfile & $logfiletimerange & ".txt", $cachelog)
			$cachelog = ""
		Else
			If WinExists($guititle) Then ; no GUI no on screen log
				GUICtrlSetData($Gollogedit, @MDAY & "/" & @MON & "_" & @HOUR & ":" & @MIN & " " & $logtext & @CRLF, 1)
			EndIf
			_FileWriteLog($logfile & $logfiletimerange & ".txt", $logtext)
		EndIf
		$lastlog = "sicrlf"
	EndIf
EndFunc   ;==>GOLLOG

; #FUNCTION# ====================================================================================================================
; Name...........: GOLzipLOG
; Description ...: takes all log files older than specified number of months, and zip these in a unique zip file, in the same folder
; Syntax.........: GOLLOG(ByRef $months2notZIP)
; Parameters ....: $months2notZIP  - number of months (age of log files) to not zip
; Return values .: n/a
; Author ........: NSC
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: no
; ===============================================================================================================================
Func GOLzipLOG($months2NOTzip) ; zipping old log leaving unzipped only n months
	GOLLOG("ZIPping log files older than " & $months2NOTzip & " months")

	Local $hSearch = FileFindFirstFile($logfile & "*.txt") ; searching for logs
	Local $logconta = 0
	Local $logfiletimerange = @YEAR & @MON
	While 1 ; single file processing cycle
		Local $sFileName = FileFindNextFile($hSearch)
		; If there is no more file matching the search.
		If @error Then ExitLoop

		Local $stringtime = StringTrimRight(StringRight($sFileName, 10), 4) ;obtaining year-month like 201609

		If $logfiletimerange - $stringtime > $months2NOTzip Then ;zipping

			If Not FileExists($logfile & ".zip") Then
				If Not _Zip_Create($logfile & ".zip", 1) Then
					GOLLOG("Error " & @error & " creating " & $logfile & ".zip")
				Else
					GOLLOG("Created new log archive: " & $logfile & ".zip")
				EndIf
			Else
				GOLLOG("adding to archive: " & $logfile & ".zip")
			EndIf
			If Not _zip_additem($logfile & ".zip", $logpath & $sFileName) Then
				GOLLOG("Error " & @error & " zipping:  " & $logpath & $sFileName)
			Else
				GOLLOG("Added: " & $logpath & $sFileName)
				$logconta += 1
				If Not FileDelete($logpath & $sFileName) Then
					GOLLOG("ERROR - Unable to DELETE log file " & $logpath & $sFileName)
				EndIf
			EndIf
		EndIf
	WEnd
	GOLLOG("Finished = " & $logconta & " log files zipped")
EndFunc   ;==>GOLzipLOG

; #INTERNAL_USE_ONLY#============================================================================================================
; Name...........: cleanedit
; Description ...: create the edit box delete edit box and recreate it with same parameters
;				   when the edit box is "full" of chars delete edit box and recreate it with same parameters
;				   parameters are global variables specified in GOLLOG_INI
; Syntax.........: cleanedit()
; Parameters ....: n/a
; Return values .: n/a
; Author ........: NSC
; Modified.......:
; Remarks .......:
; Related .......: GOLLOG_INI
; Link ..........:
; Example .......: no
; ===============================================================================================================================
Func cleanedit() ; cleaning of edit every n° lines (in program put if $nlines > xlines then this function)
	GUICtrlDelete($Gollogedit)
	$Gollogedit = GUICtrlCreateEdit("", $geleft, $getop, $gewidth, $geheight) ;, BitOR($ES_AUTOVSCROLL, $ES_AUTOHSCROLL, $ES_WANTRETURN, $WS_BORDER))
	GUICtrlSetData(-1, "" & @CRLF)
	GUICtrlSetFont(-1, $GEfontsize, $gefontweight, 0, $GEfont)
	GUICtrlSetColor(-1, $GEfontcolor)
	GUICtrlSetBkColor(-1, $GEbkcolor)
	GUICtrlSetCursor(-1, 3)
EndFunc   ;==>cleanedit