#include-once
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPISys.au3>
;~ #NoTrayIcon

#Au3Stripper_Ignore_Funcs=__PlayAnim__1,__PlayAnim__2,__PlayAnim__3, _BGTexture1, _BGTexture2, _BGTexture3, _BGTexture4, _BGTexture5, _BGTexture6
Global $__bAnim__, $__bGUIFade__, $__iGUIFadeInTimer__, $__iGUIFadeOutTimer__, $__hBitmap__, $__iAnim__ = 0, $__aAnims__, $__iW__, $__iH__, $__iX__, $__iY__, $__iCtrl__, $__bBgTexture__, _
			$__hGUI__, $__hPic__, $__iAnimColor__, $__bAnimShadow__

#Region example
;~ _GDIPlus_Startup()
;~ Global Const $iW = 1000, $iH = 200
;~ Global Const $hSplash = _SplashTextEx("Please wait while coordinates are created!", 30)

;~ Do
;~ 	Switch GUIGetMsg()
;~ 		Case $GUI_EVENT_CLOSE
;~ 			_SplashTextCloseEx($hSplash)
;~ 			_GDIPlus_Shutdown()
;~ 			Exit
;~ 	EndSwitch
;~ Until False
#EndRegion example


; #FUNCTION# ====================================================================================================================
; Name ..........: _SplashTextEx
; Description ...:	_SplashTextEx creates a splash window with several options
; Syntax ........: _SplashTextEx($sText, $fFontSize[, $iW = Default[, $iH = Default[, $sFontName = "Impact"[, $iX_Anim = $iW[,
;                  $iY_Anim = $iH[, $iColorText1 = 0xFF505080[, $iColorText2 = 0xFFFFFFFF[, $iAnimColor = 0xF0ABCDEF[,
;                  $bAnim = False[, $iAnim = 3[, $bAnimShadow = True[, $bFontShadow = True[, $iFontShadowPosX = 6[,
;                  $iFontShadowPosY = 8[, $bBgTexture = True[, $Texture = -1[, $iFontHAlign = 1[,
;                  $iFontVAlign = 1[, $iColorFontShadow = 0x90202020[, $fFontShadowBlurLevel = 0.175[,
;                  $iGUIBorderStyle = $WS_BORDER[, $iGUITrans = 0xF8[, $bGUIDrag = True[, $iFontStyle = 0[,
;                  $bGUIFade = False[, $iGUIFadeInTimer = 250[, $iGUIFadeOutTimer = 250[,
;                  $iTextureWrapMode = 3[, $iGUIBgColor = 0xF8F8F8]]]]]]]]]]]]]]]]]]]]]]]]]]]]])
; Parameters ....: $sText               - A string value for the splash text.
;                  $fFontSize           - A float value for the splash text font size.
;                  $iW                  - An integer value for the width of the splash gui. Default is  Default -> gui width will be calculated automatically.
;                  $iH                  - An integer value for the height of the splash gui Default is  Default -> gui height will be calculated automatically.
;                  $sFontName           - [optional] A string value. Default is "Arial".
;                  $iX_Anim             - [optional] An integer value for the position on x axis for the animation. Default is $iW (right border).
;                  $iY_Anim             - [optional] An integer value for the position on y axis for the animation. Default is $iH (bottom).
;                  $iColorText1         - [optional] An integer value for the font color. Default is 0xFF505080.
;                  $iColorText2         - [optional] An integer value for the font color. Default is 0xFFFFFFFF.
;                  $bGradient 	        - [optional] A boolean value to enable / disable gradient color to fill letters. If false $iColorText2 will be used for flat color
;                  $iAnimColor          - [optional] An integer value for the color of the animation objects in ARGB format. Default is 0xF0ABCDEF.
;                  $bAnim               - [optional] A boolean value to enable/disable animation. Default is False.
;                  $iAnim               - [optional] An integer value to select an animation. Available animation values are from 0 to 2. Default is 3 which means random selection.
;                  $bAnimShadow         - [optional] A boolean valuee to enable/disable animation shadow. Default is True.
;                  $bFontShadow         - [optional] A boolean value to enable/disable splash text font shadow. Default is True.
;                  $iFontShadowPosX     - [optional] An integer value to position splash text shadow on x axis. Default is 6.
;                  $iFontShadowPosY     - [optional] An integer value to position splash text shadow on Y axis. Default is 8.
;                  $bBgTexture          - [optional] A boolean value to enable/disable background texture. Default is True.
;                  $Texture             - [optional] A  integer/string/binary value to choose/set texture. Default is -1. -1 to -6 are predefined textures, if a string is given then it will intepreted as a filename,
;													 a binary value is a bitmap in binary format.
;                  $iFontHAlign         - [optional] An integer value to align the splash text on horizontal level (0: left, 1:center, 2: right). Default is 1.
;                  $iFontVAlign         - [optional] An integer value to align the splash text on vertical level (0: top, 1:center, 2: bottom). Default is 1.
;                  $iColorFontShadow    - [optional] An integer value to set splash text shadow color. Default is 0x90202020.
;                  $fFontShadowBlurLevel- [optional] A float value to set the blur level of splash text shadow. Default is 0.175.
;                  $iGUIBorderStyle     - [optional] An integer value to set gui style. Default is $WS_BORDER.
;                  $iGUITrans           - [optional] An integer value to set the transparency of the gui. Default is 0xF8.
;                  $bGUIDrag            - [optional] A boolean value. to enable/disable splah gui dragging Default is True.
;                  $iFontStyle          - [optional] An integer value to set the splash text font. style. Default is 0 (normal).
;                  $bGUIFade            - [optional] A boolean value to enable/disable gui fade in/out on start/exit. Default is False.
;                  $iGUIFadeInTimer     - [optional] An integer value to set fade in time. Default is 250 ms.
;                  $iGUIFadeOutTimer    - [optional] An integer value to set fade out time. Default is 250 ms.
;                  $iTextureWrapMode    - [optional] An integer value to set texture wrap mode (see help file for details -> _GDIPlus_TextureCreate). Default is 3.
;                  $iGUIBgColor         - [optional] An integer value to set gui background color. Default is 0xF8F8F8.
;                  $iBorderSize         - [optional] An integer value to set border pen width. Default is 1.
; Return values .: None
; Author ........: UEZ
; Version........: 0.91 build 2015-05-10
; Modified ......: -
; Remarks .......: Don't forget to use _GDIPlus_Startup() before calling this function and _GDIPlus_Shutdown() when done
; Comment .......: Thanks to eukalyptus for the blur function
; Example .......: yes
; ===============================================================================================================================
Func _SplashTextEx($sText,  $fFontSize, _
		$iW = Default, $iH = Default, $sFontName = "Impact", $iX_Anim = $iW, $iY_Anim = $iH, $iColorText1 = 0xFF505080, $iColorText2 = 0xFFFFFFFF, $bGradient = True, _
		$iAnimColor = 0xF0ABCDEF, $bAnim = False, $iAnim = 3, $bAnimShadow = True,  $bFontShadow = True, $iFontShadowPosX = 6, $iFontShadowPosY = 8, _
		$bBgTexture = True, $Texture = -1, $iFontHAlign = 1, $iFontVAlign = 1, $iColorFontShadow = 0x90202020, $fFontShadowBlurLevel = 0.175, _
		$iGUIBorderStyle = $WS_BORDER, $iGUITrans = 0xF8, $bGUIDrag = True, $iFontStyle = 0, $bGUIFade = False, $iGUIFadeInTimer = 250, $iGUIFadeOutTimer = 250, _
		$iTextureWrapMode = 3, $iGUIBgColor = 0xF8F8F8, $iBorderCharColor = 0x40101010, $iBorderSizeChar = 1)

	Local $fTimer = TimerInit()
	If $iW = Default Or $iH = Default Then
		Local $aDim = _GDIPlus_MeasureString($sText, $sFontName, $fFontSize, $iFontStyle, False)
		If $iW = Default Then $iW = $aDim[0] > @DesktopWidth * 0.95 ? @DesktopWidth * 0.95 :  $aDim[0]
		If $iH = Default Then $iH = $aDim[1] * 3 > @DesktopHeight * 0.95 ? @DesktopHeight * 0.95  :  $aDim[1] * 3
		$iX_Anim = $iW
		$iY_Anim = $iH
	EndIf
	Local Const $hGUI_Splash = GUICreate("", $iW, $iH, -1, -1, BitOR($iGUIBorderStyle, $WS_POPUP), $WS_EX_TOPMOST, WinGetHandle(AutoItWinGetTitle())), $__hGUI__ = $hGUI_Splash
	GUISetBkColor($iGUIBgColor, $hGUI_Splash)
	Local Const $iPic = GUICtrlCreatePic("", 0, 0, $iW, $iH, $SS_CENTERIMAGE)
	GUICtrlSetState($iPic, $GUI_DISABLE)
	$__hPic__ = GUICtrlGetHandle($iPic)
	If $bGUIDrag Then
		Local Const $iLabel_Drag = GUICtrlCreateLabel("", 0, 0, $iW, $iH, Default, $GUI_WS_EX_PARENTDRAG)
		GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
	EndIf
	Local Const $hFamily = _GDIPlus_FontFamilyCreate($sFontName)
	If Not $hFamily Then Return SetError(1, 0, 0)
	Local Const $hFormat = _GDIPlus_StringFormatCreate()
	Local $tLayout = _GDIPlus_RectFCreate($iFontShadowPosX, $iFontShadowPosY, $iW, $iH)
	_GDIPlus_StringFormatSetAlign($hFormat, $iFontVAlign)
	_GDIPlus_StringFormatSetLineAlign($hFormat, $iFontHAlign)
	Local Const $hPath = _GDIPlus_PathCreate()
	Local Const $hBrush = _GDIPlus_BrushCreateSolid($iColorFontShadow), $hPen = _GDIPlus_PenCreate($iBorderCharColor, $iBorderSizeChar)
	Local Const $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH), $hGfx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
	_GDIPlus_GraphicsSetSmoothingMode($hGfx, $GDIP_SMOOTHINGMODE_ANTIALIAS + (@OSBuild > 5999) * 1)
	_GDIPlus_GraphicsSetTextRenderingHint($hGfx, $GDIP_TextRenderingHintAntialiasGridFit)
	_GDIPlus_GraphicsSetPixelOffsetMode($hGfx, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
	$__bBgTexture__ = $bBgTexture
	If $bBgTexture Then
		Local $hBmp_Texture
		If $Texture < 0 Then
			$Texture = ($Texture < -6) ? -6 : $Texture
			Local $sTexture = "_BGTexture" & $Texture * -1
			$hBmp_Texture = _GDIPlus_BitmapCreateFromMemory(Call($sTexture))
		ElseIf IsString($Texture) Then
			$hBmp_Texture = _GDIPlus_BitmapCreateFromFile($Texture)
		ElseIf IsBinary($Texture) Then
			$hBmp_Texture = _GDIPlus_BitmapCreateFromMemory($Texture)
		EndIf
		If $hBmp_Texture Then
			Local Const $hTexture = _GDIPlus_TextureCreate($hBmp_Texture, $iTextureWrapMode)
			_GDIPlus_GraphicsFillRect($hGfx, 0, 0, $iW, $iH, $hTexture)
			_GDIPlus_BitmapDispose($hBmp_Texture)
			_GDIPlus_BrushDispose($hTexture)
		EndIf
	Else
		$hBmp_Texture = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
		Local Const $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBmp_Texture)
		_GDIPlus_GraphicsClear($hCtxt, 0xFF000000 + $iGUIBgColor)
		_GDIPlus_GraphicsDrawImage($hGfx, $hBmp_Texture, 0, 0)
		_GDIPlus_GraphicsDispose($hCtxt)
		_GDIPlus_BitmapDispose($hBmp_Texture)
	EndIf
	If $bFontShadow Then
		_GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, $iFontStyle, $fFontSize, $hFormat)
		Local Const $hBitmap_Blur = _GDIPlus_BitmapCreateFromScan0($iW, $iH), $hGfx_Blur = _GDIPlus_ImageGetGraphicsContext($hBitmap_Blur)
		_GDIPlus_GraphicsSetSmoothingMode($hGfx_Blur, $GDIP_SMOOTHINGMODE_ANTIALIAS + (@OSBuild > 5999) * 1)
		_GDIPlus_GraphicsSetTextRenderingHint($hGfx_Blur, $GDIP_TextRenderingHintAntialiasGridFit)
		_GDIPlus_GraphicsFillPath($hGfx_Blur, $hPath, $hBrush)
		Local Const $hBmp_Blur = _GDIPlus_BitmapCreateBlurBitmapv10($hBitmap_Blur, $fFontShadowBlurLevel)
		_GDIPlus_GraphicsDrawImageRect($hGfx, $hBmp_Blur, 0, 0, $iW, $iH)
		_GDIPlus_BitmapDispose($hBmp_Blur)
		_GDIPlus_GraphicsDispose($hGfx_Blur)
		_GDIPlus_BitmapDispose($hBitmap_Blur)
		$tLayout.X = 0
		$tLayout.Y = 0
	EndIf
	_GDIPlus_PathReset($hPath)
	_GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, $iFontStyle, $fFontSize, $hFormat)
	_GDIPlus_BrushSetSolidColor($hBrush, $iColorText1)
	Local $aCoord = _GDIPlus_PathGetWorldBounds($hPath)
	Local $hBrush_Fill
	If $bGradient Then
		$hBrush_Fill = _GDIPlus_LineBrushCreate($aCoord[0] + $aCoord[2] * 0.5, $aCoord[1], $aCoord[2], $aCoord[3], $iColorText2, $iColorText1, 1)
		_GDIPlus_LineBrushSetGammaCorrection($hBrush_Fill)
	Else
		$hBrush_Fill = _GDIPlus_BrushCreateSolid($iColorText2)
	EndIf
	_GDIPlus_GraphicsFillPath($hGfx, $hPath, $hBrush_Fill)
	_GDIPlus_GraphicsDrawPath($hGfx, $hPath, $hPen)
	_GDIPlus_PenDispose($hPen)
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_BrushDispose($hBrush_Fill)
	_GDIPlus_FontFamilyDispose($hFamily)
	_GDIPlus_StringFormatDispose($hFormat)
	_GDIPlus_PathDispose($hPath)
	_GDIPlus_GraphicsDispose($hGfx)
	$__bGUIFade__ = $bGUIFade
	$__iGUIFadeInTimer__ = $iGUIFadeInTimer
	$__iGUIFadeOutTimer__ = $iGUIFadeOutTimer
	$__iCtrl__ = $iPic
	$__iAnimColor__ = $iAnimColor
	$__bAnimShadow__ = $bAnimShadow
	$__bAnim__ = $bAnim
	$__hBitmap__ = $hBitmap
	$__iX__ = $iX_Anim
	$__iY__ = $iY_Anim
	_WinAPI_CopyBitmapToCtrl($hBitmap, $iPic)
	If $bAnim Then
		Dim $__aAnims__[3][2] = [["__PlayAnim__3", 30], ["__PlayAnim__2", 40], ["__PlayAnim__1", 50]]
		$iAnim = $iAnim < 0 ? 0 : $iAnim > UBound($__aAnims__) - 1 ? Random(0, UBound($__aAnims__) - 1, 1) : $iAnim
		$__iW__ = $iW
		$__iH__ = $iH
		Call($__aAnims__[$iAnim][0])
		GUIRegisterMsg($WM_TIMER, $__aAnims__[$iAnim][0])
		DllCall("user32.dll", "int", "SetTimer", "hwnd", $hGUI_Splash, "int", 0, "int", $__aAnims__[$iAnim][1], "int", 0)
		$__iAnim__ = $iAnim
	Else
		_GDIPlus_BitmapDispose($hBitmap)
	EndIf
	ConsoleWrite(TimerDiff($fTimer) & " ms" & @CRLF)
	Switch $bGUIFade
		Case True
			_WinAPI_AnimateWindow($hGUI_Splash, BitOR($AW_BLEND, $AW_ACTIVATE), $iGUIFadeInTimer)
			GUISetState(@SW_SHOW, $hGUI_Splash)
		Case False
			GUISetState(@SW_SHOW, $hGUI_Splash)
	EndSwitch
	WinSetTrans($hGUI_Splash, "", $iGUITrans)
	Return $hGUI_Splash
