help on listview sorting

[talun]

Good morning to all,

I'm starting to work with autoit and I have a problem with the sorting of the listview. I saw that there are many examples in the forum but I could not figure it out. In the example below I want to sort in ascending order the various elements of listview immediately after their insertion but do not understand where I'm wrong

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>
$Form1_1 = GUICreate("Form1", 200, 300, 200, 200)
$ListView1 = GUICtrlCreateListView("Date", 5, 5, 190, 250)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 200)
$Date1 = GUICtrlCreateDate("2013/04/03 14:34:10", 5, 265, 190, 25, 0)
$sortFlag = True
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Date1
$myDate = GUICtrlRead($Date1)
if _GUICtrlListView_FindInText($ListView1, $myDate, -1) = -1 Then
$lvIndex = _GUICtrlListView_GetItemCount($ListView1)
_GUICtrlListView_InsertItem($ListView1, $myDate, $lvIndex)
_GUICtrlListView_SimpleSort($ListView1, $sortFlag, 0)
EndIf
EndSwitch
WEnd

Can anyone help me?

thanks!

Sergio

[BrewManNH]

Try modifying the listview creation line like this.

$ListView1 = GUICtrlCreateListView("Date", 5, 5, 190, 250, $LVS_SORTASCENDING)

[talun]

BrewManNH,

many thanks for your advice that works well.

However I have not yet understood why the _GUICtrlListView_SimpleSort function () does not automatically update the sorting each time it is called..

bye

Sergio

[BrewManNH]

The reason it's not sorting correctly is because the _GUICtrlListView_SimpleSort function uses _ArraySort to sort the incoming information in the array, and _ArraySort uses _ArrayReverse to reverse the array every time. So it appears that what is happening is that the information gets sorted correctly, but every other time through the function the contents are reversed. The listview is getting sorted, but it's reversing it so it gets sorted ascending then descending then back to ascending ad infinitum.

[talun]

Now I understand, thank you very much for your explanation.

cheers

Sergio

[guinness]

I re-wrote _GUICtrlListView_SimpleSort and submitted to the next version of AutoIt. This is what I created.

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlListView_SimpleSort
; Description ...: Sorts a list-view control (limited)
; Syntax.........: _GUICtrlListView_SimpleSort($hWnd, ByRef $vDescending, $iCol)
; Parameters ....: $hWnd        - Handle to the control
;                  $vDescending - Can be:
;                  | True       - Sort Descending
;                  | False      - Sort Ascending
;                  +Array       - With the following format:
;                  |[0]         - First Column
;                  |[1]         - Second Column
;                  |[n]         - Last Column
;                  $iCol        - Column number
; Return values .: None
; Author ........: Gary Frost (gafrost)
; Modified.......: guinness - Re-write of function to remove magic numbers and unnecessary use of UBound.
; Remarks .......: This is a basic sort fuction, for advanced sort see GUICtrlRegisterListViewSort
; Related .......: GUICtrlRegisterListViewSort
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _GUICtrlListView_SimpleSort($hWnd, ByRef $vDescending, $iCol)
    If $Debug_LV Then __UDF_ValidateClassName($hWnd, $__LISTVIEWCONSTANT_ClassName)

    Local $iItemCount = _GUICtrlListView_GetItemCount($hWnd)
    If $iItemCount Then
        Local $iDescending = 0
        If IsArray($vDescending) Then
            $iDescending = $vDescending[$iCol]
        Else
            $iDescending = $vDescending
        EndIf
        Local $vSeparatorChar = Opt('GUIDataSeparatorChar')
        Local $iColumnCount = _GUICtrlListView_GetColumnCount($hWnd)
        Local Enum $iIndexValue = $iColumnCount, $iItemParam ; Additional columns for the index value and ItemParam
        Local $aListViewItems[$iItemCount][$iColumnCount + 2]

        Local $aSelectedItems = StringSplit(_GUICtrlListView_GetSelectedIndices($hWnd), $vSeparatorChar)
        Local $aCheckedItems = StringSplit(__GUICtrlListView_GetCheckedIndices($hWnd), $vSeparatorChar)
        Local $sItemText, $iFocused = -1
        For $i = 0 To $iItemCount - 1 ; Rows
            If $iFocused = -1 Then
                If _GUICtrlListView_GetItemFocused($hWnd, $i) Then $iFocused = $i
            EndIf
            _GUICtrlListView_SetItemSelected($hWnd, $i, False)
            _GUICtrlListView_SetItemChecked($hWnd, $i, False)
            For $j = 0 To $iColumnCount - 1 ; Columns
                $sItemText = StringStripWS(_GUICtrlListView_GetItemText($hWnd, $i, $j), 2)
                If (StringIsFloat($sItemText) Or StringIsInt($sItemText)) Then
                    $aListViewItems[$i][$j] = Number($sItemText)
                Else
                    $aListViewItems[$i][$j] = $sItemText
                EndIf
            Next
            $aListViewItems[$i][$iIndexValue] = $i ; Index value
            $aListViewItems[$i][$iItemParam] = _GUICtrlListView_GetItemParam($hWnd, $i) ; ItemParam
        Next

        ; Sort the ListView array
        _ArraySort($aListViewItems, $iDescending, 0, 0, $iCol)

        For $i = 0 To $iItemCount - 1 ; Rows
            For $j = 0 To $iColumnCount - 1 ; Columns
                _GUICtrlListView_SetItemText($hWnd, $i, $aListViewItems[$i][$j], $j)
            Next

            _GUICtrlListView_SetItemParam($hWnd, $i, $aListViewItems[$i][$iItemParam]) ; ItemParam

            For $j = 1 To $aSelectedItems[0]
                If $aListViewItems[$i][$iIndexValue] = $aSelectedItems[$j] Then
                    If $aListViewItems[$i][$iIndexValue] = $iFocused Then
                        _GUICtrlListView_SetItemSelected($hWnd, $i, True, True)
                    Else
                        _GUICtrlListView_SetItemSelected($hWnd, $i, True)
                    EndIf
                    ExitLoop
                EndIf
            Next
            For $j = 1 To $aCheckedItems[0]
                If $aListViewItems[$i][$iIndexValue] = $aCheckedItems[$j] Then
                    _GUICtrlListView_SetItemChecked($hWnd, $i, True)
                    ExitLoop
                EndIf
            Next
        Next
        If IsArray($vDescending) Then
            $vDescending[$iCol] = Not $iDescending
        Else
            $vDescending = Not $iDescending
        EndIf
    EndIf
