Unknown function name - unexpected error

[mLipok]

Today I continue cleaning my old scripts, and I got error.

So what I do, just press F4 in S4A

and it appear with this description:

"Z:\TOOLs\Macro\PROGRAMY\__UDF\KK_Licences.au3" (970) : ==> Unknown function name.:
Case StringInStr($s_nazwa_bazy_config, "baza") <> 0 Or StringInStr($s_nazwa_bazy, "BAZA") <> 0 And _SQL_Test_Licencji('*****', '*****', 'BAZA') = True
Case StringInStr($s_nazwa_bazy_config, "baza") <> 0 Or StringInStr($s_nazwa_bazy, "BAZA") <> 0 And ^ ERROR

So I just highlight this function : _SQL_Test_Licencji and normaly press CTRL+j

And what happend ?

Nothing unexpected ??? S4A just jump in to the right UDF file.

But on the other hand, in this case this is unexpected !

Question:

Why AutoIt gives me an error "Unknown function name" when S4A correctly jumping in to the right UDF file ?

[jchd]

Is the #include before function invokation?

[mLipok]

Yes 

And CTRL+j works well, as I mention in OP

[water]

Then we need more information. At least your script and the include file.

[mLipok]

I think you know me well enough that you'd expect such a response:
Unfortunately I can not give you my script.
But certainly not give up so easily with this problem.
So I get to work, I have a lot to analyze.
But any comments ideas are most welcome, can help me quickly find the cause and hopefully a solution.
Of course, as I find it I will inform about the results.

---

This can be a recursion problem, with #include

Remarks:

in all script I use #include-once at the very top of the script

[water]

To troubleshoot such high confidential projects I suggest:

Create a copy of the include file and the script file

Strip down all code in the include file and script file until there is only the function in the include file and the call in the script.

Still get the error?

[mLipok]

Taking into account my meager language skills, in this case I have to admit that I'm not exactly sure what you mean.
But looking at my last 4 hours of analysis, I dare say that this is exactly what I am doing

edit:

work in progress......

Edited July 16, 2014 by mLipok

[Melba23]

mLipok,

On a side-note, your syntax in the problem line is not very clear and I wonder if it will work as you intend.

What you have is essentially:

Case (Comparison 1) Or (Comparison 2) And (Comparison 3)

Which can be read in 2 ways:

Case ( (Comparison 1) Or (Comparison 2) ) And (Comparison 3)
       (Do this first                 )

or

Case (Comparison 1) Or ( (Comparison 2) And (Comparison 3) )
                          (Do this first                 )

I hope you can see the difference. AutoIt has an operator precedence order, but it says that And & Or are at the same level so that is no help.

This GUI allows you to play with the various values. As you can see you do not always get the same answer for all cases - just try with the default settings:

expandcollapse popup

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Comparison 1", 10, 20, 90, 20)
GUIStartGroup()
$cRadio_1 = GUICtrlCreateRadio(" True", 100, 20, 100, 20)
GUICtrlSetState($cRadio_1, $GUI_CHECKED)
GUICtrlCreateRadio(" False", 200, 20, 200, 20)

GUICtrlCreateLabel("Comparison 2", 10, 50, 90, 20)
GUIStartGroup()
$cRadio_2 = GUICtrlCreateRadio(" True", 100, 50, 100, 20)
GUICtrlSetState($cRadio_2, $GUI_CHECKED)
GUICtrlCreateRadio(" False", 200, 50, 200, 20)

