#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Res_SaveSource=y
#AutoIt3Wrapper_Res_Language=1031
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Array.au3>
#include <File.au3>
#include <Date.au3>


$CamUpDir = @UserProfileDir & "\Dropbox\Kamera-Uploads\"
$PicDoneDir = @UserProfileDir & "\Dropbox\Bilder-abgelegt-auf-VM\"
$PicOutsideDir = "C:\Backup\PicsOutside\"
DirCreate($PicDoneDir)
DirCreate($PicOutsideDir)

$CamUpDirSize = DirGetSize($CamUpDir)
If @error Then
	; Das Camera Upoad Verzeichnis existiert nicht mehr! FATAL!!!
	Exit
EndIf

$PicDoneDirSize = DirGetSize($PicDoneDir)
If @error Then
	; Das Camera Upoad Verzeichnis existiert nicht mehr! FATAL!!!
	Exit
EndIf

While 1
	ConsoleWrite("Beginn Hauptschleife: " & _NowCalc() & @CRLF)
	$aFiles = _FileListToArray($CamUpDir, "*.*", 1, 1) ; filesonly, fullpath
	; _ArrayDisplay($aFiles)
		If IsArray($aFiles) Then
		for $a = 1 to $aFiles[0]
			$Src=$aFiles[$a]
			$Dst1=StringReplace($Src,$CamUpDir,$PicOutsideDir) ; ausserhalb Dropbox
			$Dst2=StringReplace($Src,$CamUpDir,$PicDoneDir) ; Innerhalb Dropbox: Zur Kontrolle, dass sie verarbeitet sind. Können dann auf dem Telefon / Laptop gelöscht werden
			if FileExists($Dst1) Then
				; darf nicht passieren: Die Cam macht keine Bilder mit identishem Namen zweimal!
				ConsoleWrite("Fehler: Datei schon da: " & $Dst1 & @CRLF)
				ConsoleWrite(@TAB & "wird ignoriert --> " & $Src & @CRLF)
				ConsoleWrite("------------------" & @CRLF)
			Else
				ConsoleWrite("Verarbeite: " & $Src & @CRLF)
				if FileCopy($Src,$Dst1,1+8) Then
					ConsoleWrite(@TAB & " Kopieren OK --> " & $Dst1 & @CRLF)
					if FileExists($Dst2) Then
						ConsoleWrite(@TAB & "Fehler: $Dst2 schon da: " & $Dst2 & @CRLF)
						ConsoleWrite(@TAB & "Orginaldatei wird belassen!" & @CRLF)
						; darf nicht passieren
						ConsoleWrite("------------------" & @CRLF)
					Else
						if FileMove($Src,$dst2,1+8) Then
							; Verschieben innerhalb Dropbox erfolgreich
							ConsoleWrite(@TAB & "Verschieben OK nach: " & $dst2 & @CRLF)
							ConsoleWrite("------------------" & @CRLF)
						Else
							ConsoleWrite(@TAB & "!-FEHLER-! kann nicht innerhalb Dropbox verschieben!" & @CRLF)
							ConsoleWrite(@TAB & "Ziel wäre gewesen: " & $dst2 & @CRLF)
							ConsoleWrite("------------------" & @CRLF)
						EndIf
					EndIf
				Else
					ConsoleWrite(@TAB & "!-FEHLER-! Kann nicht nach AUSSERHALB der Dropbox kopieren: " & @CRLF)
					ConsoleWrite(@TAB & "Ziel wäre gewesen: " & $Dst1 & @CRLF)
							ConsoleWrite("------------------" & @CRLF)
					; Kopieren nach außerhalb Dropbox fehlgeschlagen: Belassen
				EndIf
			EndIf
		Next
	Else
		ConsoleWrite("Nichts zu tun" & @CRLF)
	EndIf
	ConsoleWrite(" -------- Ende Hauptschleife --- Warte 10 Minuten -------- " & _NowCalc() & @CRLF)
	Sleep(10*60*1000) ; einmal pro 10 Minuten reicht vollkommen
WEnd