Is it possible to read/change vars from another Autoit script?

[Skrip]

Is it possible to read and write vars of one script with another script? I've seen the debugger, but I don't know if that'll suit the purpose.

[bundyxc]

Is it possible to read and write vars of one script with another script? I've seen the debugger, but I don't know if that'll suit the purpose.

Well, you could write your vars to an INI. Would that work?

[Skrip]

Well, you could write your vars to an INI. Would that work?

That could work. I was going to have them write to another window, then have the other script read and write to those. But I was wondering if there was a more direct way to do it.

[bundyxc]

I can't think of any, but I'm an AutoIt noob. I'm thinking that you just write to an INI (or a plaintext file), and have your other one read it. How are they going to know how to communicate with eachother? Are they both being run at the same time?

[MrCreatoR]

You can do it only with predefined interaction handeling, like this for example:

Sender.au3

#include <GuiConstantsEx.au3>

$GUI = GUICreate("Sender Script", 200, 140)

$SetVar_Button = GUICtrlCreateButton("SET Variable", 40, 20, 120, 20)
$SetValue_Input = GUICtrlCreateInput("Assign('i_Var', 1)", 40, 40, 120, 20)

$GetVar_Button = GUICtrlCreateButton("GET Variable", 40, 80, 120, 20)
$GetValue_Input = GUICtrlCreateInput("Eval('i_Var')", 40, 100, 120, 20)

GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $SetVar_Button
            $sSend_Data = "SET_VAR" & @CRLF & GUICtrlRead($SetValue_Input)
            ControlSetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1", $sSend_Data)
        Case $GetVar_Button
            $sSend_Data = "GET_VAR" & @CRLF & GUICtrlRead($GetValue_Input)
            ControlSetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1", $sSend_Data)
            
            Sleep(10)
            
            $sRet_Data = ControlGetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1")
            ControlSetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1", "")
            
            GUICtrlSetData($GetValue_Input, $sRet_Data)
    EndSwitch
WEnd

Reciever:

expandcollapse popup

#include <GuiConstantsEx.au3>

AutoItWinSetTitle("Reciever Script")

Global $i_Var = 0

$GUI = GUICreate("Reciever Script", 300, 200)
GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    
    $sInteract_Data = ControlGetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1")
    
    If $sInteract_Data <> "" Then
        ControlSetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1", "")
        
        $sFirst_Line = StringLeft($sInteract_Data, StringInStr($sInteract_Data, @CRLF))
        $sFirst_Line = StringStripWS($sFirst_Line, 3)
        
        $sMsg = StringTrimLeft($sInteract_Data, StringInStr($sInteract_Data, @CRLF))
        $sMsg = StringStripWS($sMsg, 3)
        
        Switch $sFirst_Line
            Case "GET_VAR"
                $sGet_Var = Execute($sMsg)
                If $sGet_Var = "" Then $sGet_Var = Eval($sMsg)
                ConsoleWrite($sGet_Var & @CRLF)
                ControlSetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1", $sGet_Var)
                
                While ControlGetText("[CLASS:AutoIt v3;TITLE:Reciever Script]", "", "Edit1") <> ""
                    Sleep(10)
                WEnd
            Case "SET_VAR"
                Execute($sMsg)
                MsgBox(64, $sFirst_Line, "$i_Var = " & $i_Var, 0, $GUI)
        EndSwitch
    EndIf
WEnd

Edited July 7, 2009 by MrCreatoR

[Skrip]

Oh I see. That's simple enough. Thanks.