GUICtrlCreateLabel("Comparison 1", 10, 80, 90, 20)
GUIStartGroup()
$cRadio_3 = GUICtrlCreateRadio(" True", 100, 80, 100, 20)
GUICtrlCreateRadio(" False", 200, 80, 200, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
GUIStartGroup()

GUICtrlCreateLabel("(C1 Or C2) And C3", 10, 110, 100, 20)
$cAns1 = GUICtrlCreateLabel("", 10, 130, 200, 20)

GUICtrlCreateLabel("C1 Or (C2 And C3)", 10, 170, 100, 20)
$cAns2 = GUICtrlCreateLabel("", 10, 190, 200, 20)

GUICtrlCreateLabel("C1 Or C2 And C3", 10, 230, 100, 20)
$cAns3 = GUICtrlCreateLabel("", 10, 250, 200, 20)

$cTest = GUICtrlCreateButton("Test", 10, 300, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cTest
            If GUICtrlRead($cRadio_1) = 1 Then
                $b1 = True
            Else
                $b1 = False
            EndIf
            If GUICtrlRead($cRadio_2) = 1 Then
                $b2 = True
            Else
                $b2 = False
            EndIf
            If GUICtrlRead($cRadio_3) = 1 Then
                $b3 = True
            Else
                $b3 = False
            EndIf
            GUICtrlSetData($cAns1, ($b1 Or $b2) And $b3)
            GUICtrlSetData($cAns2, $b1 Or ($b2 And $b3))
            GUICtrlSetData($cAns3, $b1 Or $b2 And $b3)
    EndSwitch

WEnd

M23 Edited July 16, 2014 by Melba23
Typo

[water]

When you have stripped it down to:

Script:

#include <MySQLInclude.au3>
$bResult = _SQL_Test_Licencji('*****', '*****', 'BAZA')

MySQLInclude.au3:

Func  _SQL_Test_Licencji($suserid, $spassword,  $sdb)
EndFunc

and you still get the error then you could post this two files on the forum. So we can play with them.

[mLipok]

This problematic function is located in "KK_SQL.au3"
 
I create a copy of this function
 

Func _SQL_Test_Licencji_2()
......
EndFunc

and add some MsgBox to chceck what happend:

expandcollapse popup

#include-once
#Region INCLUDE - MY STANDARD UDF
#include ....
#include ....
#include ....
#include ....
MsgBox(0, 'KK_SQL.au3', '1')
#include ....
#include ....
#include ....
#include ....
#include ....
MsgBox(0, 'KK_SQL.au3', '2')
#include ....
#include ....
#include ....
MsgBox(0, 'KK_SQL.au3', 'n')
#include ....
#include ....
#include ....
#EndRegion INCLUDE - MY STANDARD UDF
MsgBox(0, 'KK_SQL.au3', 'Last')
MsgBox(0, 'KK_SQL.au3: IsFunc("_SQL_Test_Licencji")', IsFunc("_SQL_Test_Licencji"))
MsgBox(0, 'KK_SQL.au3: IsFunc("_SQL_Test_Licencji_2")', IsFunc("_SQL_Test_Licencji_2"))

.....
.....
Func _SQL_Test_Licencji()
EndFunc

Func _SQL_Test_Licencji_2()
EndFunc

.....
.....
.....
.....
.....
.....
.....
.....

and results of this:

MsgBox(0, 'KK_SQL.au3: IsFunc("_SQL_Test_Licencji")', IsFunc("_SQL_Test_Licencji"))
MsgBox(0, 'KK_SQL.au3: IsFunc("_SQL_Test_Licencji_2")', IsFunc("_SQL_Test_Licencji_2"))

is false.

 

Give me a few minutes for further analysis, including the Water suggestion 

[water]

You can't check includes the way you do.

All include statements are processed first. Then the resulting (combined) sourcecode is being processed.d

[mLipok]

Ok I found the issue with my own analytic capabilities

here is a "Repro":

#include-once
#Region INCLUDE - MY STANDARD UDF
#include ....
#include ....
#include ....
#include ....
#include ....
#include ....
#include ....
#EndRegion INCLUDE - MY STANDARD UDF
.....
.....
#include-once ; Now I know that: You can not use this twice in one file
.....
.....
Func _SQL_Test_Licencji()
EndFunc

Func _SQL_Test_Licencji_2()
EndFunc
.....
.....

the second #include-once was a "bug" in my case

 

EDIT: #2798

Edited July 16, 2014 by mLipok

[water]

So you should use #include-once only once

[Melba23]

mLipok,

Interesting - I will look into adding something to the Help file. But did you see my side-bar at post #8?

M23

[Melba23]

mLipok,

I cannot reproduce the problem.

Include file:

#include-once
#include <MsgBoxConstants.au3>
#include-once

Func _Test()
    MsgBox($MB_SYSTEMMODAL, "Title", "Text")
    Return True
EndFunc

Main script:

#include "Dbl_Include_Once.au3"

If _Test() Then
    MsgBox($MB_SYSTEMMODAL, "Hi", "Here")
EndIf

M23

[mLipok]

Interesting - I will look into adding something to the Help file.

 

good idea

But did you see my side-bar at post #8?

 

not yet , but I will

 

mLipok,

I cannot reproduce the problem.

Include file:

#include-once
#include <MsgBoxConstants.au3>
#include-once

Func _Test()
    MsgBox($MB_SYSTEMMODAL, "Title", "Text")
    Return True
EndFunc

Main script:

#include "Dbl_Include_Once.au3"

If _Test() Then
    MsgBox($MB_SYSTEMMODAL, "Hi", "Here")
EndIf

M23

 

I will try to make a repro.

 

You can't check includes the way you do.

All include statements are processed first. Then the resulting (combined) sourcecode is being processed.d

 

You must wait for my repro which I mention above.

Edited July 16, 2014 by mLipok

[water]

 

You can't check includes the way you do.

All include statements are processed first. Then the resulting (combined) sourcecode is being processed.d

I understand your code that you try to include some external files, write MsgBox and when clicked OK inlcude some more external files etc.

This doesn't work.

AutoIt first loads ALL external files, merges them with the main script and then executes this expanded script.

[mLipok]

AutoIt first loads ALL external files, merges them with the main script and then executes this expanded script.

 

And now I have different experience , but maybe I'am  wrong.

Please wait for repro.

now I'am busy.... 

I try to make in few hour.

[mLipok]

I cannot reproduce the problem.

 

try my Repro:

#include <MsgBoxConstants.au3>
Local $sScript = '#include-once' & @CRLF

For $i = 1 To 20
    $sScript &= '#include "' & $i & '.au3"' & @CRLF
Next

For $i = 1 To 20
    FileWrite($i & '.au3', $sScript)
    If $i = 15 Then
        FileWrite($i & '.au3', '#include-once' & @CRLF)
        FileWrite($i & '.au3', 'Func _test()' & @CRLF)
        FileWrite($i & '.au3', 'EndFunc' & @CRLF)
    EndIf
Next
FileWrite('test.au3', $sScript & @CRLF & '_Test()')
ShellExecute('15.au3', '', '', 'edit')
WinWaitActive("[REGEXPTITLE:(?i)(.*15.au3.*SciTE.*)]")
ShellExecute('test.au3', '', '', 'edit')
WinWaitActive("[REGEXPTITLE:(?i)(.*test.au3.*SciTE.*)]")

MsgBox($MB_SYSTEMMODAL, "How To", "Just run test.au3" & @CRLF & "Of course after when you close this MsgBox info.")

edit: small script clean up Edited July 16, 2014 by mLipok

[Melba23]

mLipok,

Interesting - If you have the second #include-once before the line #include "15.au3" the script works without problem - it is only if the second #include-once is placed after that point that the error occurs.

I will add a remark to the Help file explaining that not only must there be only the one such line in any file but also that it must be before any other #include lines.

M23