Operator XOR XNOR

[mLipok]

I looked through the documentation section "Language Reference / Operators"

There are operators described OR NOT AND.

 

So I remembered that there are also other type of XOR and XNOR

And here I have a question whether they were taken into account when it comes to adding them to the AutoIT?

 

The following examples.

 

XOR and XNOR Image:

https://encrypted-tbn2.gstatic.com/images?q=tbn:ANd9GcTq8IO8Ygk-IJ_LHDqmGmW3hFLeImrRVAPPl2SYJ2pktfyf7Sar

XNOR Image:

'>

 

English:

http://en.wikipedia.org/wiki/Exclusive_or

English:

http://en.wikipedia.org/wiki/Logical_equality

Polish:

http://4programmers.net/Delphi/Xor

 

 

[James]

AutoIt has:

• BitAND
• BitNOT
• BitOR
• BitRotate
• BitShift
• BitXOR

Check them out.

[mLipok]

Thanks but basically I'm talking about this functionality:

if Expression1 XOR Expression2 Then
    .............
EndIf


if Expression1 XNOR Expression2 Then
    .............
EndIf

[FireFox]

if Expression1 XOR Expression2 Then
    .............
EndIf
;is
If BitXOR(Expression1, Expression2) Then


if Expression1 XNOR Expression2 Then
    .............
EndIf
;is
If BitNOT(BitXOR(Expression1, Expression2)) Then

[mLipok]

@FireFox

Thanks

[James]

@FireFox

Thanks

You could create your own function to do this:

Func BitXNOR($a, $b)
    Return BitNot(BitXOR($a, $b))
EndFunc

[mLipok]

Bad result

ConsoleWrite('Result = ' & BitXNOR(_Test1(), _Test2()) & @CRLF)

Func BitXNOR($a, $b)
    Return BitNOT(BitXOR($a, $b))
EndFunc   ;==>BitXNOR

Func _Test1()
    Return True
EndFunc   ;==>_Test1

Func _Test2()
    Return False
EndFunc   ;==>_Test2

[FireFox]

BitNOT is not the opposed number, remember that you are working with binary.

[mLipok]

Yes I know

but I asking for something like this

if _Test1() XOR _Test2() Then
    .............
EndIf


if _Test1() XNOR _Test2() Then
    .............
EndIf

Func _Test1()
    Return True
EndFunc   ;==>_Test1

Func _Test2()
    Return False
EndFunc   ;==>_Test2

[FireFox]

Maybe this...

;if _Test1() XOR _Test2() Then
If Not (_Test1() = _Test2()) Then
EndIf

;if _Test1() XNOR _Test2() Then
If (_Test1() = _Test2()) Then

EndIf

Func _Test1()
    Return True
EndFunc ;==>_Test1

Func _Test2()
    Return False
EndFunc ;==>_Test2

[AdamUL]

Try this with the Boolean Algebra equation for XOR.

ConsoleWrite("XOR Truth Table" & @LF)
ConsoleWrite("_XOR(False, False) = " & _XOR(False, False) & @LF)
ConsoleWrite("_XOR(False, True) = " & _XOR(False, True) & @LF)
ConsoleWrite("_XOR(True, False) = " & _XOR(True, False) & @LF)
ConsoleWrite("_XOR(True, True) = " & _XOR(True, True) & @LF & @LF)

ConsoleWrite("XNOR Truth Table" & @LF)
ConsoleWrite("_XNOR(False, False) = " & _XNOR(False, False) & @LF)
ConsoleWrite("_XNOR(False, True) = " & _XNOR(False, True) & @LF)
ConsoleWrite("_XNOR(True, False) = " & _XNOR(True, False) & @LF)
ConsoleWrite("_XNOR(True, True) = " & _XNOR(True, True) & @LF)

Func _XOR($A, $B)
;~  Return ($A And (Not $B)) Or ((Not $A) And $B)
    Return ($A Or $B) And (Not ($A And $B))
EndFunc

Func _XNOR($A, $B)
    Return Not _XOR($A, $B)
;~  Return ($A And $B) Or ((Not $A) And (Not $B))
EndFunc

 

 

Adam

Edited August 15, 2013 by AdamUL

[mLipok]

it works 

Thanks

[mLipok]

I wrote on this group because I thought that such operators could be added to the AutoIT.

But the solution as suggested @ AdamUL dispelled all my doubts that a solution is available.

Except that I was on it before I got there

But at least I have given to this topic thread will make it easy to find a solution to this problem other looking for the solution.

 

ps.

I think it is a good piece of code that can be added to a standard UDF, not unless that is already in the standard install of AutoIT

[AdamUL]

@mlipok

Glad I could help.

Here are two more functions that can take up to 10 parameters each. My examples use 3 parameters, the truth tables get a lot larger after that.

 

expandcollapse popup

#NoTrayIcon
ConsoleWrite("XOR Truth Table" & @LF)
ConsoleWrite("_XOR(False, False) = " & _XOR(False, False) & @LF)
ConsoleWrite("_XOR(False, True) = " & _XOR(False, True) & @LF)
ConsoleWrite("_XOR(True, False) = " & _XOR(True, False) & @LF)
ConsoleWrite("_XOR(True, True) = " & _XOR(True, True) & @LF & @LF)

