#include "HTMLParser.au3"
#include <Array.au3>

Func StringRepeat($sChar, $nCount)
    $tBuffer = DLLStructCreate("char[" & $nCount & "]")
    DllCall("msvcrt.dll", "ptr:cdecl", "memset", "ptr", DLLStructGetPtr($tBuffer), "int", Asc($sChar), "int", $nCount)
    Return DLLStructGetData($tBuffer, 1)
EndFunc

$sHTML = FileRead("prettyhtml.txt")

$hFile = FileOpen("prettyhtml_output.txt", 2)

$tTokenList = _HTMLParser2($sHTML)
$iExtended = @extended

$pItem = $tTokenList.First

$iLevel = 0

While 1
	_MemMoveMemory($pItem, $__g_pTokenListToken, $__g_iTokenListToken)
	Switch $__g_tTokenListToken.Type
		Case $__HTMLPARSERCONSTANT_TYPE_NONE
			FileClose($hFile)
			Exit MsgBox(0, "Ooops!", "Some unknown element found!"&@CRLF&"Closing script...")
		Case $__HTMLPARSERCONSTANT_TYPE_CDATA, $__HTMLPARSERCONSTANT_TYPE_COMMENT, $__HTMLPARSERCONSTANT_TYPE_DOCTYPE
			FileWrite($hFile, ($iLevel>0?StringRepeat(@TAB, $iLevel):"")&StringMid($sHTML, $__g_tTokenListToken.Start, $__g_tTokenListToken.Length)&@CRLF)
		Case $__HTMLPARSERCONSTANT_TYPE_STARTTAG
			FileWrite($hFile, ($iLevel>0?StringRepeat(@TAB, $iLevel):"")&StringMid($sHTML, $__g_tTokenListToken.Start, $__g_tTokenListToken.Length)&@CRLF)
			$iLevel+=1
		Case $__HTMLPARSERCONSTANT_TYPE_ENDTAG
			$iLevel-=1
			FileWrite($hFile, ($iLevel>0?StringRepeat(@TAB, $iLevel):"")&StringMid($sHTML, $__g_tTokenListToken.Start, $__g_tTokenListToken.Length)&@CRLF)
;~ 			ConsoleWrite("?"&@CRLF)
		Case $__HTMLPARSERCONSTANT_TYPE_TEXT
			;excluded for now
;~ 			ConsoleWrite(StringMid($sHTML, $__g_tTokenListToken.Start, $__g_tTokenListToken.Length)&@CRLF)
			$sTabs = ($iLevel>0?StringRepeat(@TAB, $iLevel):"")
			FileWrite($hFile, $sTabs&StringReplace(StringMid($sHTML, $__g_tTokenListToken.Start, $__g_tTokenListToken.Length), @CRLF, @CRLF&$sTabs)&@CRLF)
	EndSwitch
	$pItem = $__g_tTokenListToken.Next
	If $pItem = 0 Then ExitLoop
WEnd

FileClose($hFile)

Func _HTMLParser2($sHTML);alternate parser, dealing with the tmp current <script> content problem in _HTMLParser function
	Local $iExtended, $i, $aRet, $iOffset = 1, $iScript = 0
	While 1
		$aRet=StringRegExp($sHTML, "\G<![dD][oO][cC][tT][yY][pP][eE][\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}]+[^>]*?>", 1, $iOffset)
		If @error=0 Then
			$iExtended = @extended