EndFunc   ;==>_SplashTextEx

Func __PlayAnim__1()
	Local Const $hBitmap_Anim = _GDIPlus_BitmapCreateFromScan0($__iW__, $__iH__)
	Local Const $hGfx_Anim = _GDIPlus_ImageGetGraphicsContext($hBitmap_Anim)
	_GDIPlus_GraphicsSetSmoothingMode($hGfx_Anim, 4)
	Local Const $hBrush_Anim = _GDIPlus_BrushCreateSolid($__iAnimColor__), $hPen_Anim = _GDIPlus_PenCreate(Shift_ARGB_ColorValue($__iAnimColor__, 1, True), 1)
	Local Const $hPath_Anim = _GDIPlus_PathCreate()
	Local Const $iSize_Rect = $__iW__ > $__iH__ ? Int($__iH__ / 10) > 16 ? 16 : Int($__iH__ / 10) : Int($__iW__ / 10) > 16 ? 16 : Int($__iW__ / 10), $iDeltaW = ($iSize_Rect + $iSize_Rect * 0.3333), $iRect = 3
;~ 	Local Const $iX_Anim = $__iW__ - ($iRect + 1) * $iDeltaW, $iY_Anim = $__iH__ - 2 * ($iSize_Rect + $iSize_Rect / 10)
	Local Const $iX_Anim = $__iX__ - $iDeltaW * ($iRect + 1), $iY_Anim = $__iY__ - $iDeltaW * 1.5
	Local $i, $iRS
	Local Static $f1 = 0, $f2 = 0
	For $i = 0 To $iRect - 1
		$iRS = Int($iSize_Rect * Abs(Sin($f1 * 5 + $f2)))
		$iRS = ($iRS < 2) ? 2 : $iRS
		_GDIPlus_PathAddRectangle($hPath_Anim, $iX_Anim + $i * $iDeltaW + ($iSize_Rect - $iRS) / 2, $iY_Anim + ($iSize_Rect - $iRS) / 2, $iRS, $iRS)
		$f2 += 0.775
	Next
	$f1 += 0.11
	_GDIPlus_GraphicsDrawImage($hGfx_Anim, $__hBitmap__, 0, 0)
	_GDIPlus_GraphicsFillPath($hGfx_Anim, $hPath_Anim, $hBrush_Anim)
	_GDIPlus_GraphicsDrawPath($hGfx_Anim, $hPath_Anim, $hPen_Anim)
	_WinAPI_CopyBitmapToCtrl($hBitmap_Anim, $__iCtrl__)
	_GDIPlus_PathDispose($hPath_Anim)
	_GDIPlus_BrushDispose($hBrush_Anim)
	_GDIPlus_PenDispose($hPen_Anim)
	_GDIPlus_GraphicsDispose($hGfx_Anim)
	_GDIPlus_BitmapDispose($hBitmap_Anim)
EndFunc   ;==>__PlayAnim__1

Func __PlayAnim__2()
	Local Const $hBitmap_Anim = _GDIPlus_BitmapCreateFromScan0($__iW__, $__iH__)
	Local Const $hGfx_Anim = _GDIPlus_ImageGetGraphicsContext($hBitmap_Anim)
	_GDIPlus_GraphicsSetSmoothingMode($hGfx_Anim, 4)
	Local Const $hBrush_Anim = _GDIPlus_BrushCreateSolid($__iAnimColor__), $hBrush_AnimShadow = _GDIPlus_BrushCreateSolid(Shift_ARGB_ColorValue($__iAnimColor__, 5, True)), $hPen_Anim = _GDIPlus_PenCreate(0x40000000)
	Local Const $hPath_Anim = _GDIPlus_PathCreate(), $hPath_AnimShadow = _GDIPlus_PathCreate()
	Local Const $iSize_Ellipse = $__iW__ > $__iH__ ? Int($__iH__ / 10) > 16 ? 16 : Int($__iH__ / 10) : Int($__iW__ / 10) > 16 ? 16 : Int($__iW__ / 10), $iDeltaW = ($iSize_Ellipse + $iSize_Ellipse * 0.3333), $iEllipses = 5, _
			$fSpeed = (75 / $iEllipses) / 350, $fDeltaY = $iSize_Ellipse * 0.75
;~ 	Local Const $iX_Anim = $__iW__ - ($iEllipses + 1) * $iDeltaW, $iY_Anim = $__iH__ - 3 * $iSize_Ellipse
	Local Const $iX_Anim = $__iX__ - ($iEllipses + 1) * $iDeltaW, $iY_Anim = $__iY__ - 3 * $iSize_Ellipse
	Local $i, $iRS, $r
	Local Static $f1 = 1
	For $i = 0 To $iEllipses - 1
		$iRS = $iSize_Ellipse + Sin($i + $f1) * $fDeltaY
		_GDIPlus_PathAddEllipse($hPath_Anim, $iX_Anim + $i * $iDeltaW, $iY_Anim - $iRS, $iSize_Ellipse, $iSize_Ellipse)
		$r = $__bAnimShadow__ ? _GDIPlus_PathAddEllipse($hPath_AnimShadow, $iX_Anim + $i * $iDeltaW, $iY_Anim + $iRS + $iSize_Ellipse / 2 + 1, $iSize_Ellipse, $iSize_Ellipse) : ""
		$f1 += $fSpeed
	Next
	_GDIPlus_GraphicsDrawImage($hGfx_Anim, $__hBitmap__, 0, 0)
	_GDIPlus_GraphicsFillPath($hGfx_Anim, $hPath_Anim, $hBrush_Anim)
	$r = $__bAnimShadow__ ? _GDIPlus_GraphicsFillPath($hGfx_Anim, $hPath_AnimShadow, $hBrush_AnimShadow) : ""
	_GDIPlus_GraphicsDrawPath($hGfx_Anim, $hPath_Anim, $hPen_Anim)
	_WinAPI_CopyBitmapToCtrl($hBitmap_Anim, $__iCtrl__)
	_GDIPlus_PathDispose($hPath_Anim)
	_GDIPlus_PathDispose($hPath_AnimShadow)
	_GDIPlus_BrushDispose($hBrush_Anim)
	_GDIPlus_BrushDispose($hBrush_AnimShadow)
	_GDIPlus_PenDispose($hPen_Anim)
	_GDIPlus_GraphicsDispose($hGfx_Anim)
	_GDIPlus_BitmapDispose($hBitmap_Anim)