EndFunc   ;==>_GUICtrlListView_SimpleSort

[BrewManNH]

It does the same thing that the original does, it sorts the list ascending, then descending, then ascending etc, everytime you add a new item to the listview.

[guinness]

It's optimised from Gary's version.

[water]

But based on your description the optimization seems to be of cosmetic nature. No new functions or faster processing.

[BrewManNH]

I just figured out why this is happening with both functions, the original and the rewrite. The parameter $sortflag is passed to the function ByRef, at the end of the sort function that variable is reversed from True/False to False/True, so the next time you call the function, the $sortflag has been changed from its original value of True to False, and every subsequent call to the function reverses its value back and forth.

EDIT: I'm not sure why that the last part of the function was even put in there. Shouldn't the person using the function decide whether the column sort should be sorted the other way around the next time the function is called and not arbitrarily have it changed "under the hood"? Not only that, there's no mention that the function changes your sort direction setting after it's ended.

If IsArray($vDescending) Then
            $vDescending[$iCol] = Not $iDescending
        Else
            $vDescending = Not $iDescending
        EndIf

Edited April 11, 2013 by BrewManNH

[guinness]

But based on your description the optimization seems to be of cosmetic nature. No new functions or faster processing.

The previous version was incomprehensible to understand from an average users perspective.

I can't see what is wrong with the last part.

[water]

Your comment says that you removed magic numbers and unnecessary use of UBound. That's what I meant with "cosmetic".

[guinness]

I was agreeing with you.

[water]

What I means i: How can removing of magic numbers and UBound make a function easier to understand?

Usually the users don't try to understand the coding of a function. They use it as a black box and are happy if the function does what they need.

Edited April 11, 2013 by water

[guinness]

I did it for those who work on the UDFs i.e. me!

[BrewManNH]

I can't see what is wrong with the last part.

Is this in reference to what I posted in my edit?

[guinness]

Yes.

[BrewManNH]

My problem with the last part of this function is that it's doing something it shouldn't. It's inverting the value of the incoming variable for no good reason.

I could understand if this wasn't set up to select ascending or descending, and you wanted to reverse the sort of the items in the column of a list view that you clicked on every time you click on it. But, if you have a parameter that can be set to either sort ascending or descending, why on earth is it being changed inside the function? This shouldn't be set up this way in a production UDF because it's nonsensical to have it inverting incoming parameters for no reason, and then it's not even documented that your incoming sort direction parameter is getting changed every time you use the function. There's no reason to use ByRef on that parameter, and there's no reason to have it get inverted inside the function.

That's what's wrong with that section.