Compress PST (MS Outlook) files

[storme]

G'day all

I'm trying to update this script so it works with Office 2007 and hopfully 2010.

I've modified it so that it'll find mlcfg32.cpl instead of hard coding it.

BUT when I get to the main screen it used to have a standard listview containing the list of files but it's been changed and I can't access it anymore.

I've added a message box to stop the script before the faulty section.

If anyone has a method of getting access to the list and can tell me what the control is, then this script can be usefull again.

(I can't get the AUTOIT tag to work on the forum... the window comes up but the OK/cancel buttons don't work.

<autoit>

#include <GUIListView.au3>

;~ BlockInput(1)

SplashTextOn("Compacting now", "This may take hours...", 250, 40)

;//Runs the mail application that is in control panel.

$Path = FileGetShortName(RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Control Panel\Cpls","mlcfg32.cpl"))

Run(@SystemDir & "\control.exe " & $Path)

Opt("WinTitleMatchMode", 4)

WinWait("Mail Setup - Outlook","Setup e-mail accounts and dire")

ControlClick("Mail Setup - Outlook","Setup e-mail accounts and dire","Button2")

WinWait("Account Settings","AcctMgr Tab")

;//Gets list of data files listed

$sTitle = "Account Settings"

$hWnd = WinGetHandle($sTitle)

If @error Then

MsgBox(0,"Error","Unable to find window")

EndIf

WinActivate($hWnd)

MsgBox(0,"ERROR", "Everything works till here" & @CR & "But the controls have changed so I can't get thie listview")

$hlist = ControlGetHandle($hWnd, "", "SysListView321")

If @error Then Exit

$arraycount = _GUICtrlListView_GetItemCount($hlist)

Local $ltext[$arraycount]

$i = 0

Do

$ltext[$i] = _GUICtrlListView_GetItemText($hlist, $i)

$i = $i + 1

Until $i = $arraycount

_ArrayDisplay($ltext)

Exit

;//Goes into each listed Data file and compresses them

$b = 0

Do

_GUICtrlListView_ClickItem($hlist, $b, "left", False, 2)

Sleep(1000)

ControlClick("Personal Folders", "", "[CLASS:Button; INSTANCE:2]") ; click Compact Now

Sleep(1200)

If WinExists("Compact Now") Then WinWaitClose("Compact Now")

WinClose("Personal Folders")

$b = $b + 1

Until $b = $arraycount

WinClose("Outlook Data Files")

WinClose("Mail Setup")

;~ BlockInput(0)

<\autoit>

Thanks for the help!

John

[taietel]

storme, I have modified this line:

$hlist = ControlGetHandle($hWnd, "", "SysListView321")

with this:

$hlist = ControlGetHandle($hWnd, "", "[CLASS:SysListView32; INSTANCE:2]")

and I can get the values into array.

See if it works for you.

Regards,

taietel

[edit] There are changes also in the last part of the script, if you want it with Outlook 2010:

expandcollapse popup

#include <GUIListView.au3>
SplashTextOn("Compacting now", "This may take hours...", 250, 40)
;//Runs the mail application that is in control panel.
$Path = FileGetShortName(RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Control Panel\Cpls", "mlcfg32.cpl"))
Run(@SystemDir & "\control.exe " & $Path)
Opt("WinTitleMatchMode", 4)
WinWait("Mail Setup - Outlook", "Setup e-mail accounts and dire")
ControlClick("Mail Setup - Outlook", "Setup e-mail accounts and dire", "Button2")
WinWait("Account Settings", "AcctMgr Tab")
;//Gets list of data files listed
$sTitle = "Account Settings"
$hWnd = WinGetHandle($sTitle)
If @error Then
 MsgBox(0, "Error", "Unable to find window")
EndIf
WinActivate($hWnd)
$hlist = ControlGetHandle($hWnd, "", "[CLASS:SysListView32; INSTANCE:2]")
If @error Then Exit
$arraycount = _GUICtrlListView_GetItemCount($hlist)
Local $ltext[$arraycount]
$i = 0
Do
 $ltext[$i] = _GUICtrlListView_GetItemText($hlist, $i)
 $i = $i + 1
Until $i = $arraycount
;//Goes into each listed Data file and compresses them
$b = 0
Do
 _GUICtrlListView_ClickItem($hlist, $b, "left", False, 2)
 Sleep(1000)
 WinWaitActive("Outlook Data File")
 ControlClick("Outlook Data File", "", "[CLASS:Button; INSTANCE:2]") ; click Compact Now
 Sleep(1200)
 If WinExists("Compact Now") Then WinWaitClose("Compact Now")
 WinClose("Outlook Data File")
 $b = $b + 1
Until $b = $arraycount
WinClose("Outlook Data Files")
WinClose("Account Settings")
WinClose("Mail Setup - Outlook")
SplashOff()
MsgBox(64, "Outlook", "All accounts were processed." & @CRLF & "Closing in 5 seconds...", 5)
Exit

Edited September 25, 2011 by taietel

[Eliezer]

<snip>

Edited October 22, 2013 by Melba23
Advertising removed

[water]

Advertising commercial products isn't allowed here.

[Melba23]

Eliezer,

We do not accept adverts for payware - please do not do it again.

M23

[water]

Advertising commercial products isn't allowed here.