ConsoleWrite("XOR_Ex Truth Table" & @LF)
ConsoleWrite("_XOR_Ex(False, False, False) = " & _XOR_Ex(False, False, False) & @LF)
ConsoleWrite("_XOR_Ex(False, False, True) = " & _XOR_Ex(False, False, True) & @LF)
ConsoleWrite("_XOR_Ex(False, True, False) = " & _XOR_Ex(False, True, False) & @LF)
ConsoleWrite("_XOR_Ex(False, True, True) = " & _XOR_Ex(False, True, True) & @LF)
ConsoleWrite("_XOR_Ex(True, False, False) = " & _XOR_Ex(True, False, False) & @LF)
ConsoleWrite("_XOR_Ex(True, False, True) = " & _XOR_Ex(True, False, True) & @LF)
ConsoleWrite("_XOR_Ex(True, True, False) = " & _XOR_Ex(True, True, False) & @LF)
ConsoleWrite("_XOR_Ex(True, True, True) = " & _XOR_Ex(True, True, True) & @LF & @LF)

ConsoleWrite("XNOR Truth Table" & @LF)
ConsoleWrite("_XNOR(False, False) = " & _XNOR(False, False) & @LF)
ConsoleWrite("_XNOR(False, True) = " & _XNOR(False, True) & @LF)
ConsoleWrite("_XNOR(True, False) = " & _XNOR(True, False) & @LF)
ConsoleWrite("_XNOR(True, True) = " & _XNOR(True, True) & @LF & @LF)

ConsoleWrite("XNOR_Ex Truth Table" & @LF)
ConsoleWrite("_XNOR_Ex(False, False, False) = " & _XNOR_Ex(False, False, False) & @LF)
ConsoleWrite("_XNOR_Ex(False, False, True) = " & _XNOR_Ex(False, False, True) & @LF)
ConsoleWrite("_XNOR_Ex(False, True, False) = " & _XNOR_Ex(False, True, False) & @LF)
ConsoleWrite("_XNOR_Ex(False, True, True) = " & _XNOR_Ex(False, True, True) & @LF)
ConsoleWrite("_XNOR_Ex(True, False, False) = " & _XNOR_Ex(True, False, False) & @LF)
ConsoleWrite("_XNOR_Ex(True, False, True) = " & _XNOR_Ex(True, False, True) & @LF)
ConsoleWrite("_XNOR_Ex(True, True, False) = " & _XNOR_Ex(True, True, False) & @LF)
ConsoleWrite("_XNOR_Ex(True, True, True) = " & _XNOR_Ex(True, True, True) & @LF & @LF)

Func _XOR($A, $B)
;~  Return ($A And (Not $B)) Or ((Not $A) And $B)
    Return ($A Or $B) And (Not ($A And $B))
EndFunc

Func _XOR_Ex($A, $B, $C = False, $D = False, $E = False, $F = False, $G = False, $H = False, $I = False, $J = False)
    Local $fResult = False
    Select
        Case @NumParams >= 2
            $fResult = _XOR($A, $B)
            If @NumParams > 2 Then ContinueCase
        Case @NumParams >= 3
            $fResult = _XOR($fResult, $C)
            If @NumParams > 3 Then ContinueCase
        Case @NumParams >= 4
            $fResult = _XOR($fResult, $D)
            If @NumParams > 4 Then ContinueCase
        Case @NumParams >= 5
            $fResult = _XOR($fResult, $E)
            If @NumParams > 5 Then ContinueCase
        Case @NumParams >= 6
            $fResult = _XOR($fResult, $F)
            If @NumParams > 6 Then ContinueCase
        Case @NumParams >= 7
            $fResult = _XOR($fResult, $G)
            If @NumParams > 7 Then ContinueCase
        Case @NumParams >= 8
            $fResult = _XOR($fResult, $H)
            If @NumParams > 8 Then ContinueCase
        Case @NumParams >= 9
            $fResult = _XOR($fResult, $I)
            If @NumParams > 9 Then ContinueCase
        Case @NumParams >= 10
            $fResult = _XOR($fResult, $J)
    EndSelect

    Return $fResult
EndFunc

Func _XNOR($A, $B)
    Return Not _XOR($A, $B)
;~  Return ($A And $B) Or ((Not $A) And (Not $B))
EndFunc

Func _XNOR_Ex($A, $B, $C = False, $D = False, $E = False, $F = False, $G = False, $H = False, $I = False, $J = False)
    Local $fResult = False
    Select
        Case @NumParams >= 2
            $fResult = _XOR($A, $B)
            If @NumParams > 2 Then ContinueCase
        Case @NumParams >= 3
            $fResult = _XOR($fResult, $C)
            If @NumParams > 3 Then ContinueCase
        Case @NumParams >= 4
            $fResult = _XOR($fResult, $D)
            If @NumParams > 4 Then ContinueCase
        Case @NumParams >= 5
            $fResult = _XOR($fResult, $E)
            If @NumParams > 5 Then ContinueCase
        Case @NumParams >= 6
            $fResult = _XOR($fResult, $F)
            If @NumParams > 6 Then ContinueCase
        Case @NumParams >= 7
            $fResult = _XOR($fResult, $G)
            If @NumParams > 7 Then ContinueCase
        Case @NumParams >= 8
            $fResult = _XOR($fResult, $H)
            If @NumParams > 8 Then ContinueCase
        Case @NumParams >= 9
            $fResult = _XOR($fResult, $I)
            If @NumParams > 9 Then ContinueCase
        Case @NumParams >= 10
            $fResult = _XOR($fResult, $J)
    EndSelect

    Return Not $fResult
EndFunc

Adam Edited August 15, 2013 by AdamUL

[cryptotitan]

it would be great if the xorAray function appeared for an example, I have an array $ ArrA [[3] [3] and an array $ ArrB [[1000] [1000]] and in order to process this data I have to create a loop in a loop fingering the neighboring cells of array B by the array of array A. I understand that it is easier to use "exclusive or" thereby increasing the speed of data processing by 64 times.

I dream of such a function _XORaray ($ arrA, $ arrB) return $ ArrC

PS: in my case, this applies to the wave path search.

[RTFC]

@cryptotitan: you may wish to look into the functionality of the various CwiseLogicalOp functions in Eigen4AutoIt.