EndFunc   ;==>__PlayAnim__2

Func __PlayAnim__3()
	Local Const $hBitmap_Anim = _GDIPlus_BitmapCreateFromScan0($__iW__, $__iH__)
	Local Const $hGfx_Anim = _GDIPlus_ImageGetGraphicsContext($hBitmap_Anim)
	_GDIPlus_GraphicsSetSmoothingMode($hGfx_Anim, 4)
	Local Const $hPath_Anim = _GDIPlus_PathCreate(), $hPath_AnimShadow = _GDIPlus_PathCreate(), $iMaxSize = 80
	Local Const $iSize_Arc = $__iW__ > $__iH__ ? Int($__iH__ / 2) > $iMaxSize ? $iMaxSize : Int($__iH__ / 2) : Int($__iW__ / 2) > $iMaxSize ? $iMaxSize : Int($__iW__ / 2)
;~ 	Local Const $iX_Anim = $__iW__ - $iSize_Arc * 1.5, $iY_Anim = $__iH__ - $iSize_Arc * 1.25
	Local Const $iX_Anim = $__iX__ - $iSize_Arc * 1.5, $iY_Anim = $__iY__ - $iSize_Arc * 1.25
	Local $i, $iRS, $fSpeed_Arc = 6, $fArc = 0.7
	Local Static $fStartAngle = 180, $fSweepAngle = 0, $iMode = 0, $iPenSize = $iSize_Arc * 0.25
	Local Const $hPen_Anim = _GDIPlus_PenCreate(Shift_ARGB_ColorValue($__iAnimColor__, 1, True), $iPenSize), _
			$hPen_AnimShadow = _GDIPlus_PenCreate(Shift_ARGB_ColorValue($__iAnimColor__, 5, True), $iPenSize)

	_GDIPlus_PathAddArc($hPath_Anim, $iX_Anim, $iY_Anim, $iSize_Arc, $iSize_Arc, $fStartAngle, $fSweepAngle)
	$i = $__bAnimShadow__ ? _GDIPlus_PathAddArc($hPath_AnimShadow, $iX_Anim, $iY_Anim + $iSize_Arc * 0.125, $iSize_Arc, $iSize_Arc, -$fStartAngle, -$fSweepAngle) : ""

	Switch $iMode
		Case 0
			If $fSweepAngle > 89 Then
				If $fStartAngle < 271 Then
					$fStartAngle += $fSpeed_Arc
				Else
					$iMode = 1
					ContinueCase
				EndIf
			Else
				$fSweepAngle += $fSpeed_Arc
				$iPenSize -= $fArc
				_GDIPlus_PenSetWidth($hPen_Anim, $iPenSize)
			EndIf
		Case 1
			If $fStartAngle + $fSpeed_Arc < 350 Then
				$fStartAngle += $fSpeed_Arc
				$fSweepAngle -= $fSpeed_Arc
				$iPenSize += $fArc
				_GDIPlus_PenSetWidth($hPen_Anim, $iPenSize)
			Else
				$iMode = 2
				ContinueCase
			EndIf
		Case 2
			If $fStartAngle > 269 Then
				$fStartAngle -= $fSpeed_Arc
				$fSweepAngle += $fSpeed_Arc
				$iPenSize -= $fArc
				_GDIPlus_PenSetWidth($hPen_Anim, $iPenSize)
			Else
				If $fStartAngle > 179 Then
					$fStartAngle -= $fSpeed_Arc
				Else
					$iMode = 3
					ContinueCase
				EndIf
			EndIf
		Case 3
			If $fSweepAngle - 2 * $fSpeed_Arc > 10 Then
				$fSweepAngle -= $fSpeed_Arc
				$iPenSize += $fArc
				_GDIPlus_PenSetWidth($hPen_Anim, $iPenSize)
			Else
				$iMode = 0
				ContinueCase
			EndIf
	EndSwitch

	_GDIPlus_GraphicsDrawImage($hGfx_Anim, $__hBitmap__, 0, 0)
	_GDIPlus_GraphicsDrawPath($hGfx_Anim, $hPath_Anim, $hPen_Anim)
	$i = $__bAnimShadow__ ? _GDIPlus_GraphicsDrawPath($hGfx_Anim, $hPath_AnimShadow, $hPen_AnimShadow) : ""
	_WinAPI_CopyBitmapToCtrl($hBitmap_Anim, $__iCtrl__)
	_GDIPlus_PathDispose($hPath_Anim)
	_GDIPlus_PathDispose($hPath_AnimShadow)
	_GDIPlus_PenDispose($hPen_Anim)
	_GDIPlus_GraphicsDispose($hGfx_Anim)
	_GDIPlus_BitmapDispose($hBitmap_Anim)
EndFunc   ;==>__PlayAnim__3

Func Shift_ARGB_ColorValue($iARGB, $iShiftBy = 1, $bAlphaDiv = True)
	Local $iA = BitAND(BitShift($iARGB, 24), 0x000000FF)
	If $bAlphaDiv Then $iA = BitShift($iA, $iShiftBy)
	Return $iA * 0x1000000 + BitShift(BitAND(BitShift($iARGB, 16), 0x000000FF), $iShiftBy) * 0x10000 + BitShift(BitAND(BitShift($iARGB, 8), 0x000000FF), $iShiftBy) * 0x100 + BitShift(BitAND($iARGB, 0x000000FF), $iShiftBy)
EndFunc   ;==>Shift_ARGB_ColorValue

Func _WinAPI_CopyBitmapToCtrl($hBitmap, $iCtrl)
	Local Const $hHBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
	_WinAPI_DeleteObject(GUICtrlSendMsg($iCtrl, 0x0172, 0x0000, $hHBitmap))
	_WinAPI_DeleteObject($hHBitmap)
EndFunc   ;==>_WinAPI_CopyBitmapToCtrl

Func _SplashTextCloseEx($hWnd, $bGUIFade = True)
	If $__bGUIFade__ Then
		WinSetTrans($hWnd, "", 0xFF)
		_WinAPI_AnimateWindow($hWnd, BitOR($AW_BLEND, $AW_HIDE), $__iGUIFadeOutTimer__)
	EndIf
	GUIRegisterMsg($WM_TIMER, "")
	_GDIPlus_BitmapDispose($__hBitmap__)
	Return GUIDelete($hWnd)
EndFunc   ;==>_SplashTextCloseEx

Func _SplashTextHideEx($hWnd)
	Return GUISetState(@SW_HIDE, $hWnd)
EndFunc   ;==>_SplashTextHideEx

Func _SplashTextShowEx($hWnd, $iFlag = @SW_SHOW)
	Return GUISetState($iFlag, $hWnd)
EndFunc   ;==>_SplashTextShowEx

Func _GDIPlus_MeasureString($sString, $sFont = "Arial", $fSize = 12, $iStyle = 0, $bRound = True)
	Local $aSize[2]
	Local Const $hFamily = _GDIPlus_FontFamilyCreate($sFont)
	If Not $hFamily Then Return SetError(1, 0, $aSize)
	Local Const $hFormat = _GDIPlus_StringFormatCreate()
	Local Const $hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle)
	Local Const $tLayout = _GDIPlus_RectFCreate(0, 0, 0, 0)
	Local Const $hGraphic = _GDIPlus_GraphicsCreateFromHWND(0)
	Local $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sString, $hFont, $tLayout, $hFormat)
	$aSize[0] = $bRound ? Round($aInfo[0].Width, 0) : $aInfo[0].Width
	$aSize[1] = $bRound ? Round($aInfo[0].Height, 0) : $aInfo[0].Height
	_GDIPlus_FontDispose($hFont)
	_GDIPlus_FontFamilyDispose($hFamily)
	_GDIPlus_StringFormatDispose($hFormat)
	_GDIPlus_GraphicsDispose($hGraphic)
	Return $aSize
EndFunc   ;==>_GDIPlus_MeasureString

