GUICtrlCreateMenu + _GUICtrlStatusBar_Create = bug?

[Lemonxtt]

StatusBar disabled (only 3.3.10)

#include <GuiStatusBar.au3>

$hGUI = GUICreate("(Example 1) StatusBar Set Text", 400, 300)
$Menu = GUICtrlCreateMenu('Menu')
$hStatus = _GUICtrlStatusBar_Create($hGUI)
GUISetState(@SW_SHOW)
_GUICtrlStatusBar_SetText($hStatus, "Part 5")

Do
Until GUIGetMsg() = -3

Edited December 31, 2013 by Lemonxtt

[Melba23]

Lemonxtt,

Welcome to the AutoIt forum.

If you create the status bar after the GUISetState line it appears as normal - which solves the immediate problem:

#include <GuiStatusBar.au3>

$hGUI = GUICreate("(Example 1) StatusBar Set Text", 400, 300)
$Menu = GUICtrlCreateMenu('Menu')

GUISetState(@SW_SHOW)

$hStatus = _GUICtrlStatusBar_Create($hGUI)
_GUICtrlStatusBar_SetText($hStatus, "Part 5")

Do
Until GUIGetMsg() = -3

But there is a difference from the behaviour in 3.3.8.1 - I will investigate further and open a bug report in Trac if required. Thanks for telling us.

M23

Edit:

The status bar is being created as normal. What is happening is that the menu is taking up some of the client area and so the status bar is pushed down below the bottom of the visible GUI if the GUI state is not set first. You can see this if you increase the height of the status bar:

#include <GuiStatusBar.au3>

$hGUI = GUICreate("(Example 1) StatusBar Set Text", 400, 300)
$Menu = GUICtrlCreateMenu('Menu')

$hStatus = _GUICtrlStatusBar_Create($hGUI)
_GUICtrlStatusBar_SetMinHeight ($hStatus, 50)

GUISetState(@SW_SHOW)

Do
Until GUIGetMsg() = -3

The visible part of the status bar is only ~30 pixels high - comment out the menu line and you will see the full 50.

Another quick solution is to resize the status bar once the GUI state has been set:

#include <GuiStatusBar.au3>

$hGUI = GUICreate("(Example 1) StatusBar Set Text", 400, 300)
$Menu = GUICtrlCreateMenu('Menu')

$hStatus = _GUICtrlStatusBar_Create($hGUI)

GUISetState(@SW_SHOW)

_GUICtrlStatusBar_Resize($hStatus)

Do
Until GUIGetMsg() = -3

Now it resets to the correct position even if a menu is present.

I will open a Trac ticket later this morning - thanks again for pointing this out.

Edited December 31, 2013 by Melba23

[Lemonxtt]

thank you for your support 

[Melba23]

Lemonxtt,

Now Trac #2588.

M23

[VenusProject2]

Sorry to resurrect the dead, but I got caught with this bug(Ver 3.3.10.2) wise use of an hour of my life, anyway thanks for the solution......