Why does 'GUICtrlCreateListViewItem()' looks chumpy ?

[Armand]

any idea on how to fix it ?!

i used to use the UDF, but then i've realized that the UDF doesn't support UNICODE, so i moved to this and not my listview looks very chumpy... maybe i should just convert the UDF functions into UNICODE supporting ones ?!

[zackrspv]

any idea on how to fix it ?!

i used to use the UDF, but then i've realized that the UDF doesn't support UNICODE, so i moved to this and not my listview looks very chumpy... maybe i should just convert the UDF functions into UNICODE supporting ones ?!

chumpy?

[Armand]

yeah well... when it loads the items it looks like it refreshes after each item and the entire listview is like FLICKERing ...

it doesn't load up as smooth as the UDF doesn't refresh at all, it just loads up the items....

>> it looks like it's being redrawn many times....

[now u see it, now u have a blank control, now u see it again +1 item... etc]

[zackrspv]

yeah well... when it loads the items it looks like it refreshes after each item and the entire listview is like FLICKERing ...

it doesn't load up as smooth as the UDF doesn't refresh at all, it just loads up the items....

>> it looks like it's being redrawn many times....

[now u see it, now u have a blank control, now u see it again +1 item... etc]

If i remember the help file correctly; to help alleviate the flickering, the extended style: $LVS_EX_DOUBLEBUFFER usually helps with that. but i agree, ive seen that, dunno why tho.

[Armand]

already used the double buffer... i think that that what's made the UDF work so smooth... [not sure though]... anyways it has no effect on built-in func...

[Siao]

_GUICtrlListView_BeginUpdate()

add items

_GUICtrlListView_EndUpdate()

[ChrisL]

Have you tried this UDF?

; Create and insert items directly into the listview
Func MyGUICtrlCreateListViewItem($sText, $nCtrlID, $nIndex)
    Local $stLvItem = DllStructCreate("uint;int;int;uint;uint;ptr;int;int;int;int;")
    Local $stText   = DllStructCreate("char[260]")
    Local $arText   = StringSplit($sText, "|")
    
    If $nIndex = -1 Then $nIndex = GUICtrlSendMsg($nCtrlID, $LVM_GETITEMCOUNT, 0, 0)
    
    DllStructSetData($stText, 1, $arText[1]); Save the item text in the struct
        
    DllStructSetData($stLvItem, 1, BitOr($LVIF_TEXT, $LVIF_PARAM))
    DllStructSetData($stLvItem, 2, $nIndex)
    DllStructSetData($stLvItem, 6, DllStructGetPtr($stText))
; Set the lParam of the struct to the line index - unique within the listview
    DllStructSetData($stLvItem, 9, $nIndex)
    
    $nIndex = GUICtrlSendMsg($nCtrlID, $LVM_INSERTITEM, 0, DllStructGetPtr($stLvItem))

    If $nIndex > -1 Then
    ; Insert now the rest of the column text
        For $i = 2 To $arText[0]
            DllStructSetData($stText, 1, $arText[$i])
            DllStructSetData($stLvItem, 3, $i - 1); Store the subitem index
            
            GUICtrlSendMsg($nCtrlID, $LVM_SETITEMTEXT, $nIndex, DllStructGetPtr($stLvItem))
        Next
    EndIf

    $stText     = 0
    $stLvItem   = 0

EndFunc

[Armand]

@Siao

Tried that, not working... still flickering like a disco club!!!

@ChrisL

WHoooHOOO u'r the man !!!

no more flickers !!!!

P.S> i've edited it as follows and now it support UNICODE just like the built-in [the disco built-in function].

Au3. Beta 3.2.11.10.

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name...........: MyGUICtrlCreateListViewItem
; Description ...: Create and insert items directly into the listview, Unicode supported!
; Syntax.........: MyGUICtrlCreateListViewItem($sText, $nCtrlID[, $nIndex = -1])
; Parameters ....: $sText       - Text of the item and subitems seperated by seperation char. [Default "|"]
;                  $nCtrlID     - Listview control ID.
;                  $nIndex      - Item's index. [Default -1, will add at last location]
; Return values .: Nothing.
; Author ........: Unknown, Supplied by: ChrisL @www.autoitscript.com/forum/index.php?showtopic=70227&view=findpost&p=515453
; Modified.......: Armand.
; ===============================================================================================================================
Func MyGUICtrlCreateListViewItem($sText, $nCtrlID, $nIndex = -1)
    Local $stLvItem = DllStructCreate("uint;int;int;uint;uint;ptr;int;int;int;int;")
    Local $stText = DllStructCreate("wchar[260]")
    Local $arText = StringSplit($sText, "|")

    If $nIndex = -1 Then $nIndex = GUICtrlSendMsg($nCtrlID, $LVM_GETITEMCOUNT, 0, 0)

    DllStructSetData($stText, 1, $arText[1]); Save the item text in the struct

    DllStructSetData($stLvItem, 1, BitOR($LVIF_TEXT, $LVIF_PARAM))
    DllStructSetData($stLvItem, 2, $nIndex)
    DllStructSetData($stLvItem, 6, DllStructGetPtr($stText))
    ; Set the lParam of the struct to the line index - unique within the listview
    DllStructSetData($stLvItem, 9, $nIndex)

    $nIndex = GUICtrlSendMsg($nCtrlID, $LVM_INSERTITEMW, 0, DllStructGetPtr($stLvItem))

    If $nIndex > -1 Then
        ; Insert now the rest of the column text
        For $i = 2 To $arText[0]
            DllStructSetData($stText, 1, $arText[$i])
            DllStructSetData($stLvItem, 3, $i - 1); Store the subitem index

            GUICtrlSendMsg($nCtrlID, $LVM_SETITEMTEXTW, $nIndex, DllStructGetPtr($stLvItem))
        Next
    EndIf

    $stText = 0
    $stLvItem = 0

EndFunc   ;==>MyGUICtrlCreateListViewItem

Works like a charm for me, thanks for that awesome UDF mate !!!!!!!

@AU3 Developers

-. Please make notice that this function works smoother and better then the built-in.

Edited May 2, 2008 by Armand

[ChrisL]

@ChrisL

WHoooHOOO u'r the man !!!

no more flickers !!!!

Works like a charm for me, thanks for that awesome UDF mate !!!!!!!

it's in the help file it's not mine

edit: its on the page for GUICtrlRegisterListViewSort

Edited May 5, 2008 by ChrisL