Func _GDIPlus_BitmapCreateBlurBitmapv10($hBitmap, $fScale = 0.2, $iQual = 6); by eukalyptus
	Local Const $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
	Local Const $hGraphics = _GDIPlus_GraphicsCreateFromHWND(_WinAPI_GetDesktopWindow())
	Local Const $hBmpSmall = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
	Local Const $hGfxSmall = _GDIPlus_ImageGetGraphicsContext($hBmpSmall)
	_GDIPlus_GraphicsSetPixelOffsetMode($hGfxSmall, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
	Local Const $hBmpBig = _GDIPlus_BitmapCreateFromGraphics($iW, $iH, $hGraphics)
	Local Const $hGfxBig = _GDIPlus_ImageGetGraphicsContext($hBmpBig)
	_GDIPlus_GraphicsSetPixelOffsetMode($hGfxBig, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)
	_GDIPlus_GraphicsScaleTransform($hGfxSmall, $fScale, $fScale)
	_GDIPlus_GraphicsSetInterpolationMode($hGfxSmall, $iQual)
	_GDIPlus_GraphicsScaleTransform($hGfxBig, 1 / $fScale, 1 / $fScale)
	_GDIPlus_GraphicsSetInterpolationMode($hGfxBig, $iQual)
	_GDIPlus_GraphicsDrawImageRect($hGfxSmall, $hBitmap, 0, 0, $iW, $iH)
	_GDIPlus_GraphicsDrawImageRect($hGfxBig, $hBmpSmall, 0, 0, $iW, $iH)
	_GDIPlus_GraphicsDispose($hGraphics)
	_GDIPlus_BitmapDispose($hBmpSmall)
	_GDIPlus_GraphicsDispose($hGfxSmall)
	_GDIPlus_GraphicsDispose($hGfxBig)
	Return $hBmpBig
EndFunc   ;==>_GDIPlus_BitmapCreateBlurBitmapv10

;Code below was generated by: 'File to Base64 String' Code Generator v1.20 Build 2015-01-20

#Region some predefined background textures
Func _BGTexture1($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $BGTexture1
	$BGTexture1 &= 'iVBORw0KGgoAAAANSUhEUgAAAGQAAABkCAMAAABHPGVmAAABOFBMVEXm6erx8/Tw8vPw8/Py9PXv8fLx9PTv8vLy9fXu8fHw8/Tu8PHz9fbu8fLt7/Dt8PDx9PXv8vPz9vb09vfs7+/s7u/y9fbt8PHx8/P19/j09/fz9vfs7/Dw8vLr7e7r7u7y9PT2+Pn1+Pjy9Pby8/Xv8/Pv8fPw8fPz9fXr7u/w8vTq7e3v8fHx8/Xv8PLx8vT09/ju8PDp7O3u8PLq7O3q7e7z9Pby8/T19/fu8vL1+Pnp7Ozw9PTx9fXy9vbt7+/w9PPt8fHu7/Hz9ff2+fnx9fTv8/Lo6+z09vbw8fLx8vPp6+zs7vD09ffu8vHt8fDs7u7t7/Hz9vXv8PHs8PD09fbz9PXo6+vy9vXw8/Lq7O7y9vfn6uvv8vHt7vD19vjp6+vp7e3x9PPs7+72+Pjn6urz9/b2+fr7QFg7AAAXqElEQVR4Xi3Qxa60bZcb4LIX3vBw8eaX8WOGn6mRIcxw/meQtJKRLXlg6do9bqnbplKaeK9tP+V364b7ieNk0rUNom/QVfX2NozC1xOB3lHdE943FSxcvre6mPYNtE/xq/jLPW+gXXNWFX2ze+wyTiF2erj/4u10GJupAvv3FDDw+/jlw+HUDjYjQt1102hkKE8mKiMVHxOpMP715HrtAJFwIcykfW0LrX2762daEZEIQPQ83z3c1vUoxcDSQtMF6lBx/XRGBHJF9VAUPt86Ds3V293rc26rRPy9hjVD7+mxQJd9xJcL1911miyMqchUnPPPB2yXp6cbKKfDPnzburpwVdrYphaCWTNTWWKQZKHmQEF1MbPeIeqUVOHBEGfvMZruup2m6RAuKorTfRES0MvvrK2a0Q6FAdIcTWHty5B2kuxvUoilqlvjo0QAACDhirk1+mpeGtpJehzG2IGpgLVwQJUhcQdZ9LKKsD/bdDpMr5B4iRGbAx/fcZxIukjvx/QgoXevEQZhFMjUDvvDXr0YRUIc5ZY7PPx3Gxwhx97z5iqtmcV/RH8mCrKsKwkgb/qXBiVVxE4no9Okzpkuiy2MO2sRFuZu9grSIGP7xBbC4eK7jnH/9qFVEpk9/+GrVt6OxRYaZ2XxxOKomVufX3gmnIkYZIW1yUS9KyQBGOt8dPd17dq/+ZjSCiLIKNTdetmuyTbMkFIGjUYVRnFgHPqG22aEDFYoeumigDstQo6ptBgWOBIEfk6k6lwMIj3nRLEoFWJN+04HO143Rnto43gH7kcCgIoU865m4+1tMTJxGDs4J0g7lQZPtijFIiAxa2bmqjxNZmGsPJud/svUsxzaeYdh3OO4iINQhZf9VASpqZg9n+ua681RGbrK7Yltkuzr5Y3TYlFQBCAgePERs3t2Tq9nIdjKUOx0KOrWll0e0Rap7t4hnkgII1yzvrbIvvre+nW11uSyevLWVINgusqsJqognKSVuyjhUhrSHSzkxyUK3IEdg5xTxagd5r2GtL109Z5dpOcmI5GQgDN6X37cl+L8T+HdaxTObofG9nmjGcKcdt/CplD3tsRxWfCO2G3DYSr0XLxvz9iOrosNRTpawMa4uf4CMm/9PG/b5ro90+kAaM/At/MMXbWLJe6WEFWvArWWvSv69jBZc6hK322bRrjMC+Fdbj+Xvq4/dED5vtl//QtDhPn6W4Hj+mxTfVJzhchiyH7HNU2M4OJ52boTQKNuCtvMyhe7vzXebLvMnsiYbidZnzr/b/QQSt82iPp4MKKJz9E48KKiN13Q4kvyqwPU59mXsUUbG0H86U8QrD5NNBDHdBy+aIG+o00OLtHe/tiul758tW+mcctlvUIuV4bPFCiaeIllSTUTyLZ1ez+GC/LS1ZOTfOT5eHNEaLZ/GadR2oN0UsvQlp1oK/G2bL7FKJebfzWHz8cuhC5cs90OVnj8TkOCXeMN0I8L/LrZ/vDLvcO3dSDfjiaGNcfG69raVKSMnnwI58NpZ+xTGFdH'
	$BGTexture1 &= 'Vn3T89n/N+ei12MXj69Hs1Nb0AIV0UxGaJVD6z2drQ778BWVkzka5ev3PxaXJdYVsj1dyyQobTfuoYUQt8MtNXzr8GYt4usDLJ+eJSoTZ+2bH245FFH19frMAQzy07Rvxcx1GcbDIcBkuaOrNJDDaJlL9547b+jRKLpl27N5WkjlP60b/3jbGvs82cSuW1+fbXMgbwLmjlRfgePw+Wjqc6qZjZZ+vKm5wVVmMb4dmxKOdWf327U/l7Hk1p1aEsgM4OamfN5aZU9O7+/v339Z1z+lHX7j0U50wPum6Jsc7v+G6VKoZvS+ajme23nRrkmhInvJHf6F0s65P0DP0srJ5BZ65sH6Suq7VR3Yj62Nh1Jd24NV2thCdO1A/90P/d2vi+S61f5nbZpMHEUEbRSt9G86RLntrvvGr96/8WY4S4Qxde7bRTnPbaxQXT+7PF3y8mxV1+xEG5SI/RiUIFB1GEV1U6/Tfr+/L8cogIyjDg9fN+qW9bgDVOu+yGINz82PN4GAewc6A/33kJexPbnlD13Q85hYem5dFFKmRVAKCkVcGCFQmAHO5FiXMk6NQu87k95/O5zYt6t4fVs8yqn+3ivygnAkhgL+lZaxXsvoflQfRbtH/65ztPWHZyGGRPfM65YvEhS6q5L0NWdxp+5gRp3G25m1r94OIcswTnc110tHgV64n4Oq1tKnezrlfrLnas0TNg2ROr7fN37D0j8ut1PI7HBYnu+mt2WYDq202InExNbvTt4sj5ujDS+IONw29o1jASaC/QJr7jw+0+TSWthfTmSKphvTTRP3b60OMo2kdH+Vm5f397dlOLWYdssgcmRP60dSuyrY87oSbparl2l/aKB3XTUI8Zk9U/t3N9UOEtqfdOpPKX6crTrZGjRETo25ehXNDJfd9VjkAnPqxUd1/f/mJT87MsR+8uH+/rYVZDrm3nVuDnWbf/e0Tq3Q+6X9Rvqcc0+uPcVa1nBYMblc1y6zxLaTbPcLJ/OaHveWv+L9yVKH4n1j+5DZ548xRUHqcGt5s14yVeop9DJPtyfoPxv9E5nn3EQys74cjoDIyWzBvCpklF2W6XMynzb7cOn0i+ZdtBavDm2QzfvWE8+3FM9rvprGkVZTHa2FIYynw1TKPVL1dGqTtRPxyMUG+5i06TCiS5js0hAz6M/6ffO5AtSeum39hRQ+jNDOhhWC7YKTGMtCW+R2H1Dbh3Ma2xdfiHcpvxwZYWcoWWjDaFMxcxlK7ta92bg3XW+ggEg0siuPT09X93LfFpwtJqzVtI+yD4jK/NnVu6IMzfpnlxt8faCftS+xCHROzVyDnKDLYd+WxXcqJ4mqerN2V+3Jvp2fL0uL/KzLVo3rs82HQ4G5tl7HZaBmpua6YZm12LpyaKwCVdaZLjK7rjDZD4FXp2ky7JTDMn5uIWwFohxDmfW0P5lE6cmgrJ3xvh1iuX3IyT5avHR2uNpUr+UT8fFQNI9KK1XdQVX2rTGmUA4e6DuafDmNbyegjHYWMzstXMrtP3oORXVLW/qm66qsFvtG0Uxgb1iv2k4/lcPo/nljlA8ylEdhsoUbuuHifVPY/ag7QD5BbUvvR7xGSNe8/O7phyv8Mz8UQN2zb1ozq/eOwko9ps+6Xi6r9q1MuZ5JMsQCx9ZopQhUX98oVOoyndadbp1QvdlUvbGuR1fP7fL0v3tf69gWgqjs8Mvx707Xy9pBG25b0NVp25NPWLsIPj2ujvapchaU6WFs99N+xHZRfKi7sdqI6iIiqSQGk6h49FUnkmHwsTnQHc908KrbEy2KRQMM8HXbN02KLxGuCcUy1X9qDyUwuzW95DGxM8X9V03hPVcRXeeyVNor+rOrOiCoY9kuEjDjwDa21Q/7scUp5mhS4qbtTYyobaSuKjCJKrJuW+KrL/iSUdedL1rH8Y52MLWywGWhPbR03S5bz76uPUeBoIzTQzvq1P6+iAsbpf14P03HbdpH2xfc2dAkPX27qdO4N1+f6n+QZbJZ'
	$BGTexture1 &= 'd46tMwLZJjazcSwibF/ckmh0r/rN5SJnLpmOsMf+3Jciych8VJsE+j+eRuFt4Zzjw2jDr8v8Wb8/lIJ3eilTfL1X7PZFU6Tw8pm0vUF5KKn5U+VEpaZHkX6z3eTl6UqCtJBP88YmqoiwPEz1CvESgmz7QthU8iZOY/F5/Wwtc/6t+W685xwEfZutyKe5rf3pBx2y93NAJSE/Z76rlf1ZJ2ZIuNbujbqyFLYT7fnWnexHP00BG+nLvoyHQfWHI7/sy7DtcDAVwlMFuQoLjUeUEPX9X4wPBdpTUcZPSnTw1XIUS/+oNhav4eBxY1X3WfDopX1uNhbIeBqGaZTjenrQRN99F8UgHyvEFb861xhsUa1ErSog0Q6mCbHSFoKn0UoBurKExDL8A4EjwgTw55Xiikp0lGKn8AvfR++525LNWrCNnCHZdWYzev/TFsN1q5/CzwClWqC2O/di0fZjw0asGsFozHQ5DVOjDINNE9thqNP9oRm877/aS+zWdXWvvowmM1SwXdZ6KubrKnubj5m6VmxXfWmCRWrV1gR4J4rg/Ot9IUPXiGYPhw93NDN2bU0l2hjGi5a3hp2k1oC3Ii8FLkPDdo3DaD6jKEz9+aqm65oc9DgHAYTVwWwqOEczQZRz+7KV8kBVhfi8etRMtkPEehPB6y77prRX48QI19pKIULaab+f9qc3vcc4ljYewi//3rWJi2QKF/zdPhznabxvgEDB+J9/tMUBtCIha/e4NaMDy7xTf5Ymx0doDcpyGKkYyx1OYxt/LKlq5aHEZKIdypYemsBfqWRKrVMptwZ4Xi/9dDuWIFImC0gZTNQBMGS3LstzUPOYDtWjpqbEHwb0bf3F4T4UTPkNUMbmmTKp+r9xiMjarbCWhIWlT3Z9WjfGMpWfsvdE3Db0VHUX5o5xh5nzTCuCWh19neFAiPr57pWEab4jaRa+9aaX9LDTKcxacVVVhk21FErAgm1/KrMKKzwVOudj8Lg7U1iNjNYGETMLeTme0N0oJooWlQvbPlJKZJXZ1Y0kFTL3DkhwOiwRQcB1W7PsG/1xVRtP/DO8pMiuSyw0+HJq/uhh/MQkTo2yUJUgh9MkAM2tHB7KmyMFJoCuPlgEs7aCu8NhsjnVbV6zS1CwmBnvDrclAjtWgNJT7GDpUUTVtyR5dqr4O1VoZmpNRaXdfbdFXRZbgONisl6uLyPQI75vSHGlTXLjrBC4IEHQX+yE7sQMgQdUk8Y2iHOvb+KvDGzsLu58pfUsDVzgFST85hrFgRI8Wc41zJVF8g1MKEfZ30EK0XvXvrsJn4GPUSJhQldv7eG++TR1YmLa+8Pt278h9AaCNqULxAKiW39nFI9eRkK7IkobB02figVas9YiADnO207Ru+oLcprMEBAT9TDg3lT8LHlnZTIK+nbEydgvKaUEDDJQf/eU0ppoV1drC89zpqvjX/tki4jZQt+1QcR1Jqo4bYKY0qh90xImWY83K0hzmKuGjSSE022odqdusf/lFJjZwimg0K/djdRNdea50kS5U19Bne8IiCu/RfD09uFkNkNmWcn1qKtNLeiPKiwlggJIv1yg2+u2N1d1hiBsTpfc/tkZomJLsWWJwn7dFbOjOuoZsoRrKvzI8UCwcT4XDNpn4cM0vZq12xAVpAV07TFBD+1kApG/3p9E4a6V6KuiIppF6BHUn2MHmwZyscG7Olw9Yr3mn3E70iLHr754Czag/PoEWWcpIl7JpRTVrlw0bg3q2pcA24NNf3GPpKB3oq8pFCh2VzVr+9FiUfUIxmkvGs1oZWzbk38YdAWV0wG0m7VK0NSt+aU8fH0f3WNirjXfZO9+Krz9qolNFgypsxR/WXTdbZ2AiCzv8igBK5RPFfetTG26b0fww/FZyp14i28gfVVMIxyfHOOwb/RnK8f775eBbRRdL+yfSSujSWAo9AiFu+62Lbu6c5md8K52mFTxKSHkeOANDP/5qiIs+1PZF+i3ZaDk4/IwuiL0+tk6HvYB'
	$BGTexture1 &= '5zvSYf2ZlrLQ8eePiThN9lp81zftq3sdSgtCE+2L96XxM9fc0uJlpvStr98gog7DByp+n+rQ8RTzuhTdbrZL2UO0r0Bu7ioB0LXnGbYPKcEdVwXwqK+mgy0RrKhLjLdbf5PrqqWIqB1/2yUK125DLCGZmXxvnn2h6+zPNqRYo+3teXR1ddX+i2xGo3jKsttP6q3R0yNqIsJkBhbgzNLidFio9tegWSsR4ziN054vKMEjwosJx94ZQb5CbQeJpbEOi0DdwBJVUf7tTg4FEqLqRyXPitdh4rC7qBWJv5yUpZDWRnO5C4e1QSEWC4/pepYQFYGS+jPG38jYamJ+EUbqzIgAsVu1LBpyRMxOM9ZjnYYI44kOfBvvrROZ9ZVA+7nAgwvAaSymVlwdDSw+D+IJ0eG2VgmwkBFWOwLkDoSqRICsjsVK9/bvhrJIhLCYjQc7bp5QdUIGYwSWOOw9E+Nk0aZmvkAz9c3aY28hIh2sXm3imrYQu+4AIFEsZkVtIxWtLCZ6THeAxvkIdTEHelelYV72ppnNCpRwwKHa5xepDKMJRGdSOJincN52m2IhnDGchkdNiSDVSCL71vNyuekOaIcCM+AIwiPW9dO2N6hQPNkaVV8yM/vNBvdWguJKQ8Lu+q6nyqIKDtMUwJzqRRbb74MfhihCZEVdJKhiS5UqbGMhKeb6vxz4fG+LCVmNEChcxNGmySocqhwPyy7E58U0aSFtbMXnjyJCNuXDH//4434EZJ6rRIkIzOI4NTP3ObtmkiolAtLaHSEWiHbbwNc2GaIYRO0w7sJOdAkHhlimXx7iSLPHtig3j3EEUp1eSxRa4c8KmKhvHfAlKtS7+tCQK8oSdie0Rs0zKyhTee3HN3XYOaeCFPNcmCgfSndy1luka86sfw7VMtrC0BoWqr+CZ27amkVAe3dVt9+uvdcIqHIa5Sa/tzq7uhOy3vTdmukOj7LQTCWiLlNFsvja1zniN4Oq27epj5q+lJCIoHQ5HAbKpxTQVb5+hVxhlqsymunqzTWrLDERed31uRrgWAIwnIu4jEVKSBDpkOC2rSRtkDkd2ruNEbWasUZDZu/A2JqRFbNXYAaVY8ELYYixInesqPUPxIs4q3FpfAMRgF4P9xNnsfbxuvYuS2smgIsi8Lz3bVufSwThN6oOCl7An+sSjb8yKD+cFfI4jEOE7CxY4w9xGhaAXILutU2vC5PT6csqn3xiFZKb88v2qg1CKPox3bW/cZcIWziJ9jVdUIUsd/x8Om+1VK3dPi+HveyASsUSlZ4AGOw3aG0q3sWatXG6bdEIl6oQooUKudBFqoQXOyrMxUOEQbFPoaggjjG7qoi1gp0TrIqzYt0WcrFDWbdNIz4YEWYh42QLGMYK0F3qa4tisWRKKKPORHcECNDEpX6/uCqaOSUIdd8pZDKtFg0dxWYMt0NPd9d0upUCgcMv2UqYEOuqqcN+ZPbsa8oibo1B1AjKEsaEEIqYWBFRBeuudxi01mgLMPvZNZqkD4cGtxmobQqyYK3lSzKquK7XGw1T1W/VK5GVEnKMILEU48+quRJretAV5C92SyUchMpi4milKsUzx4cgq/KdL+O+2STbvHBeLKiAJ61IrYDcoecZ6B6MISpoesNIKXFzjXAnKTtf7BSMEMhZtfvQIFPYOR0hnmrrdcsw+xC1BoI8nUGCMbYykBFQlRBBNFbt1QSozDWK1PqBzbT3Xd61FjoL7wYTeo/i8FWlGFykKERlKOG1jIMwgqXQjMEqwxBSpQKcmqgHHU5zM/W+zvw9wTaG9m1nQUJnlQiTgu4GWaCwUkXmaYrIVBqPGO7qQmO6O1lMM2eWAYD+t+9PmqrigY9lfBs04h1VDGHzC8pObBGogoKzGz2mENIxTEsp1sYmripIHA5Wm4HIm7XjXzfXKGYl/PjTvgCqpHa3KVxq1YQv7lRU7PTDaYCDIueQBCBi5VS8TlPQEIfwFC7mv3Wi2r4xDApKknB3aSGATWYE8ah9'
	$BGTexture1 &= 'BQUKUWoqCnXtu/46IiyAIFyz5wqbBgopTmvWmniNcthbgy6ICXV6uA0QWw+zEHdUex0sUgY5JuiKu1fUHiXOPphv667TIowKaCmG7JdtU6PwkYa0FmbiYiJSrONExEVZsbyk6SzT+wk0EtnXm/Lrw7B2gb5Y2olQDaqX8P934tCEgbHYDCKfi+zv2/7Q3LkwCrWv0KOIc6+umRCPBsUsrQVLSGniqhQLMAAwFrsTDksVyb7bukdVVYiN5NvBp++t6poUVejmC2YSiIf7cbQ605C/WOvyrTr7+gffNqQGMswWhs6yhC2Aeyoll0YAvtOtE4D4m5RpKSWsnYba13XL9Oy5KukRPh2UIWKAuzMI2Dwbv0l6rUHgnVk5LUKkfqwiZyC3TgPcd483z62duJRChBHaUwyCvuHXE636dXUlNat3wAG2f4x37xYyxBmMmM85zyL++E4Ew2QOqCKGoF41WqnYuT6SMbOh967av/vuO5l4Mq6bhU2tFPH5mH7M7zTMCGWTY4dglgUy+9kNovPzbUvv6uoiEtLFRMR9eyP6+H8AhvmWOBTNch0AAAAASUVORK5CYII='
	Local Const $bString = Binary(_WinAPI_Base64Decode($BGTexture1))
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\handmadepaper.png", 18)
		If @error Then Return SetError(1, 0, 0)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_BGTexture1

Func _BGTexture2($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $BGTexture2
	$BGTexture2 &= '/9j/4AAQSkZJRgABAQEAYABgAAD/2wBDAAUDBAQEAwUEBAQFBQUGBwwIBwcHBw8LCwkMEQ8SEhEPERETFhwXExQaFRERGCEYGh0dHx8fExciJCIeJBweHx7/2wBDAQUFBQcGBw4ICA4eFBEUHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh7/wAARCABgAGADqCIAAhEBAxEB/8QAHwAAAQUBAQEBAQEAAAAAAAAAAAECAwQFBgcICQoL/8QAtRAAAgEDAwIEAwUFBAQAAAF9AQIDAAQRBRIhMUEGE1FhByJxFDKBkaEII0KxwRVS0fAkM2JyggkKFhcYGRolJicoKSo0NTY3ODk6Q0RFRkdISUpTVFVWV1hZWmNkZWZnaGlqc3R1dnd4eXqDhIWGh4iJipKTlJWWl5iZmqKjpKWmp6ipqrKztLW2t7i5usLDxMXGx8jJytLT1NXW19jZ2uHi4+Tl5ufo6erx8vP09fb3+Pn6/8QAHwEAAwEBAQEBAQEBAQAAAAAAAAECAwQFBgcICQoL/8QAtREAAgECBAQDBAcFBAQAAQJ3AAECAxEEBSExBhJBUQdhcRMiMoEIFEKRobHBCSMzUvAVYnLRChYkNOEl8RcYGRomJygpKjU2Nzg5OkNERUZHSElKU1RVVldYWVpjZGVmZ2hpanN0dXZ3eHl6goOEhYaHiImKkpOUlZaXmJmaoqOkpaanqKmqsrO0tba3uLm6wsPExcbHyMnK0tPU1dbX2Nna4uPk5ebn6Onq8vP09fb3+Pn6/9oADAOoAAIRAxEAPwD6lU4MccjO8pX7/kdM4pqbVaNHfdKVOJGt/wD61SRpImyFY7llK4MnmdOlEaSoI4EjndSh+fzBUjI12o0cckpaZk+8bcHH6U1QUaNHmR5WztbyRkfpUyCaPy4FhuZMocv5gH5UiLIiLEIrxg2SZA2QPxoGQxs6tCjzeZK+SGFuMLUkW5GhSVy0rZw4gBxxRB5iJFD5N424HLbxj8DSxrIiwxpFdtkHLmQDt2oEAby5Y43uC0jFsEwdKbkIsXnSGVyflYwZxT4lkQxxCO5kDE5fzAaI0khijRI7iTeeWMg4OKAEyn2hIiymYx8OYOlNUKrJEzF7kx8SGAcVIgfzFgWO5cmLl9w/nSASoq26rdFjH9/dxQA1TtdELEzFOH8rgU3OwiMndN5fLiDIBqZAy7YFW7YeX9/PSo1EwZIBDdkeVnzfMB/CgZHGiEqqLaNAE5Ic9c8/jSxpGQqxi1WDYSSWOafHICVZZysGz7otjz0pUkHyMs4WLy/um3PSgQ1DiOMRm1MG3n5j+NImwqgja38kZ3neSaesjZiYTbYRGflMBP6UCZSI3jkYRAHgW3JoGRw+WVhERtvJwQxZmJ/GiEJiLyvszQ7SH+c9akicOIHjeRIlB+U2+d1ELlxCySyJGqnK+R1/xoEMRkXYIVg8kZ3ks2abGsRWMW/2by8/OzO2RUyM5aN45XWEbsoYOTz2pqybo0eJ2jjGcqYOvH60AIApIRRbC38vrvNIiq0QVRbm38vlhIRUgbDCTzPLi8vo0H9KY8kexTJL+4EeNhgNAAiKQqLFD5BT5mMppgjXCrHDb+QE5bzevHWpBIpwxeIWoiBC+SckZpqyKUV1nUW4jxt+z8mgCVVmYJMftS/JxGGHPSkgSUiOXFyMRnEe4A1EDGGjdzAkxXhTKSO3ahDGHjMj23nlcAEtigCVVlLxyYu1Pln5N4yabtmbZIRdIQpwm8c8ikAiBiMrW4mK8DcwA/WjMAaPzWtvOwdvztxQMIo3YQyBrpPlOI/MAzToRK4jk/0pCFOEWYc9MUweUDAZmtvOwcfeNIjQGSHzDbeaVOCN360CJEFxI0cgS5Vhu2oZBzSYuZIUmcXC4X5Yww5GKVVj8yKSXyfOGQB5pApjBQkchSMTAYVBNwRjuPagCQLOHWX/AEs/ux+7DDNNYzLH'
	$BGTexture2 &= '9oJuwgi5jBBJoxGJ1m2ReeYxhftGAaQBciYRRmUx8KJ+DQA5TPsNwftRURAiMqM4pU+0OiTA3IHlcR8DNINokWRlj84xjCfaOCajJVtrvFbrP5fC+eeeP88UAPVpEZEaWLzmyARFjHSlieYJHG90POIOD5JOKELo0cQF23B+csKWISqsUYW7fKn59wOPWgBkUmzykln3SkEA+STjrSrKyhFlnDSnO0iLpT4vNi8iFRduCD85Ycf5zRH5oWOIrcuGzlgwAH+c0DGxO6CJZbhXkYnafIJxTfMEbw+dLC75Yr/o5AHHf1qSPzIhCm26lLEncJAMetKjNG0SKly5JPzmQMBxQIhWRg8YkeEyF2wRDnFKCyKA8sfmFjsPk5A605C6tGgaeXLsfMGPlpE3RoqL9rlLSH5twIU4oAaGQSpG8kJm2dTDnFIh2+UrSW5uNvBMBwPrUkTsmyMJcv8AJzIGUY/Gm2zuVSPbfNlDhyy8fSgAjJQxK8sXnFDhvJzjpSZAaJWeDziDhvJyKfE0gEcSrdklTmTaCO1C742hh2XJYqcvxxQMZGiokawC3aDB3MZD7ZpYBGiIsQtfJwdx84g+9EUpcJIrYhA+79m69OKSF90SGNtsIU8fZetACxBNsSQpE0RX5m80ihAkYjWGO2MI3bj5x49aSKRjFG0T4hAwQbXkf40ROzBGicLEATtFqDmgBYlj2RRwJbNFkhiZTSRJGojSFLTyznexkJBOKdEWYQtERHEC2VNpjP8AjSxK+2Fon8uMA8C3wx4/WgQxUiwixLaGEs2/5yPzpIliCj7MlmQW+YmQ0+NpHCtGXijViSvkDn6U23lMiKYmKLuyc22TQAqqnyqi25tsHcd59abEItscaJbtbhMO3mY5pytI0itHKyxBT8n2fr+FIGOxXU7LdVbK/Z8Z59KACJUxHHFFE0GzLsZSKBFGHRYorYwlSWPmH/Ip0LuY0dZovI2dPs5J+lJGxMcbLMBCqE4NvyR6GgCWPzX8uU/a1wnEYce1Mj85/LlxfLhTiPevNRoIfMRphbCbblVEh56YpY/s58lpVtxNtOAZCMfX0oAkVpXSGVlukwnyxiUc+lCLNKqS4vFIB2x+YBmo4vs/7l5fsgl2HAMpB9vpQoiYxvILUTgHavnGgYsSPMYZ3F1Gw3bU8wc05FeQxSMt4uM7U8wAH6UyMwuYGk+yeeM7V3n8KVfs7mEz/Z/NwSFEh4+tAiSNXkMcjR3CbWbCCQDJpqedLHE+LuIA8KjLg/So/KhLxtcLAs2TsHmHHXjNIFXy42uEt0lz8gMp9PSgCcpI7pKBdhtmQm4DNJD57qlzsu1wp/dhgc0zZEJI2la187ZkDzDjPbNNRUfy3b7N5/lnagmI/MetAE4Lny5yt2Nq58sEc0gEhaOYJdD92SEDAfpUSiASxs3lCfZwokPXNJiESIX8pZTHwnnHBoA//9k='
	Local $bString = _WinAPI_Base64Decode($BGTexture2)
	If @error Then Return SetError(1, 0, 0)
	$bString = Binary($bString)
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\Texture0201.jpg", 18)
		If @error Then Return SetError(2, 0, $bString)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_BGTexture2

Func _BGTexture3($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $BGTexture3
	$BGTexture3 &= '/9j/4AAQSkZJRgABAQEAYABgAAD/2wBDAAUDBAQEAwUEBAQFBQUGBwwIBwcHBw8LCwkMEQ8SEhEPERETFhwXExQaFRERGCEYGh0dHx8fExciJCIeJBweHx7/2wBDAQUFBQcGBw4ICA4eFBEUHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh7/wAARCABgAGADqCIAAhEBAxEB/8QAHwAAAQUBAQEBAQEAAAAAAAAAAAECAwQFBgcICQoL/8QAtRAAAgEDAwIEAwUFBAQAAAF9AQIDAAQRBRIhMUEGE1FhByJxFDKBkaEII0KxwRVS0fAkM2JyggkKFhcYGRolJicoKSo0NTY3ODk6Q0RFRkdISUpTVFVWV1hZWmNkZWZnaGlqc3R1dnd4eXqDhIWGh4iJipKTlJWWl5iZmqKjpKWmp6ipqrKztLW2t7i5usLDxMXGx8jJytLT1NXW19jZ2uHi4+Tl5ufo6erx8vP09fb3+Pn6/8QAHwEAAwEBAQEBAQEBAQAAAAAAAAECAwQFBgcICQoL/8QAtREAAgECBAQDBAcFBAQAAQJ3AAECAxEEBSExBhJBUQdhcRMiMoEIFEKRobHBCSMzUvAVYnLRChYkNOEl8RcYGRomJygpKjU2Nzg5OkNERUZHSElKU1RVVldYWVpjZGVmZ2hpanN0dXZ3eHl6goOEhYaHiImKkpOUlZaXmJmaoqOkpaanqKmqsrO0tba3uLm6wsPExcbHyMnK0tPU1dbX2Nna4uPk5ebn6Onq8vP09fb3+Pn6/9oADAOoAAIRAxEAPwD6mQ4MccpZ5SnD/Z+nSmptVokkcNMy8O1vn+lSRpLHsgWO7YFCDIHHHT9KWNJUWK3SO4cMh+fzAce9cpsQoFR445Zd0zJ94244/SkUGMxpJPE8rZ2t5AyKmjE0ZigEN1ISpy/mDge1EQljRIhFfOGyTIrZA/GmBXjZleFZJhJK+SpFsPlFSw7o3hSZ90rZ2uLcHFJB5qJFD5N6+4H5twx+Bp8SyIsMaRXjEg/OZAB07UAxN3lzRRvc7pG3bS0HTmm5WNIvtEnmuT8rG3yBT4lkRo4vLupN275/MBA5oiSWCGNEjuZN7ckyDjigQDy/tCRMyGYx8ObfpUaBFeOJmD3Jj4kMHQVMgk3pAqXTkxjMm4cfjTAJkC26i6LmM4fdx9M0IYinY6IXzOU4cw8Cmg7GEZIeYx8uLfIBqaMMuy3UXbZjPz5HFRoJlaOAQ3hHlE+bvB/CgCKJEJVES0aAJy3mHrnn8adHHGQqxi1EGw7mMhzT45AdpW4224jPAtjz0/zmljkGI3S4VIhH91rc9KBDYzhI1j+ymDacneR9c0kewrGsTW5hGd5MhzT0kO6JlmUQhD8ptyf0oSZCInikIiAOQLXJNAyKHyysIhNsYeQxZ2OPr706AL+58n7M0O07/nPWnRSK/kPHI6QqDlTb5zToJC4hMczpGqnK/Z+v+NAiJHRCiwLAYQG3lnbPWkiWIrGLb7NsJO9nkbI4/SpY2YtG8crLCA2UMHXmkSQNEjwuY41J3Kbc88frQAihSVjVbYW/l/e8w01FUoqKLdrfy+WWQg5qZX5D+YI4RGOGg6/hUTyx7FMko+ziPG0wGgaFiRcKixQmAp8zGY5/PtTVjXCpHBbmAR5ZvO6+9PEiEht8ItRFnb5JyRmmxyKUR1uEW3EeMfZuT/n1oYiZFmdUmP2xQIziPI56UkCTFY5gLoYj4j3AGoQY1aJ3MCTlOFMxI6jHH4UIY90Zle184rhVLMB7UhkqLMXilxeL8h+TcCTSBZ3EcmLpMKcJuGTyKaoiDRGVrcTFSFXzGUD9aAYFMXnNa+dghcu3FMAiSRhBIGu4+DiPeBn6U6ATP5UmbuPapwiyjnpimAQq0DTtaibBxyxpI2gMkPmfZfOKnBBbH0NAiRBcyPFKFu1ZQ21C4G7mjF1JAk7i5UBTtjDDkYoV'
	$BGTexture3 &= 'Y/Nill8nzgGAHnEAnP6U0gCOOUpGJQCqos/B49PahgSKtwHWX/TCBEP3YK5pjNMqC4JvFTyuY+CTSgRidJtkf2gxjC/acA03A3LOIYzKYuFW44NAIchn2G4JuyoiBERQZIp0ZuHRJgbkL5XEeACaaNolWVlTzjGNqfaev+fSowQxWR4YFn2cL9o6/wCfShgPVpEZEaSHziCARF05pYnmCRxyXSCYg4Pkk4/HFLGXRo4v9Mc4PzkjjmiISqsMe28ckH59wOPXFAxkMgTyVmnDTHIU+STjrSpKypGJZ1aUk7CIulPiM0PkQqLx8gnfuHH+c0RGUCOErdSZ3EsGAA9/1oAbC7p5QmuEeRmO0+QTj603zFjeHz5bdnJJX/RyAOO/rUsZliEKbbyUsxO4OBj1ojdkaJFS6dix+curAHFAiFZWEiCV4DIXbaRCTilUlE+eSLzC52HyCQOtKm9HjTdPKS7ESAD5aI98cYRftkxaQ4YEEKcGhjEV0EqRySQGfZ1MGcU1Tt8kO9s1xt4JhOB9alhd0CRhLqQ7OZFKjH40y3kkIjjxfsSvDnbx9KQIIyVMIklh88odreTnFNBAeFXe384g4YxZHWnwtIBHCq3jMVOZNgIH0NLH5kbQQ7bouVOXwOPpTAbHGqJGsC27Q7TuYyn1Gf8APtRAsccaLEtr5ODubzyD70QylwrqyiEA/L9l69OKSCQNDGY3AhCnI+y5zQAsITbEkMcTxEHc3nEUqKkaxJDFbGL5txM549abDIxiiMTAQgEMDa8jj9aIHZlQwuohGcqLQHP+NACxLHsijgjtmiyQxMx96SJI1EaQx2nlnO9mkJBNOiJbyjEVjiDNlTaHn/GlhVtsLQyCOMZyBbYY8e/WgQxY4hsSJbQwlm3/ALwjv3oiWJUH2aOzILHcTKRTo3kfa0RaKNSxK/Zxz9PWm28pkjBhfYu8ls2uTQA5FQBURbc22DuYufWmRLEFijSO3a324dhJjkdaejys6tHKVhCnKfZuv4UzcdqsuEtwrblNtjP4UDFiVMRxQxRNDtJd/OIxQsMavGkUNuYdpLN5p/yKW3d2SN1mh+z7On2cn8PeiNyY42WVRAqE82/Ueh9aGBNH5ziKb/TVwhxGGXnkVHGZ5BFLi/UBSRHvXmo41g3xtMLZZduVUStz0xSx/Z28h5Vt1m2kqDKRjnjPpQIlVpXSGVhdpheIxIORjikiWeZY5cXq4B2x7xzio4hb/uXlFmsu04BmIPt9KVBE3lPILUTc7V88880hhEkk7Q3DfbIyM7UEg5+lOjWSTypHF6uM7U3gZ+lMjMLtA0v2PzxkKvmH8Kcv2eQwGf7P5uCVUSn9aYh8avIY5DHcx7WbCCQc80iGeaKJsXkKhjhUZcH6VEYoWdGuFgWbLbB5hHfvQFXy0a4S3SQk7AZjyPpQBP5ckjxygXgITITcBmmwmeQJc7bxQFP7sMDmmbIhJG0rWvm7OF844z2zTVVZDE7/AGYT7DtQTlfpketJDLAZyIpyLwBVJ8sY5pqeaWjnCXYzGSEDAfpUSeQJY3YxCfZwolJ5pMQiVC/lrKYz8nnnBpsR/9k='
	Local $bString = _WinAPI_Base64Decode($BGTexture3)
	If @error Then Return SetError(1, 0, 0)
	$bString = Binary($bString)
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\Texture0202.jpg", 18)
		If @error Then Return SetError(2, 0, $bString)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_BGTexture3

Func _BGTexture4($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $BGTexture4
	$BGTexture4 &= '/9j/4AAQSkZJRgABAQEAYABgAAD/2wBDAAUDBAQEAwUEBAQFBQUGBwwIBwcHBw8LCwkMEQ8SEhEPERETFhwXExQaFRERGCEYGh0dHx8fExciJCIeJBweHx7/2wBDAQUFBQcGBw4ICA4eFBEUHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh7/wgARCABgAGADqCIAAhEBAxEB/8QAFwABAQEBAAAAAAAAAAAAAAAAAQACB//EABUBAQEAAAAAAAAAAAAAAAAAAAAB/9oADAOoAAIQAxAAAAHrJENAuYNkSZNEmsqYUKoYQSEg3lgmCQqBqGcg0OZJIaBso5YFiEJyiOSbRk3klAHRlQLQEbDOo//EAB8QAAICAwEBAQEBAAAAAAAAAAABESECMUEQEiAiMv/aAAgBqAABBQL+UlSEkVNFEY/SSZtuPN57NeUOCjukoOMbZ3vMtD0bHrKSzKJ87XvPEPVzkNQdLIZxz5Y04Y/x3ZybbpJkU/Z8kTLhSWKZLH5zvR26ITyNIsenrKBjSkoy8cEkW5HPxlJlveVj/wA39W0dizjkymfMtMyHr8ot+ZSNHzj9Qf/EABQRAQAAAAAAAAAAAAAAAAAAAFD/2gAIAQMBAT8BE//EABQRAQAAAAAAAAAAAAAAAAAAAFD/2gAIAQIBAT8BE//EACYQAAIBBAECBgMAAAAAAAAAAAABMRARIUGBAnESIEJRYZEiMqH/2gAIAagABj8CODilkck7JJf2I6RdzdNEolFrox4TR6S91ZCLXZBBySWTLXHkn+E7ORpF7XoySTCMdOiCBlulDGiTZi5DLQfsiUJ/iR0jgZbxGPamjmnYU/RuDgfv2MvJek0lGbEl/EScE+TJEUfwT5OxindmpopGslzYxDlElvmnNPkZyOiGTs6i9i9OKvvRI6qPG6OKbZs9Rs2bHlmWYP/EACEQAQACAgIDAQADAAAAAAAAAAEAESExQVFhcYGRobHB/9oACAGoAAE/IQp42wUZfSAFZuFN1x3Er7Lcwo4+rgdq+cota77lBcDWyb5mJbzzMUmviY3UHqN2o8GY0Qu1Q4rRlmlG3qPTsziFWsw8zGJ7wrDRupSkZgS7rQSoWwNsKvn3KDM7noBhGnBfkVbiuo0Ox24mOhfiaqnmAywA6SzhXzElBiVZQHuOzNHqK5D/ABM8Zb1MU/UFDpruWrWBybjgXDHcXF69zg0me5e8Ed3Lt0la39RAslrqCxu8sUF9h22RWqB7E1LymMSylcCczhKLXJG+G5Ma4PUAgjFuIHDu7XA13juUtrkncvRZjtHdWBfM2d0OoriQVDTQEG1QFP8AMUQtWiB3kUG2VddzENfkqinJxqBzYFVDgds8q+5hS6zlR2fmWuHUV+EsyeO4BZkwQXilqP8ATgmKaMFZWnyYtvFOI7Xj6jWcv5KKbxcQ1gy8Q9wzDdi6YCFEEBpzC/ZGCN3eo/l1BRBmJo0S0lgWQcvca5VZObKFRvuET0B5J3CizLXinJxFbL4zI/ZRfGHcyUOs3LuFaTOjQ9zC/TqNs9SsquNsbC08IZ+9sBuluORPPczeHdxuvB4Rq61RxLHehOIu7dHSNinhuJqY1DkX1xAaW/EDRf6mM0WVe5l4iobusVsnFHRM16wWdk3DAGPLDDVru5kNnxEu/BNz9Y5a63c//9oADAOoAAIAAwAAABDzk3i3ln3R2wXWHyQSCmnhDx3Bm1FnGWyjUlX/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAEDAQE/EBP/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAECAQE/EBP/xAAfEAEBAQEBAQEAAwEBAAAAAAABEQAhMUFRYXGBkaH/2gAIAagAAT8QDJbBQxeoEgMSGqkFk1KKAfzlIDLHkxUEU6W+dQ8bZSfl5zKir/xgJyTrE6oUfVx7C2TgNwBY884MoMQ4zReOr2YUB7aG'
	$BGTexture4 &= 'hajCpj1For0uCD6Cjzdq1vSfcpkBJ/MEwIjPq5StFC+V9w8SaTy48PRedbohk1b7g8dYIVcIKETPBcHmh1RBDvPgZhvvHIWy/rMCeQ6wj4im+OJqk7mEhKnt0Wgok6cU+uJpI9S+v3kYoQX8dwLVdP5Mokg+jFUQ833mrXiP3qUhlZg2r7V95E8LwHv+5OFYNMOxgpRDCxgTxmCiEK4Up4c8t1n1ddAUMLGHGnQmR+C4HSKGGfXXBI8MhE+CHvfYBQK6QDwV5zkKIDHakSIHxoQAQs+M6xcHXXD4aJfDoQEi/TlbQF+3cEIArvELbeNRwtrzUjRg+8nooIdfc1gQ8YgwJJUdQQCVzrlCtpATzA5wqg+3zCD4uBea9wneL3IJEgl+6vrVnj9wIh/enFRYUAL3KI5hxzqTeKOOMP6ylA8p85RZgK4xcUIB3mYWacNoRxS8CYn5T1+6FACvrEEMJXO3moxPuMjhhZzILO0FLMumoUnJIgCAOriAhTPrnHTgL3ICEQfWSTZQsrnowwHJXAGtfDrhQKE/RdzX80P/ALliJOQ+DDv8wGAg9eBZMhQoong1hCA1YJB+xdLIA9eM1EVW/BigChwuGfjUvhnKAri81UFCKGSJ0FHLILLHwZPFjS+8/jW7oK3AUEP8xd0LwA6uCyAc+3KQFUT8MmDQlCzIhZ9L6wgNCMMX/Mi0EsMAkAFP73w8FWaUlAGC/fLS8MDJRF/XMzdFVfxrm1tA91IGNUPdFGgJEDEcQ1TR6ynB9cCy49+Bv//Z'
	Local $bString = _WinAPI_Base64Decode($BGTexture4)
	If @error Then Return SetError(1, 0, 0)
	$bString = Binary($bString)
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\Texture0205.jpg", 18)
		If @error Then Return SetError(2, 0, $bString)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_BGTexture4

Func _BGTexture5($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $BGTexture5
	$BGTexture5 &= '/9j/4AAQSkZJRgABAQEAYABgAAD/2wBDAAUDBAQEAwUEBAQFBQUGBwwIBwcHBw8LCwkMEQ8SEhEPERETFhwXExQaFRERGCEYGh0dHx8fExciJCIeJBweHx7/2wBDAQUFBQcGBw4ICA4eFBEUHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh7/wgARCABgAGADqCIAAhEBAxEB/8QAGAABAQEBAQAAAAAAAAAAAAAAAgEAAwf/xAAWAQEBAQAAAAAAAAAAAAAAAAAAAQL/2gAMA6gAAhADEAAAAfXGrm0K2FmSk2mPTEipoGc+2JiOhYwWBEWoaqnJMrFMWlBU5nTTC1Nih0Lcuil7E0BenOmtqHLUXiSWQ9JVOUBLElpqDT3FSpBGiqf/xAAfEAACAgICAwEAAAAAAAAAAAAAARARAiESICIxMkH/2gAIAagAAQUC9tJQzFRm4Ts4noTbKKmx5I+hTqWebhsVQ6LRsasxVCyTliWzQ0VihNsUPFMot9mr6a6Lr5M00kyuyuXRyUNl2PJIvVsWpaRxso3f60JHFCWxidn4vRZpFxcexj0Ieyoqyqi2KHF7TuHDmzyR9CtG2XP/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAEDAQE/ARP/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAECAQE/ARP/xAAdEAABBAMBAQAAAAAAAAAAAAAhABARMSAwQAFR/9oACAGoAAY/AlbXieK3pp2yqHVeo5xnbBHinaNAK+eo4//EAB8QAAIDAAMBAQEBAAAAAAAAAAABESExEEFRYXGBwf/aAAgBqAABPyFT5IUemQa0QLiDot2MRoOb1x4Sk/w6SENHQoKEKU/g+CHZKSiMU5aIRA1p6QuhsZxWi8CQshiEsE1AkScqKJTJ7KiomhvaSpwRFCSiKzco+ktROO4M0GUwh0p0c2jFEDLgiXIifBCdYJQoQ9hcSn7w7RcYI+IPwv8ApZ4ux0BSnISK4G+EfEVAiuNRg2k4G8DqR1IhaLsRWNjTDFBRpsQT1w5pDQpfBJPASTl4M3R4rLcGKUsoo5H0SGlyIITDWki+GMlJQyxjPGGZCaGkyQux9mCRKRMD8OEIh1pXaGqh0dILRPCvT0fyS9Q5YWS0PB3h0n2iy1QkVCa19jR//9oADAOoAAIAAwAAABBKHo7b64a4JKZ+a6564UNKIL7PklsX+/vlY7f/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAEDAQE/EBP/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAECAQE/EBP/xAAgEAEAAgMBAQEBAQEBAAAAAAABABEhMUFRYXGBsZGh/9oACAGoAAE/EBUujdx3XoFxC2Sr+S4kT0IF21zDfyKxv+kDwPIQX8YWEPDUw6ZNCXqL67YEo3KAtal8pXWYM2YNwQ6E+TbgfGLgFPyB1DYvcoy3cwdrAp/7opTlfSIIYzL21eoSF/EyxUaBj+8nyCHI3nLClIUfkobFEaK/LnhHiAlE98iLdXIQ2GcYjlM6V/yX47joo0XqC3bX5ANGXC1DyKWuM5ZkgPb2W1i/SLMFHCa5p0xBFBU2TgwfYYRcu45KsaTsIN1G4hMbgEFzHTNHJiWiIKB9YlucMX7HwQVLSvkJQn8lilP2UNVcff8AIhNI/IVVRo0/EWkte15YKS69mgA1e5ihGaMYZSCxCW6iiGS4ipjzEyAc12TjBBNtwJkP1gYCquAheQqZNQi4AjZhOo2wqmBiKNQlL3m5XTcR7h5Cit+P2WGzj2WlaRgSEhbziI0LoXHNzT7uCmBW7mzvyKgw8ZknYBCWnIk2K2sRSyIcMOohewfLi3IqbrRAqBr2IRQT5HG91wguKv5ElrkJkHj/ACDwI6GLlL6nEq+Q6WSowbPG4CIzMUU/gJUaPYmi7dErYYfNwNIuSBZAuAbFusXHZqoSRQzd'
	$BGTexture5 &= 'QM0DqkSMNbzO+Hsq1QKCly2rQJpRjyBism0lZGOuQjI6gO5R7ButyrlPB2aHVbiKoOJRuqZ//9k='
	Local $bString = _WinAPI_Base64Decode($BGTexture5)
	If @error Then Return SetError(1, 0, 0)
	$bString = Binary($bString)
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\Texture0212.jpg", 18)
		If @error Then Return SetError(2, 0, $bString)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_BGTexture5

Func _BGTexture6($bSaveBinary = False, $sSavePath = @ScriptDir)
	Local $BGTexture6
	$BGTexture6 &= '/9j/4AAQSkZJRgABAQEAYABgAAD/2wBDAAUDBAQEAwUEBAQFBQUGBwwIBwcHBw8LCwkMEQ8SEhEPERETFhwXExQaFRERGCEYGh0dHx8fExciJCIeJBweHx7/2wBDAQUFBQcGBw4ICA4eFBEUHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh4eHh7/wgARCABgAGADaCIAAhEBAxEB/8QAGAABAQEBAQAAAAAAAAAAAAAAAgEAAwf/xAAWAQEBAQAAAAAAAAAAAAAAAAAAAQL/2gAMA2gAAhADEAAAAfVTJivCmnQlhRVyx0vPUrNFoQciLTGpwpiFKGswsaaLAqJZaaxUKLGzJtSLHDwxroWWmNwzlXNUQsKXRAZwisTam0xYaf/EABsQAAIDAQEBAAAAAAAAAAAAAAERABAgITAx/9oACAFoAAEFAsGClBhRWxFaMRi9hDH5KA0Nu1Y2tDYoqChh38n3A8xHlwOjO47O0Fr5OU46cJr/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAEDAQE/ARP/xAAUEQEAAAAAAAAAAAAAAAAAAABQ/9oACAECAQE/ARP/xAAZEAACAwEAAAAAAAAAAAAAAAAxQAAhUGD/2gAIAWgABj8ClJnizgFH/8QAIhAAAgICAgMAAwEAAAAAAAAAAAERIRAxQXFRYYEgkbHR/9oACAFoAAE/IWiBxhCjZyeSGn8OiOxDfJEexB5Irll8T9GzghM5JdjXrNTlHwvC+DR9GnTwlpi0X2NrkV7HBfkRI21cUNlaJkOxo2b5GX2ROEdDehpMoJTZHRtZzjmNjo/hB6QPDq4E55GmSmcSR7OM/tiSpPHFFhpFohi0H5Ml+hpFLRPk0FQ7OxLDsg0JsabQwqaIfIkN9lr0hqN6oU9kvAwrKQp4RHqRL/A15kROCE9D+id6geiKgQbC3olJBqR4XIUwf//aAAwDaAACAAMAAAAQX/SaD8LSmGyfdPX63uIO62eKi26Au6CiSmPL/8QAGBEBAAMBAAAAAAAAAAAAAAAAEQAQIED/2gAIAQMBAT8QhZZl4S3H/8QAGhEAAgMBAQAAAAAAAAAAAAAAABEBECAhMf/aAAgBAgEBPxAYqe5kStYYt+08cpn/xAAkEAEAAgICAgIDAQEBAAAAAAABABEhMUFRYXGBkaGx0cHh8P/aAAgBaAABPxArbQOa1LDlXh5mW1ZOHUESqUfxFtc1equEsW6rmLgcOKdxo0I9wll+E1Gy6p5q4UuT5ZWMLUS6B8EUFYPhYOEZeL3+5ZAlndNMYZEfMRaiXiK0Ux1n9RUFfiI0IrwRlG6cDUTQR8FlNWa8mJtS2ukSA1ka6dsbDq+txqsA9moiFhTyDuAMiD1UFAseM3GwrgrW4BhL/UF8i9F8S3C0eiGMFjp3FNonniJ0b8TiBTTX/syiKs8SgYAQVBRcagpfDxAWzXUwcD53FZWWtViaZyeYgK3jODPHcZBArGcsKLx/r/2KLBXCG/cu2UH5l2i/SSgaB4/kpoh2VqJTTjzEmGmtJED0loU0cjpgFYc6qIshlNxMADydRYVaHeJQoqePMWyFJV11AXFoepahGHiYsWHUqy7sfiUcl+alKLU7ZZbETxAq8YlXmp3XULS3zLmN33HdYpwNSk9EOv2MzHCj8x0wvg4g0AY9MPL+ILLst3iU1oTzxLFGo5DIfMAON1xcsrBrjUCLhvZM3ka9xLQ1/n8mS8Y6ngTP3EVtc9wcFl8lxht9/fqBGlJsvL/JVJgDBUbBs5pxKVg58QFAE4qpgVfWIRWXfDUpsR6T/ZlbAex3HgbemFFFB5hyUXtP11EVwXqiWjX1Kg4+5QZy+4ygG2s1MulHTf7hG19KQKQFfRuOTATkWrmgUvFC18zDHLyltRHrtxEMgBw5x7jDsXxmcTdu6lIiY4VjS1VfLUEaU/KyrA+iku2aG1m0rW2rli6YfUG6A8K3'
	$BGTexture6 &= 'KUuTm8P8lLFuSL2elmTK/UFmhelblRUjOaaqA2EQHFVfzMAWzZWYi7yvEFQp+IBQCvwwVIp4cz//2Q=='
	Local $bString = _WinAPI_Base64Decode($BGTexture6)
	If @error Then Return SetError(1, 0, 0)
	$bString = Binary($bString)
	If $bSaveBinary Then
		Local Const $hFile = FileOpen($sSavePath & "\Texture0220.jpg", 18)
		If @error Then Return SetError(2, 0, $bString)
		FileWrite($hFile, $bString)
		FileClose($hFile)
	EndIf
	Return $bString
EndFunc   ;==>_BGTexture6
#EndRegion some predefined background texures

Func _WinAPI_Base64Decode($sB64String)
	Local $aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "ptr", 0, "dword*", 0, "ptr", 0, "ptr", 0)
	If @error Or Not $aCrypt[0] Then Return SetError(1, 0, "")
	Local $bBuffer = DllStructCreate("byte[" & $aCrypt[5] & "]")
	$aCrypt = DllCall("Crypt32.dll", "bool", "CryptStringToBinaryA", "str", $sB64String, "dword", 0, "dword", 1, "struct*", $bBuffer, "dword*", $aCrypt[5], "ptr", 0, "ptr", 0)
	If @error Or Not $aCrypt[0] Then Return SetError(2, 0, "")
	Return DllStructGetData($bBuffer, 1)
EndFunc   ;==>_WinAPI_Base64Decode