GUISetHelp - How to run/execute/view CHM file ?

[mLipok]

I just want to use:

GUISetHelp(@ScriptDir& '\my.chm')

But this not works.

It works whe I use

GUISetHelp("notepad.exe")

But as the name of the function indicates a function to launch the help file, so it begs the question:
How to run / view CHM file type ? ( of course using GUISetHelp function )

mLipok

 

edit: typo and Title

Edited January 7, 2015 by mLipok

[Melba23]

mLipok,

I use this syntax:

; Set F1 help file
GUISetHelp("hh.exe " & @ScriptDir & "\my.chm")

To run the file directly I use:

ShellExecute(@ScriptDir & "\my.chm")

M23

M23

[mLipok]

Thanks.

Here is working example:

#include <GUIConstantsEx.au3>

Example_HowTo_Use_CHM_File()

Func Example_HowTo_Use_CHM_File()
    GUICreate("My GUI") ; will create a dialog box that when displayed is centered

    Local $sAutoIt_InstallDir = RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir')

    GUISetHelp('hh.exe "' & $sAutoIt_InstallDir & '\AutoIt.chm"')

    GUISetState(@SW_SHOW) ; will display an empty dialog box

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete()
EndFunc   ;==>Example_HowTo_Use_CHM_File

Edited January 7, 2015 by mLipok