;~ 			ConsoleWrite(StringMid($sHTML, $iOffset, $iExtended-($iOffset))&@CRLF)
			If _TokenList_CreateToken($__HTMLPARSERCONSTANT_TYPE_DOCTYPE, $iOffset, $iExtended-($iOffset)) = 0 Then Return SetError(1, 1, 0)
			$iOffset = $iExtended
			ContinueLoop
		EndIf

		$aRet=StringRegExp($sHTML, "\G[<]([0-9a-zA-Z]+)(?:[\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}]+[^\x{0000}-\x{001F}\x{007F}-\x{009F}\x{0020}\x{0022}\x{0027}\x{003E}\x{002F}\x{003D}\x{FDD0}\x{FDEF}\x{FFFE}\x{FFFF}\x{1FFFE}\x{1FFFF}\x{2FFFE}\x{2FFFF}\x{3FFFE}\x{3FFFF}\x{4FFFE}\x{4FFFF}\x{5FFFE}\x{5FFFF}\x{6FFFE}\x{6FFFF}\x{7FFFE}\x{7FFFF}\x{8FFFE}\x{8FFFF}\x{9FFFE}\x{9FFFF}\x{AFFFE}\x{AFFFF}\x{BFFFE}\x{BFFFF}\x{CFFFE}\x{CFFFF}\x{DFFFE}\x{DFFFF}\x{EFFFE}\x{EFFFF}\x{FFFFE}\x{FFFFF}\x{10FFFE}\x{10FFFF}]+(?:[\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}]*[=][\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}]*(?:[^\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}\x{0022}\x{0027}\x{003D}\x{003C}\x{003E}\x{0060}]+|['][^']*[']|[""""][^""""]*[""""]))?)*[\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}]*[/]?[>]", 1, $iOffset)
		If @error=0 Then
			$iExtended = @extended
;~ 			ConsoleWrite(StringMid($sHTML, $iOffset, $iExtended-($iOffset))&@CRLF)
			If _TokenList_CreateToken($__HTMLPARSERCONSTANT_TYPE_STARTTAG, $iOffset, $iExtended-($iOffset)) = 0 Then Return SetError(1, 2, 0)
			$iOffset = $iExtended
			If StringLower($aRet[0]) = "script" Then $iScript+=1
			ContinueLoop
		EndIf

		$aRet=StringRegExp($sHTML, "\G[<][/]([0-9a-zA-Z]+)[\x{0009}\x{000A}\x{000C}\x{000D}\x{0020}]*[>]", 1, $iOffset)
		If @error=0 Then
			$iExtended = @extended
;~ 			ConsoleWrite(StringMid($sHTML, $iOffset, $iExtended-($iOffset))&@CRLF)
			If _TokenList_CreateToken($__HTMLPARSERCONSTANT_TYPE_ENDTAG, $iOffset, $iExtended-($iOffset)) = 0 Then Return SetError(1, 3, 0)
			$iOffset = $iExtended
			If StringLower($aRet[0]) = "script" Then $iScript-=1
			ContinueLoop
		EndIf

		$aRet=StringRegExp($sHTML, "\G<!\[CDATA\[.*?\]\]>", 1, $iOffset)
		If @error=0 Then
			$iExtended = @extended
;~ 			ConsoleWrite(StringMid($sHTML, $iOffset, $iExtended-($iOffset))&@CRLF)
			If _TokenList_CreateToken($__HTMLPARSERCONSTANT_TYPE_CDATA, $iOffset, $iExtended-($iOffset)) = 0 Then Return SetError(1, 4, 0)
			$iOffset = $iExtended
			ContinueLoop
		EndIf

		$aRet=StringRegExp($sHTML, "\G<!--.*?-->", 1, $iOffset)
		If @error=0 Then
			$iExtended = @extended
;~ 			ConsoleWrite(StringMid($sHTML, $iOffset, $iExtended-($iOffset))&@CRLF)
			If _TokenList_CreateToken($__HTMLPARSERCONSTANT_TYPE_COMMENT, $iOffset, $iExtended-($iOffset)) = 0 Then Return SetError(1, 5, 0)
			$iOffset = $iExtended
			ContinueLoop
		EndIf

		$aRet=($iScript>0)?StringRegExp($sHTML, "(?s)\G.+?([<][/]script[>])", 1, $iOffset):StringRegExp($sHTML, "\G[^<]+", 1, $iOffset)
		If @error=0 Then
			$iExtended = @extended
			If $iScript>0 Then $iExtended-=StringLen($aRet[0])
			If _TokenList_CreateToken($__HTMLPARSERCONSTANT_TYPE_TEXT, $iOffset, $iExtended-($iOffset)) = 0 Then Return SetError(1, 6, 0)
			$iOffset = $iExtended
			ContinueLoop
		EndIf

		ExitLoop
	WEnd
	Return SetError(0, $iExtended, $__g_tTokenListList)
EndFunc